git.squeep.com Git - akkoma/blob - lib/pleroma/user/info.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2019 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.User.Info do
   6   use Ecto.Schema
   7   import Ecto.Changeset
   8
   9   embedded_schema do
  10     field(:banner, :map, default: %{})
  11     field(:background, :map, default: %{})
  12     field(:source_data, :map, default: %{})
  13     field(:note_count, :integer, default: 0)
  14     field(:follower_count, :integer, default: 0)
  15     field(:locked, :boolean, default: false)
  16     field(:confirmation_pending, :boolean, default: false)
  17     field(:confirmation_token, :string, default: nil)
  18     field(:default_scope, :string, default: "public")
  19     field(:blocks, {:array, :string}, default: [])
  20     field(:domain_blocks, {:array, :string}, default: [])
  21     field(:mutes, {:array, :string}, default: [])
  22     field(:deactivated, :boolean, default: false)
  23     field(:no_rich_text, :boolean, default: false)
  24     field(:ap_enabled, :boolean, default: false)
  25     field(:is_moderator, :boolean, default: false)
  26     field(:is_admin, :boolean, default: false)
  27     field(:show_role, :boolean, default: true)
  28     field(:keys, :string, default: nil)
  29     field(:settings, :map, default: nil)
  30     field(:magic_key, :string, default: nil)
  31     field(:uri, :string, default: nil)
  32     field(:topic, :string, default: nil)
  33     field(:hub, :string, default: nil)
  34     field(:salmon, :string, default: nil)
  35     field(:hide_followers, :boolean, default: false)
  36     field(:hide_follows, :boolean, default: false)
  37     field(:pinned_activities, {:array, :string}, default: [])
  38     field(:flavour, :string, default: nil)
  39     field(:disabled, :boolean, default: false)
  40
  41     # Found in the wild
  42     # ap_id -> Where is this used?
  43     # bio -> Where is this used?
  44     # avatar -> Where is this used?
  45     # fqn -> Where is this used?
  46     # host -> Where is this used?
  47     # subject _> Where is this used?
  48   end
  49
  50   def set_activation_status(info, deactivated) do
  51     params = %{deactivated: deactivated}
  52
  53     info
  54     |> cast(params, [:deactivated])
  55     |> validate_required([:deactivated])
  56   end
  57
  58   def set_disabled_status(info, disabled) do
  59     params = %{disabled: disabled}
  60
  61     info
  62     |> cast(params, [:disabled])
  63     |> validate_required([:disabled])
  64   end
  65
  66   def add_to_note_count(info, number) do
  67     set_note_count(info, info.note_count + number)
  68   end
  69
  70   def set_note_count(info, number) do
  71     params = %{note_count: Enum.max([0, number])}
  72
  73     info
  74     |> cast(params, [:note_count])
  75     |> validate_required([:note_count])
  76   end
  77
  78   def set_follower_count(info, number) do
  79     params = %{follower_count: Enum.max([0, number])}
  80
  81     info
  82     |> cast(params, [:follower_count])
  83     |> validate_required([:follower_count])
  84   end
  85
  86   def set_mutes(info, mutes) do
  87     params = %{mutes: mutes}
  88
  89     info
  90     |> cast(params, [:mutes])
  91     |> validate_required([:mutes])
  92   end
  93
  94   def set_blocks(info, blocks) do
  95     params = %{blocks: blocks}
  96
  97     info
  98     |> cast(params, [:blocks])
  99     |> validate_required([:blocks])
 100   end
 101
 102   def add_to_mutes(info, muted) do
 103     set_mutes(info, Enum.uniq([muted | info.mutes]))
 104   end
 105
 106   def remove_from_mutes(info, muted) do
 107     set_mutes(info, List.delete(info.mutes, muted))
 108   end
 109
 110   def add_to_block(info, blocked) do
 111     set_blocks(info, Enum.uniq([blocked | info.blocks]))
 112   end
 113
 114   def remove_from_block(info, blocked) do
 115     set_blocks(info, List.delete(info.blocks, blocked))
 116   end
 117
 118   def set_domain_blocks(info, domain_blocks) do
 119     params = %{domain_blocks: domain_blocks}
 120
 121     info
 122     |> cast(params, [:domain_blocks])
 123     |> validate_required([:domain_blocks])
 124   end
 125
 126   def add_to_domain_block(info, domain_blocked) do
 127     set_domain_blocks(info, Enum.uniq([domain_blocked | info.domain_blocks]))
 128   end
 129
 130   def remove_from_domain_block(info, domain_blocked) do
 131     set_domain_blocks(info, List.delete(info.domain_blocks, domain_blocked))
 132   end
 133
 134   def set_keys(info, keys) do
 135     params = %{keys: keys}
 136
 137     info
 138     |> cast(params, [:keys])
 139     |> validate_required([:keys])
 140   end
 141
 142   def remote_user_creation(info, params) do
 143     info
 144     |> cast(params, [
 145       :ap_enabled,
 146       :source_data,
 147       :banner,
 148       :locked,
 149       :magic_key,
 150       :uri,
 151       :hub,
 152       :topic,
 153       :salmon
 154     ])
 155   end
 156
 157   def user_upgrade(info, params) do
 158     info
 159     |> cast(params, [
 160       :ap_enabled,
 161       :source_data,
 162       :banner,
 163       :locked,
 164       :magic_key
 165     ])
 166   end
 167
 168   def profile_update(info, params) do
 169     info
 170     |> cast(params, [
 171       :locked,
 172       :no_rich_text,
 173       :default_scope,
 174       :banner,
 175       :hide_follows,
 176       :hide_followers,
 177       :background,
 178       :show_role
 179     ])
 180   end
 181
 182   def confirmation_changeset(info, :confirmed) do
 183     confirmation_changeset(info, %{
 184       confirmation_pending: false,
 185       confirmation_token: nil
 186     })
 187   end
 188
 189   def confirmation_changeset(info, :unconfirmed) do
 190     confirmation_changeset(info, %{
 191       confirmation_pending: true,
 192       confirmation_token: :crypto.strong_rand_bytes(32) |> Base.url_encode64()
 193     })
 194   end
 195
 196   def confirmation_changeset(info, params) do
 197     cast(info, params, [:confirmation_pending, :confirmation_token])
 198   end
 199
 200   def mastodon_profile_update(info, params) do
 201     info
 202     |> cast(params, [
 203       :locked,
 204       :banner
 205     ])
 206   end
 207
 208   def mastodon_settings_update(info, settings) do
 209     params = %{settings: settings}
 210
 211     info
 212     |> cast(params, [:settings])
 213     |> validate_required([:settings])
 214   end
 215
 216   def mastodon_flavour_update(info, flavour) do
 217     params = %{flavour: flavour}
 218
 219     info
 220     |> cast(params, [:flavour])
 221     |> validate_required([:flavour])
 222   end
 223
 224   def set_source_data(info, source_data) do
 225     params = %{source_data: source_data}
 226
 227     info
 228     |> cast(params, [:source_data])
 229     |> validate_required([:source_data])
 230   end
 231
 232   def admin_api_update(info, params) do
 233     info
 234     |> cast(params, [
 235       :is_moderator,
 236       :is_admin,
 237       :show_role
 238     ])
 239   end
 240
 241   def add_pinnned_activity(info, %Pleroma.Activity{id: id}) do
 242     if id not in info.pinned_activities do
 243       max_pinned_statuses = Pleroma.Config.get([:instance, :max_pinned_statuses], 0)
 244       params = %{pinned_activities: info.pinned_activities ++ [id]}
 245
 246       info
 247       |> cast(params, [:pinned_activities])
 248       |> validate_length(:pinned_activities,
 249         max: max_pinned_statuses,
 250         message: "You have already pinned the maximum number of statuses"
 251       )
 252     else
 253       change(info)
 254     end
 255   end
 256
 257   def remove_pinnned_activity(info, %Pleroma.Activity{id: id}) do
 258     params = %{pinned_activities: List.delete(info.pinned_activities, id)}
 259
 260     cast(info, params, [:pinned_activities])
 261   end
 262 end