git.squeep.com Git - akkoma/blob - lib/pleroma/user/info.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2019 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.User.Info do
   6   use Ecto.Schema
   7   import Ecto.Changeset
   8
   9   alias Pleroma.User.Info
  10
  11   embedded_schema do
  12     field(:banner, :map, default: %{})
  13     field(:background, :map, default: %{})
  14     field(:source_data, :map, default: %{})
  15     field(:note_count, :integer, default: 0)
  16     field(:follower_count, :integer, default: 0)
  17     field(:locked, :boolean, default: false)
  18     field(:confirmation_pending, :boolean, default: false)
  19     field(:confirmation_token, :string, default: nil)
  20     field(:default_scope, :string, default: "public")
  21     field(:blocks, {:array, :string}, default: [])
  22     field(:domain_blocks, {:array, :string}, default: [])
  23     field(:mutes, {:array, :string}, default: [])
  24     field(:muted_reblogs, {:array, :string}, default: [])
  25     field(:deactivated, :boolean, default: false)
  26     field(:no_rich_text, :boolean, default: false)
  27     field(:ap_enabled, :boolean, default: false)
  28     field(:is_moderator, :boolean, default: false)
  29     field(:is_admin, :boolean, default: false)
  30     field(:show_role, :boolean, default: true)
  31     field(:keys, :string, default: nil)
  32     field(:settings, :map, default: nil)
  33     field(:magic_key, :string, default: nil)
  34     field(:uri, :string, default: nil)
  35     field(:topic, :string, default: nil)
  36     field(:hub, :string, default: nil)
  37     field(:salmon, :string, default: nil)
  38     field(:hide_followers, :boolean, default: false)
  39     field(:hide_follows, :boolean, default: false)
  40     field(:pinned_activities, {:array, :string}, default: [])
  41     field(:flavour, :string, default: nil)
  42
  43     # Found in the wild
  44     # ap_id -> Where is this used?
  45     # bio -> Where is this used?
  46     # avatar -> Where is this used?
  47     # fqn -> Where is this used?
  48     # host -> Where is this used?
  49     # subject _> Where is this used?
  50   end
  51
  52   def set_activation_status(info, deactivated) do
  53     params = %{deactivated: deactivated}
  54
  55     info
  56     |> cast(params, [:deactivated])
  57     |> validate_required([:deactivated])
  58   end
  59
  60   def add_to_note_count(info, number) do
  61     set_note_count(info, info.note_count + number)
  62   end
  63
  64   def set_note_count(info, number) do
  65     params = %{note_count: Enum.max([0, number])}
  66
  67     info
  68     |> cast(params, [:note_count])
  69     |> validate_required([:note_count])
  70   end
  71
  72   def set_follower_count(info, number) do
  73     params = %{follower_count: Enum.max([0, number])}
  74
  75     info
  76     |> cast(params, [:follower_count])
  77     |> validate_required([:follower_count])
  78   end
  79
  80   def set_mutes(info, mutes) do
  81     params = %{mutes: mutes}
  82
  83     info
  84     |> cast(params, [:mutes])
  85     |> validate_required([:mutes])
  86   end
  87
  88   def set_blocks(info, blocks) do
  89     params = %{blocks: blocks}
  90
  91     info
  92     |> cast(params, [:blocks])
  93     |> validate_required([:blocks])
  94   end
  95
  96   def add_to_mutes(info, muted) do
  97     set_mutes(info, Enum.uniq([muted | info.mutes]))
  98   end
  99
 100   def remove_from_mutes(info, muted) do
 101     set_mutes(info, List.delete(info.mutes, muted))
 102   end
 103
 104   def add_to_block(info, blocked) do
 105     set_blocks(info, Enum.uniq([blocked | info.blocks]))
 106   end
 107
 108   def remove_from_block(info, blocked) do
 109     set_blocks(info, List.delete(info.blocks, blocked))
 110   end
 111
 112   def set_domain_blocks(info, domain_blocks) do
 113     params = %{domain_blocks: domain_blocks}
 114
 115     info
 116     |> cast(params, [:domain_blocks])
 117     |> validate_required([:domain_blocks])
 118   end
 119
 120   def add_to_domain_block(info, domain_blocked) do
 121     set_domain_blocks(info, Enum.uniq([domain_blocked | info.domain_blocks]))
 122   end
 123
 124   def remove_from_domain_block(info, domain_blocked) do
 125     set_domain_blocks(info, List.delete(info.domain_blocks, domain_blocked))
 126   end
 127
 128   def set_keys(info, keys) do
 129     params = %{keys: keys}
 130
 131     info
 132     |> cast(params, [:keys])
 133     |> validate_required([:keys])
 134   end
 135
 136   def remote_user_creation(info, params) do
 137     info
 138     |> cast(params, [
 139       :ap_enabled,
 140       :source_data,
 141       :banner,
 142       :locked,
 143       :magic_key,
 144       :uri,
 145       :hub,
 146       :topic,
 147       :salmon
 148     ])
 149   end
 150
 151   def user_upgrade(info, params) do
 152     info
 153     |> cast(params, [
 154       :ap_enabled,
 155       :source_data,
 156       :banner,
 157       :locked,
 158       :magic_key
 159     ])
 160   end
 161
 162   def profile_update(info, params) do
 163     info
 164     |> cast(params, [
 165       :locked,
 166       :no_rich_text,
 167       :default_scope,
 168       :banner,
 169       :hide_follows,
 170       :hide_followers,
 171       :background,
 172       :show_role
 173     ])
 174   end
 175
 176   def confirmation_changeset(info, :confirmed) do
 177     confirmation_changeset(info, %{
 178       confirmation_pending: false,
 179       confirmation_token: nil
 180     })
 181   end
 182
 183   def confirmation_changeset(info, :unconfirmed) do
 184     confirmation_changeset(info, %{
 185       confirmation_pending: true,
 186       confirmation_token: :crypto.strong_rand_bytes(32) |> Base.url_encode64()
 187     })
 188   end
 189
 190   def confirmation_changeset(info, params) do
 191     cast(info, params, [:confirmation_pending, :confirmation_token])
 192   end
 193
 194   def mastodon_profile_update(info, params) do
 195     info
 196     |> cast(params, [
 197       :locked,
 198       :banner
 199     ])
 200   end
 201
 202   def mastodon_settings_update(info, settings) do
 203     params = %{settings: settings}
 204
 205     info
 206     |> cast(params, [:settings])
 207     |> validate_required([:settings])
 208   end
 209
 210   def mastodon_flavour_update(info, flavour) do
 211     params = %{flavour: flavour}
 212
 213     info
 214     |> cast(params, [:flavour])
 215     |> validate_required([:flavour])
 216   end
 217
 218   def set_source_data(info, source_data) do
 219     params = %{source_data: source_data}
 220
 221     info
 222     |> cast(params, [:source_data])
 223     |> validate_required([:source_data])
 224   end
 225
 226   def admin_api_update(info, params) do
 227     info
 228     |> cast(params, [
 229       :is_moderator,
 230       :is_admin,
 231       :show_role
 232     ])
 233   end
 234
 235   def add_pinnned_activity(info, %Pleroma.Activity{id: id}) do
 236     if id not in info.pinned_activities do
 237       max_pinned_statuses = Pleroma.Config.get([:instance, :max_pinned_statuses], 0)
 238       params = %{pinned_activities: info.pinned_activities ++ [id]}
 239
 240       info
 241       |> cast(params, [:pinned_activities])
 242       |> validate_length(:pinned_activities,
 243         max: max_pinned_statuses,
 244         message: "You have already pinned the maximum number of statuses"
 245       )
 246     else
 247       change(info)
 248     end
 249   end
 250
 251   def remove_pinnned_activity(info, %Pleroma.Activity{id: id}) do
 252     params = %{pinned_activities: List.delete(info.pinned_activities, id)}
 253
 254     cast(info, params, [:pinned_activities])
 255   end
 256
 257   def roles(%Info{is_moderator: is_moderator, is_admin: is_admin}) do
 258     %{
 259       admin: is_admin,
 260       moderator: is_moderator
 261     }
 262   end
 263
 264   def add_reblog_mute(info, ap_id) do
 265     params = %{muted_reblogs: info.muted_reblogs ++ [ap_id]}
 266
 267     cast(info, params, [:muted_reblogs])
 268   end
 269
 270   def remove_reblog_mute(info, ap_id) do
 271     params = %{muted_reblogs: List.delete(info.muted_reblogs, ap_id)}
 272
 273     cast(info, params, [:muted_reblogs])
 274   end
 275 end