git.squeep.com Git - akkoma/blob - lib/pleroma/user/info.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2019 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.User.Info do
   6   use Ecto.Schema
   7   import Ecto.Changeset
   8
   9   alias Pleroma.User.Info
  10
  11   @type t :: %__MODULE__{}
  12
  13   embedded_schema do
  14     field(:banner, :map, default: %{})
  15     field(:background, :map, default: %{})
  16     field(:source_data, :map, default: %{})
  17     field(:note_count, :integer, default: 0)
  18     field(:follower_count, :integer, default: 0)
  19     field(:locked, :boolean, default: false)
  20     field(:confirmation_pending, :boolean, default: false)
  21     field(:confirmation_token, :string, default: nil)
  22     field(:default_scope, :string, default: "public")
  23     field(:blocks, {:array, :string}, default: [])
  24     field(:domain_blocks, {:array, :string}, default: [])
  25     field(:mutes, {:array, :string}, default: [])
  26     field(:muted_reblogs, {:array, :string}, default: [])
  27     field(:subscribers, {:array, :string}, default: [])
  28     field(:deactivated, :boolean, default: false)
  29     field(:no_rich_text, :boolean, default: false)
  30     field(:ap_enabled, :boolean, default: false)
  31     field(:is_moderator, :boolean, default: false)
  32     field(:is_admin, :boolean, default: false)
  33     field(:show_role, :boolean, default: true)
  34     field(:keys, :string, default: nil)
  35     field(:settings, :map, default: nil)
  36     field(:magic_key, :string, default: nil)
  37     field(:uri, :string, default: nil)
  38     field(:topic, :string, default: nil)
  39     field(:hub, :string, default: nil)
  40     field(:salmon, :string, default: nil)
  41     field(:hide_followers, :boolean, default: false)
  42     field(:hide_follows, :boolean, default: false)
  43     field(:hide_favorites, :boolean, default: true)
  44     field(:pinned_activities, {:array, :string}, default: [])
  45     field(:mascot, :map, default: nil)
  46     field(:emoji, {:array, :map}, default: [])
  47     field(:pleroma_settings_store, :map, default: %{})
  48
  49     field(:notification_settings, :map,
  50       default: %{
  51         "followers" => true,
  52         "follows" => true,
  53         "non_follows" => true,
  54         "non_followers" => true
  55       }
  56     )
  57
  58     # Found in the wild
  59     # ap_id -> Where is this used?
  60     # bio -> Where is this used?
  61     # avatar -> Where is this used?
  62     # fqn -> Where is this used?
  63     # host -> Where is this used?
  64     # subject _> Where is this used?
  65   end
  66
  67   def set_activation_status(info, deactivated) do
  68     params = %{deactivated: deactivated}
  69
  70     info
  71     |> cast(params, [:deactivated])
  72     |> validate_required([:deactivated])
  73   end
  74
  75   def update_notification_settings(info, settings) do
  76     settings =
  77       settings
  78       |> Enum.map(fn {k, v} -> {k, v in [true, "true", "True", "1"]} end)
  79       |> Map.new()
  80
  81     notification_settings =
  82       info.notification_settings
  83       |> Map.merge(settings)
  84       |> Map.take(["followers", "follows", "non_follows", "non_followers"])
  85
  86     params = %{notification_settings: notification_settings}
  87
  88     info
  89     |> cast(params, [:notification_settings])
  90     |> validate_required([:notification_settings])
  91   end
  92
  93   def add_to_note_count(info, number) do
  94     set_note_count(info, info.note_count + number)
  95   end
  96
  97   def set_note_count(info, number) do
  98     params = %{note_count: Enum.max([0, number])}
  99
 100     info
 101     |> cast(params, [:note_count])
 102     |> validate_required([:note_count])
 103   end
 104
 105   def set_follower_count(info, number) do
 106     params = %{follower_count: Enum.max([0, number])}
 107
 108     info
 109     |> cast(params, [:follower_count])
 110     |> validate_required([:follower_count])
 111   end
 112
 113   def set_mutes(info, mutes) do
 114     params = %{mutes: mutes}
 115
 116     info
 117     |> cast(params, [:mutes])
 118     |> validate_required([:mutes])
 119   end
 120
 121   def set_blocks(info, blocks) do
 122     params = %{blocks: blocks}
 123
 124     info
 125     |> cast(params, [:blocks])
 126     |> validate_required([:blocks])
 127   end
 128
 129   def set_subscribers(info, subscribers) do
 130     params = %{subscribers: subscribers}
 131
 132     info
 133     |> cast(params, [:subscribers])
 134     |> validate_required([:subscribers])
 135   end
 136
 137   def add_to_mutes(info, muted) do
 138     set_mutes(info, Enum.uniq([muted | info.mutes]))
 139   end
 140
 141   def remove_from_mutes(info, muted) do
 142     set_mutes(info, List.delete(info.mutes, muted))
 143   end
 144
 145   def add_to_block(info, blocked) do
 146     set_blocks(info, Enum.uniq([blocked | info.blocks]))
 147   end
 148
 149   def remove_from_block(info, blocked) do
 150     set_blocks(info, List.delete(info.blocks, blocked))
 151   end
 152
 153   def add_to_subscribers(info, subscribed) do
 154     set_subscribers(info, Enum.uniq([subscribed | info.subscribers]))
 155   end
 156
 157   def remove_from_subscribers(info, subscribed) do
 158     set_subscribers(info, List.delete(info.subscribers, subscribed))
 159   end
 160
 161   def set_domain_blocks(info, domain_blocks) do
 162     params = %{domain_blocks: domain_blocks}
 163
 164     info
 165     |> cast(params, [:domain_blocks])
 166     |> validate_required([:domain_blocks])
 167   end
 168
 169   def add_to_domain_block(info, domain_blocked) do
 170     set_domain_blocks(info, Enum.uniq([domain_blocked | info.domain_blocks]))
 171   end
 172
 173   def remove_from_domain_block(info, domain_blocked) do
 174     set_domain_blocks(info, List.delete(info.domain_blocks, domain_blocked))
 175   end
 176
 177   def set_keys(info, keys) do
 178     params = %{keys: keys}
 179
 180     info
 181     |> cast(params, [:keys])
 182     |> validate_required([:keys])
 183   end
 184
 185   def remote_user_creation(info, params) do
 186     info
 187     |> cast(params, [
 188       :ap_enabled,
 189       :source_data,
 190       :banner,
 191       :locked,
 192       :magic_key,
 193       :uri,
 194       :hub,
 195       :topic,
 196       :salmon
 197     ])
 198   end
 199
 200   def user_upgrade(info, params) do
 201     info
 202     |> cast(params, [
 203       :ap_enabled,
 204       :source_data,
 205       :banner,
 206       :locked,
 207       :magic_key
 208     ])
 209   end
 210
 211   def profile_update(info, params) do
 212     info
 213     |> cast(params, [
 214       :locked,
 215       :no_rich_text,
 216       :default_scope,
 217       :banner,
 218       :hide_follows,
 219       :hide_followers,
 220       :hide_favorites,
 221       :background,
 222       :show_role,
 223       :pleroma_settings_store
 224     ])
 225   end
 226
 227   @spec confirmation_changeset(Info.t(), keyword()) :: Changeset.t()
 228   def confirmation_changeset(info, opts) do
 229     need_confirmation? = Keyword.get(opts, :need_confirmation)
 230
 231     params =
 232       if need_confirmation? do
 233         %{
 234           confirmation_pending: true,
 235           confirmation_token: :crypto.strong_rand_bytes(32) |> Base.url_encode64()
 236         }
 237       else
 238         %{
 239           confirmation_pending: false,
 240           confirmation_token: nil
 241         }
 242       end
 243
 244     cast(info, params, [:confirmation_pending, :confirmation_token])
 245   end
 246
 247   def mastodon_settings_update(info, settings) do
 248     params = %{settings: settings}
 249
 250     info
 251     |> cast(params, [:settings])
 252     |> validate_required([:settings])
 253   end
 254
 255   def mascot_update(info, url) do
 256     params = %{mascot: url}
 257
 258     info
 259     |> cast(params, [:mascot])
 260     |> validate_required([:mascot])
 261   end
 262
 263   def set_source_data(info, source_data) do
 264     params = %{source_data: source_data}
 265
 266     info
 267     |> cast(params, [:source_data])
 268     |> validate_required([:source_data])
 269   end
 270
 271   def admin_api_update(info, params) do
 272     info
 273     |> cast(params, [
 274       :is_moderator,
 275       :is_admin,
 276       :show_role
 277     ])
 278   end
 279
 280   def add_pinnned_activity(info, %Pleroma.Activity{id: id}) do
 281     if id not in info.pinned_activities do
 282       max_pinned_statuses = Pleroma.Config.get([:instance, :max_pinned_statuses], 0)
 283       params = %{pinned_activities: info.pinned_activities ++ [id]}
 284
 285       info
 286       |> cast(params, [:pinned_activities])
 287       |> validate_length(:pinned_activities,
 288         max: max_pinned_statuses,
 289         message: "You have already pinned the maximum number of statuses"
 290       )
 291     else
 292       change(info)
 293     end
 294   end
 295
 296   def remove_pinnned_activity(info, %Pleroma.Activity{id: id}) do
 297     params = %{pinned_activities: List.delete(info.pinned_activities, id)}
 298
 299     cast(info, params, [:pinned_activities])
 300   end
 301
 302   def roles(%Info{is_moderator: is_moderator, is_admin: is_admin}) do
 303     %{
 304       admin: is_admin,
 305       moderator: is_moderator
 306     }
 307   end
 308
 309   def add_reblog_mute(info, ap_id) do
 310     params = %{muted_reblogs: info.muted_reblogs ++ [ap_id]}
 311
 312     cast(info, params, [:muted_reblogs])
 313   end
 314
 315   def remove_reblog_mute(info, ap_id) do
 316     params = %{muted_reblogs: List.delete(info.muted_reblogs, ap_id)}
 317
 318     cast(info, params, [:muted_reblogs])
 319   end
 320 end