git.squeep.com Git - akkoma/blob - lib/pleroma/user/query.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2018 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.User.Query do
   6   @moduledoc """
   7   User query builder module. Builds query from new query or another user query.
   8
   9     ## Example:
  10         query = Pleroma.User.Query(%{nickname: "nickname"})
  11         another_query = Pleroma.User.Query.build(query, %{email: "email@example.com"})
  12         Pleroma.Repo.all(query)
  13         Pleroma.Repo.all(another_query)
  14
  15   Adding new rules:
  16     - *ilike criteria*
  17       - add field to @ilike_criteria list
  18       - pass non empty string
  19       - e.g. Pleroma.User.Query.build(%{nickname: "nickname"})
  20     - *equal criteria*
  21       - add field to @equal_criteria list
  22       - pass non empty string
  23       - e.g. Pleroma.User.Query.build(%{email: "email@example.com"})
  24     - *contains criteria*
  25       - add field to @containns_criteria list
  26       - pass values list
  27       - e.g. Pleroma.User.Query.build(%{ap_id: ["http://ap_id1", "http://ap_id2"]})
  28   """
  29   import Ecto.Query
  30   import Pleroma.Web.AdminAPI.Search, only: [not_empty_string: 1]
  31   alias Pleroma.User
  32
  33   @type criteria ::
  34           %{
  35             query: String.t(),
  36             tags: [String.t()],
  37             name: String.t(),
  38             email: String.t(),
  39             local: boolean(),
  40             external: boolean(),
  41             active: boolean(),
  42             deactivated: boolean(),
  43             is_admin: boolean(),
  44             is_moderator: boolean(),
  45             super_users: boolean(),
  46             followers: User.t(),
  47             friends: User.t(),
  48             recipients_from_activity: [String.t()],
  49             nickname: [String.t()],
  50             ap_id: [String.t()]
  51           }
  52           | %{}
  53
  54   @ilike_criteria [:nickname, :name, :query]
  55   @equal_criteria [:email]
  56   @role_criteria [:is_admin, :is_moderator]
  57   @contains_criteria [:ap_id, :nickname]
  58
  59   @spec build(criteria()) :: Query.t()
  60   def build(query \\ base_query(), criteria) do
  61     prepare_query(query, criteria)
  62   end
  63
  64   @spec paginate(Ecto.Query.t(), pos_integer(), pos_integer()) :: Ecto.Query.t()
  65   def paginate(query, page, page_size) do
  66     from(u in query,
  67       limit: ^page_size,
  68       offset: ^((page - 1) * page_size)
  69     )
  70   end
  71
  72   defp base_query do
  73     from(u in User)
  74   end
  75
  76   defp prepare_query(query, criteria) do
  77     Enum.reduce(criteria, query, &compose_query/2)
  78   end
  79
  80   defp compose_query({key, value}, query)
  81        when key in @ilike_criteria and not_empty_string(value) do
  82     # hack for :query key
  83     key = if key == :query, do: :nickname, else: key
  84     where(query, [u], ilike(field(u, ^key), ^"%#{value}%"))
  85   end
  86
  87   defp compose_query({key, value}, query)
  88        when key in @equal_criteria and not_empty_string(value) do
  89     where(query, [u], ^[{key, value}])
  90   end
  91
  92   defp compose_query({key, values}, query) when key in @contains_criteria and is_list(values) do
  93     where(query, [u], field(u, ^key) in ^values)
  94   end
  95
  96   defp compose_query({:tags, tags}, query) when is_list(tags) and length(tags) > 0 do
  97     Enum.reduce(tags, query, &prepare_tag_criteria/2)
  98   end
  99
 100   defp compose_query({key, _}, query) when key in @role_criteria do
 101     where(query, [u], fragment("(?->? @> 'true')", u.info, ^to_string(key)))
 102   end
 103
 104   defp compose_query({:super_users, _}, query) do
 105     where(
 106       query,
 107       [u],
 108       fragment("?->'is_admin' @> 'true' OR ?->'is_moderator' @> 'true'", u.info, u.info)
 109     )
 110   end
 111
 112   defp compose_query({:local, _}, query), do: location_query(query, true)
 113
 114   defp compose_query({:external, _}, query), do: location_query(query, false)
 115
 116   defp compose_query({:active, _}, query) do
 117     where(query, [u], fragment("not (?->'deactivated' @> 'true')", u.info))
 118     |> where([u], not is_nil(u.nickname))
 119   end
 120
 121   defp compose_query({:deactivated, _}, query) do
 122     where(query, [u], fragment("?->'deactivated' @> 'true'", u.info))
 123     |> where([u], not is_nil(u.nickname))
 124   end
 125
 126   defp compose_query({:followers, %User{id: id, follower_address: follower_address}}, query) do
 127     where(query, [u], fragment("? <@ ?", ^[follower_address], u.following))
 128     |> where([u], u.id != ^id)
 129   end
 130
 131   defp compose_query({:friends, %User{id: id, following: following}}, query) do
 132     where(query, [u], u.follower_address in ^following)
 133     |> where([u], u.id != ^id)
 134   end
 135
 136   defp compose_query({:recipients_from_activity, to}, query) do
 137     where(query, [u], u.ap_id in ^to or fragment("? && ?", u.following, ^to))
 138   end
 139
 140   defp compose_query(_unsupported_param, query), do: query
 141
 142   defp prepare_tag_criteria(tag, query) do
 143     or_where(query, [u], fragment("? = any(?)", ^tag, u.tags))
 144   end
 145
 146   defp location_query(query, local) do
 147     where(query, [u], u.local == ^local)
 148     |> where([u], not is_nil(u.nickname))
 149   end
 150 end