git.squeep.com Git - akkoma/blob - lib/pleroma/user/info.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2019 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.User.Info do
   6   use Ecto.Schema
   7   import Ecto.Changeset
   8
   9   alias Pleroma.User.Info
  10
  11   @type t :: %__MODULE__{}
  12
  13   embedded_schema do
  14     field(:banner, :map, default: %{})
  15     field(:background, :map, default: %{})
  16     field(:source_data, :map, default: %{})
  17     field(:note_count, :integer, default: 0)
  18     field(:follower_count, :integer, default: 0)
  19     field(:locked, :boolean, default: false)
  20     field(:confirmation_pending, :boolean, default: false)
  21     field(:confirmation_token, :string, default: nil)
  22     field(:default_scope, :string, default: "public")
  23     field(:blocks, {:array, :string}, default: [])
  24     field(:domain_blocks, {:array, :string}, default: [])
  25     field(:mutes, {:array, :string}, default: [])
  26     field(:muted_reblogs, {:array, :string}, default: [])
  27     field(:subscribers, {:array, :string}, default: [])
  28     field(:deactivated, :boolean, default: false)
  29     field(:no_rich_text, :boolean, default: false)
  30     field(:ap_enabled, :boolean, default: false)
  31     field(:is_moderator, :boolean, default: false)
  32     field(:is_admin, :boolean, default: false)
  33     field(:show_role, :boolean, default: true)
  34     field(:keys, :string, default: nil)
  35     field(:settings, :map, default: nil)
  36     field(:magic_key, :string, default: nil)
  37     field(:uri, :string, default: nil)
  38     field(:topic, :string, default: nil)
  39     field(:hub, :string, default: nil)
  40     field(:salmon, :string, default: nil)
  41     field(:hide_followers, :boolean, default: false)
  42     field(:hide_follows, :boolean, default: false)
  43     field(:hide_favorites, :boolean, default: true)
  44     field(:pinned_activities, {:array, :string}, default: [])
  45     field(:flavour, :string, default: nil)
  46     field(:mascot, :map, default: nil)
  47     field(:emoji, {:array, :map}, default: [])
  48     field(:pleroma_settings_store, :map, default: %{})
  49
  50     field(:notification_settings, :map,
  51       default: %{"remote" => true, "local" => true, "followers" => true, "follows" => true}
  52     )
  53
  54     # Found in the wild
  55     # ap_id -> Where is this used?
  56     # bio -> Where is this used?
  57     # avatar -> Where is this used?
  58     # fqn -> Where is this used?
  59     # host -> Where is this used?
  60     # subject _> Where is this used?
  61   end
  62
  63   def set_activation_status(info, deactivated) do
  64     params = %{deactivated: deactivated}
  65
  66     info
  67     |> cast(params, [:deactivated])
  68     |> validate_required([:deactivated])
  69   end
  70
  71   def update_notification_settings(info, settings) do
  72     notification_settings =
  73       info.notification_settings
  74       |> Map.merge(settings)
  75       |> Map.take(["remote", "local", "followers", "follows"])
  76
  77     params = %{notification_settings: notification_settings}
  78
  79     info
  80     |> cast(params, [:notification_settings])
  81     |> validate_required([:notification_settings])
  82   end
  83
  84   def add_to_note_count(info, number) do
  85     set_note_count(info, info.note_count + number)
  86   end
  87
  88   def set_note_count(info, number) do
  89     params = %{note_count: Enum.max([0, number])}
  90
  91     info
  92     |> cast(params, [:note_count])
  93     |> validate_required([:note_count])
  94   end
  95
  96   def set_follower_count(info, number) do
  97     params = %{follower_count: Enum.max([0, number])}
  98
  99     info
 100     |> cast(params, [:follower_count])
 101     |> validate_required([:follower_count])
 102   end
 103
 104   def set_mutes(info, mutes) do
 105     params = %{mutes: mutes}
 106
 107     info
 108     |> cast(params, [:mutes])
 109     |> validate_required([:mutes])
 110   end
 111
 112   def set_blocks(info, blocks) do
 113     params = %{blocks: blocks}
 114
 115     info
 116     |> cast(params, [:blocks])
 117     |> validate_required([:blocks])
 118   end
 119
 120   def set_subscribers(info, subscribers) do
 121     params = %{subscribers: subscribers}
 122
 123     info
 124     |> cast(params, [:subscribers])
 125     |> validate_required([:subscribers])
 126   end
 127
 128   def add_to_mutes(info, muted) do
 129     set_mutes(info, Enum.uniq([muted | info.mutes]))
 130   end
 131
 132   def remove_from_mutes(info, muted) do
 133     set_mutes(info, List.delete(info.mutes, muted))
 134   end
 135
 136   def add_to_block(info, blocked) do
 137     set_blocks(info, Enum.uniq([blocked | info.blocks]))
 138   end
 139
 140   def remove_from_block(info, blocked) do
 141     set_blocks(info, List.delete(info.blocks, blocked))
 142   end
 143
 144   def add_to_subscribers(info, subscribed) do
 145     set_subscribers(info, Enum.uniq([subscribed | info.subscribers]))
 146   end
 147
 148   def remove_from_subscribers(info, subscribed) do
 149     set_subscribers(info, List.delete(info.subscribers, subscribed))
 150   end
 151
 152   def set_domain_blocks(info, domain_blocks) do
 153     params = %{domain_blocks: domain_blocks}
 154
 155     info
 156     |> cast(params, [:domain_blocks])
 157     |> validate_required([:domain_blocks])
 158   end
 159
 160   def add_to_domain_block(info, domain_blocked) do
 161     set_domain_blocks(info, Enum.uniq([domain_blocked | info.domain_blocks]))
 162   end
 163
 164   def remove_from_domain_block(info, domain_blocked) do
 165     set_domain_blocks(info, List.delete(info.domain_blocks, domain_blocked))
 166   end
 167
 168   def set_keys(info, keys) do
 169     params = %{keys: keys}
 170
 171     info
 172     |> cast(params, [:keys])
 173     |> validate_required([:keys])
 174   end
 175
 176   def remote_user_creation(info, params) do
 177     info
 178     |> cast(params, [
 179       :ap_enabled,
 180       :source_data,
 181       :banner,
 182       :locked,
 183       :magic_key,
 184       :uri,
 185       :hub,
 186       :topic,
 187       :salmon
 188     ])
 189   end
 190
 191   def user_upgrade(info, params) do
 192     info
 193     |> cast(params, [
 194       :ap_enabled,
 195       :source_data,
 196       :banner,
 197       :locked,
 198       :magic_key
 199     ])
 200   end
 201
 202   def profile_update(info, params) do
 203     info
 204     |> cast(params, [
 205       :locked,
 206       :no_rich_text,
 207       :default_scope,
 208       :banner,
 209       :hide_follows,
 210       :hide_followers,
 211       :hide_favorites,
 212       :background,
 213       :show_role
 214     ])
 215   end
 216
 217   @spec confirmation_changeset(Info.t(), keyword()) :: Changeset.t()
 218   def confirmation_changeset(info, opts) do
 219     need_confirmation? = Keyword.get(opts, :need_confirmation)
 220
 221     params =
 222       if need_confirmation? do
 223         %{
 224           confirmation_pending: true,
 225           confirmation_token: :crypto.strong_rand_bytes(32) |> Base.url_encode64()
 226         }
 227       else
 228         %{
 229           confirmation_pending: false,
 230           confirmation_token: nil
 231         }
 232       end
 233
 234     cast(info, params, [:confirmation_pending, :confirmation_token])
 235   end
 236
 237   def mastodon_settings_update(info, settings) do
 238     params = %{settings: settings}
 239
 240     info
 241     |> cast(params, [:settings])
 242     |> validate_required([:settings])
 243   end
 244
 245   def mastodon_flavour_update(info, flavour) do
 246     params = %{flavour: flavour}
 247
 248     info
 249     |> cast(params, [:flavour])
 250     |> validate_required([:flavour])
 251   end
 252
 253   def mascot_update(info, url) do
 254     params = %{mascot: url}
 255
 256     info
 257     |> cast(params, [:mascot])
 258     |> validate_required([:mascot])
 259   end
 260
 261   def set_source_data(info, source_data) do
 262     params = %{source_data: source_data}
 263
 264     info
 265     |> cast(params, [:source_data])
 266     |> validate_required([:source_data])
 267   end
 268
 269   def admin_api_update(info, params) do
 270     info
 271     |> cast(params, [
 272       :is_moderator,
 273       :is_admin,
 274       :show_role
 275     ])
 276   end
 277
 278   def add_pinnned_activity(info, %Pleroma.Activity{id: id}) do
 279     if id not in info.pinned_activities do
 280       max_pinned_statuses = Pleroma.Config.get([:instance, :max_pinned_statuses], 0)
 281       params = %{pinned_activities: info.pinned_activities ++ [id]}
 282
 283       info
 284       |> cast(params, [:pinned_activities])
 285       |> validate_length(:pinned_activities,
 286         max: max_pinned_statuses,
 287         message: "You have already pinned the maximum number of statuses"
 288       )
 289     else
 290       change(info)
 291     end
 292   end
 293
 294   def remove_pinnned_activity(info, %Pleroma.Activity{id: id}) do
 295     params = %{pinned_activities: List.delete(info.pinned_activities, id)}
 296
 297     cast(info, params, [:pinned_activities])
 298   end
 299
 300   def roles(%Info{is_moderator: is_moderator, is_admin: is_admin}) do
 301     %{
 302       admin: is_admin,
 303       moderator: is_moderator
 304     }
 305   end
 306
 307   def add_reblog_mute(info, ap_id) do
 308     params = %{muted_reblogs: info.muted_reblogs ++ [ap_id]}
 309
 310     cast(info, params, [:muted_reblogs])
 311   end
 312
 313   def remove_reblog_mute(info, ap_id) do
 314     params = %{muted_reblogs: List.delete(info.muted_reblogs, ap_id)}
 315
 316     cast(info, params, [:muted_reblogs])
 317   end
 318 end