git.squeep.com Git - akkoma/blob - lib/pleroma/user/info.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2019 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.User.Info do
   6   use Ecto.Schema
   7   import Ecto.Changeset
   8
   9   alias Pleroma.User.Info
  10
  11   @type t :: %__MODULE__{}
  12
  13   embedded_schema do
  14     field(:banner, :map, default: %{})
  15     field(:background, :map, default: %{})
  16     field(:source_data, :map, default: %{})
  17     field(:note_count, :integer, default: 0)
  18     field(:follower_count, :integer, default: 0)
  19     # Should be filled in only for remote users
  20     field(:following_count, :integer, default: nil)
  21     field(:locked, :boolean, default: false)
  22     field(:confirmation_pending, :boolean, default: false)
  23     field(:confirmation_token, :string, default: nil)
  24     field(:default_scope, :string, default: "public")
  25     field(:blocks, {:array, :string}, default: [])
  26     field(:domain_blocks, {:array, :string}, default: [])
  27     field(:mutes, {:array, :string}, default: [])
  28     field(:muted_reblogs, {:array, :string}, default: [])
  29     field(:muted_notifications, {:array, :string}, default: [])
  30     field(:subscribers, {:array, :string}, default: [])
  31     field(:deactivated, :boolean, default: false)
  32     field(:no_rich_text, :boolean, default: false)
  33     field(:ap_enabled, :boolean, default: false)
  34     field(:is_moderator, :boolean, default: false)
  35     field(:is_admin, :boolean, default: false)
  36     field(:show_role, :boolean, default: true)
  37     field(:keys, :string, default: nil)
  38     field(:settings, :map, default: nil)
  39     field(:magic_key, :string, default: nil)
  40     field(:uri, :string, default: nil)
  41     field(:topic, :string, default: nil)
  42     field(:hub, :string, default: nil)
  43     field(:salmon, :string, default: nil)
  44     field(:hide_followers, :boolean, default: false)
  45     field(:hide_follows, :boolean, default: false)
  46     field(:hide_favorites, :boolean, default: true)
  47     field(:pinned_activities, {:array, :string}, default: [])
  48     field(:email_notifications, :map, default: %{"digest" => false})
  49     field(:mascot, :map, default: nil)
  50     field(:emoji, {:array, :map}, default: [])
  51     field(:pleroma_settings_store, :map, default: %{})
  52     field(:fields, {:array, :map}, default: nil)
  53     field(:raw_fields, {:array, :map}, default: [])
  54
  55     field(:notification_settings, :map,
  56       default: %{
  57         "followers" => true,
  58         "follows" => true,
  59         "non_follows" => true,
  60         "non_followers" => true
  61       }
  62     )
  63
  64     field(:skip_thread_containment, :boolean, default: false)
  65
  66     # Found in the wild
  67     # ap_id -> Where is this used?
  68     # bio -> Where is this used?
  69     # avatar -> Where is this used?
  70     # fqn -> Where is this used?
  71     # host -> Where is this used?
  72     # subject _> Where is this used?
  73   end
  74
  75   def set_activation_status(info, deactivated) do
  76     params = %{deactivated: deactivated}
  77
  78     info
  79     |> cast(params, [:deactivated])
  80     |> validate_required([:deactivated])
  81   end
  82
  83   def update_notification_settings(info, settings) do
  84     settings =
  85       settings
  86       |> Enum.map(fn {k, v} -> {k, v in [true, "true", "True", "1"]} end)
  87       |> Map.new()
  88
  89     notification_settings =
  90       info.notification_settings
  91       |> Map.merge(settings)
  92       |> Map.take(["followers", "follows", "non_follows", "non_followers"])
  93
  94     params = %{notification_settings: notification_settings}
  95
  96     info
  97     |> cast(params, [:notification_settings])
  98     |> validate_required([:notification_settings])
  99   end
 100
 101   @doc """
 102   Update email notifications in the given User.Info struct.
 103
 104   Examples:
 105
 106       iex> update_email_notifications(%Pleroma.User.Info{email_notifications: %{"digest" => false}}, %{"digest" => true})
 107       %Pleroma.User.Info{email_notifications: %{"digest" => true}}
 108
 109   """
 110   @spec update_email_notifications(t(), map()) :: Ecto.Changeset.t()
 111   def update_email_notifications(info, settings) do
 112     email_notifications =
 113       info.email_notifications
 114       |> Map.merge(settings)
 115       |> Map.take(["digest"])
 116
 117     params = %{email_notifications: email_notifications}
 118     fields = [:email_notifications]
 119
 120     info
 121     |> cast(params, fields)
 122     |> validate_required(fields)
 123   end
 124
 125   def add_to_note_count(info, number) do
 126     set_note_count(info, info.note_count + number)
 127   end
 128
 129   def set_note_count(info, number) do
 130     params = %{note_count: Enum.max([0, number])}
 131
 132     info
 133     |> cast(params, [:note_count])
 134     |> validate_required([:note_count])
 135   end
 136
 137   def set_follower_count(info, number) do
 138     params = %{follower_count: Enum.max([0, number])}
 139
 140     info
 141     |> cast(params, [:follower_count])
 142     |> validate_required([:follower_count])
 143   end
 144
 145   def set_mutes(info, mutes) do
 146     params = %{mutes: mutes}
 147
 148     info
 149     |> cast(params, [:mutes])
 150     |> validate_required([:mutes])
 151   end
 152
 153   @spec set_notification_mutes(Changeset.t(), [String.t()], boolean()) :: Changeset.t()
 154   def set_notification_mutes(changeset, muted_notifications, notifications?) do
 155     if notifications? do
 156       put_change(changeset, :muted_notifications, muted_notifications)
 157       |> validate_required([:muted_notifications])
 158     else
 159       changeset
 160     end
 161   end
 162
 163   def set_blocks(info, blocks) do
 164     params = %{blocks: blocks}
 165
 166     info
 167     |> cast(params, [:blocks])
 168     |> validate_required([:blocks])
 169   end
 170
 171   def set_subscribers(info, subscribers) do
 172     params = %{subscribers: subscribers}
 173
 174     info
 175     |> cast(params, [:subscribers])
 176     |> validate_required([:subscribers])
 177   end
 178
 179   @spec add_to_mutes(Info.t(), String.t()) :: Changeset.t()
 180   def add_to_mutes(info, muted) do
 181     set_mutes(info, Enum.uniq([muted | info.mutes]))
 182   end
 183
 184   @spec add_to_muted_notifications(Changeset.t(), Info.t(), String.t(), boolean()) ::
 185           Changeset.t()
 186   def add_to_muted_notifications(changeset, info, muted, notifications?) do
 187     set_notification_mutes(
 188       changeset,
 189       Enum.uniq([muted | info.muted_notifications]),
 190       notifications?
 191     )
 192   end
 193
 194   @spec remove_from_mutes(Info.t(), String.t()) :: Changeset.t()
 195   def remove_from_mutes(info, muted) do
 196     set_mutes(info, List.delete(info.mutes, muted))
 197   end
 198
 199   @spec remove_from_muted_notifications(Changeset.t(), Info.t(), String.t()) :: Changeset.t()
 200   def remove_from_muted_notifications(changeset, info, muted) do
 201     set_notification_mutes(changeset, List.delete(info.muted_notifications, muted), true)
 202   end
 203
 204   def add_to_block(info, blocked) do
 205     set_blocks(info, Enum.uniq([blocked | info.blocks]))
 206   end
 207
 208   def remove_from_block(info, blocked) do
 209     set_blocks(info, List.delete(info.blocks, blocked))
 210   end
 211
 212   def add_to_subscribers(info, subscribed) do
 213     set_subscribers(info, Enum.uniq([subscribed | info.subscribers]))
 214   end
 215
 216   def remove_from_subscribers(info, subscribed) do
 217     set_subscribers(info, List.delete(info.subscribers, subscribed))
 218   end
 219
 220   def set_domain_blocks(info, domain_blocks) do
 221     params = %{domain_blocks: domain_blocks}
 222
 223     info
 224     |> cast(params, [:domain_blocks])
 225     |> validate_required([:domain_blocks])
 226   end
 227
 228   def add_to_domain_block(info, domain_blocked) do
 229     set_domain_blocks(info, Enum.uniq([domain_blocked | info.domain_blocks]))
 230   end
 231
 232   def remove_from_domain_block(info, domain_blocked) do
 233     set_domain_blocks(info, List.delete(info.domain_blocks, domain_blocked))
 234   end
 235
 236   def set_keys(info, keys) do
 237     params = %{keys: keys}
 238
 239     info
 240     |> cast(params, [:keys])
 241     |> validate_required([:keys])
 242   end
 243
 244   def remote_user_creation(info, params) do
 245     params = Map.put(params, "fields", Enum.map(params["fields"], &truncate_field/1))
 246
 247     info
 248     |> cast(params, [
 249       :ap_enabled,
 250       :source_data,
 251       :banner,
 252       :locked,
 253       :magic_key,
 254       :uri,
 255       :hub,
 256       :topic,
 257       :salmon,
 258       :hide_followers,
 259       :hide_follows,
 260       :follower_count,
 261       :fields,
 262       :following_count
 263     ])
 264     |> validate_fields(true)
 265   end
 266
 267   def user_upgrade(info, params, remote? \\ false) do
 268     info
 269     |> cast(params, [
 270       :ap_enabled,
 271       :source_data,
 272       :banner,
 273       :locked,
 274       :magic_key,
 275       :follower_count,
 276       :following_count,
 277       :hide_follows,
 278       :fields,
 279       :hide_followers
 280     ])
 281     |> validate_fields(remote?)
 282   end
 283
 284   def profile_update(info, params) do
 285     info
 286     |> cast(params, [
 287       :locked,
 288       :no_rich_text,
 289       :default_scope,
 290       :banner,
 291       :hide_follows,
 292       :hide_followers,
 293       :hide_favorites,
 294       :background,
 295       :show_role,
 296       :skip_thread_containment,
 297       :fields,
 298       :raw_fields,
 299       :pleroma_settings_store
 300     ])
 301     |> validate_fields()
 302   end
 303
 304   def validate_fields(changeset, remote? \\ false) do
 305     limit_name = if remote?, do: :max_remote_account_fields, else: :max_account_fields
 306     limit = Pleroma.Config.get([:instance, limit_name], 0)
 307
 308     changeset
 309     |> validate_length(:fields, max: limit)
 310     |> validate_change(:fields, fn :fields, fields ->
 311       if Enum.all?(fields, &valid_field?/1) do
 312         []
 313       else
 314         [fields: "invalid"]
 315       end
 316     end)
 317   end
 318
 319   defp valid_field?(%{"name" => name, "value" => value}) do
 320     name_limit = Pleroma.Config.get([:instance, :account_field_name_length], 255)
 321     value_limit = Pleroma.Config.get([:instance, :account_field_value_length], 255)
 322
 323     is_binary(name) &&
 324       is_binary(value) &&
 325       String.length(name) <= name_limit &&
 326       String.length(value) <= value_limit
 327   end
 328
 329   defp valid_field?(_), do: false
 330
 331   defp truncate_field(%{"name" => name, "value" => value}) do
 332     {name, _chopped} =
 333       String.split_at(name, Pleroma.Config.get([:instance, :account_field_name_length], 255))
 334
 335     {value, _chopped} =
 336       String.split_at(value, Pleroma.Config.get([:instance, :account_field_value_length], 255))
 337
 338     %{"name" => name, "value" => value}
 339   end
 340
 341   @spec confirmation_changeset(Info.t(), keyword()) :: Changeset.t()
 342   def confirmation_changeset(info, opts) do
 343     need_confirmation? = Keyword.get(opts, :need_confirmation)
 344
 345     params =
 346       if need_confirmation? do
 347         %{
 348           confirmation_pending: true,
 349           confirmation_token: :crypto.strong_rand_bytes(32) |> Base.url_encode64()
 350         }
 351       else
 352         %{
 353           confirmation_pending: false,
 354           confirmation_token: nil
 355         }
 356       end
 357
 358     cast(info, params, [:confirmation_pending, :confirmation_token])
 359   end
 360
 361   def mastodon_settings_update(info, settings) do
 362     params = %{settings: settings}
 363
 364     info
 365     |> cast(params, [:settings])
 366     |> validate_required([:settings])
 367   end
 368
 369   def mascot_update(info, url) do
 370     params = %{mascot: url}
 371
 372     info
 373     |> cast(params, [:mascot])
 374     |> validate_required([:mascot])
 375   end
 376
 377   def set_source_data(info, source_data) do
 378     params = %{source_data: source_data}
 379
 380     info
 381     |> cast(params, [:source_data])
 382     |> validate_required([:source_data])
 383   end
 384
 385   def admin_api_update(info, params) do
 386     info
 387     |> cast(params, [
 388       :is_moderator,
 389       :is_admin,
 390       :show_role
 391     ])
 392   end
 393
 394   def add_pinnned_activity(info, %Pleroma.Activity{id: id}) do
 395     if id not in info.pinned_activities do
 396       max_pinned_statuses = Pleroma.Config.get([:instance, :max_pinned_statuses], 0)
 397       params = %{pinned_activities: info.pinned_activities ++ [id]}
 398
 399       info
 400       |> cast(params, [:pinned_activities])
 401       |> validate_length(:pinned_activities,
 402         max: max_pinned_statuses,
 403         message: "You have already pinned the maximum number of statuses"
 404       )
 405     else
 406       change(info)
 407     end
 408   end
 409
 410   def remove_pinnned_activity(info, %Pleroma.Activity{id: id}) do
 411     params = %{pinned_activities: List.delete(info.pinned_activities, id)}
 412
 413     cast(info, params, [:pinned_activities])
 414   end
 415
 416   def roles(%Info{is_moderator: is_moderator, is_admin: is_admin}) do
 417     %{
 418       admin: is_admin,
 419       moderator: is_moderator
 420     }
 421   end
 422
 423   def add_reblog_mute(info, ap_id) do
 424     params = %{muted_reblogs: info.muted_reblogs ++ [ap_id]}
 425
 426     cast(info, params, [:muted_reblogs])
 427   end
 428
 429   def remove_reblog_mute(info, ap_id) do
 430     params = %{muted_reblogs: List.delete(info.muted_reblogs, ap_id)}
 431
 432     cast(info, params, [:muted_reblogs])
 433   end
 434
 435   # ``fields`` is an array of mastodon profile field, containing ``{"name": "…", "value": "…"}``.
 436   # For example: [{"name": "Pronoun", "value": "she/her"}, …]
 437   def fields(%{fields: nil, source_data: %{"attachment" => attachment}}) do
 438     limit = Pleroma.Config.get([:instance, :max_remote_account_fields], 0)
 439
 440     attachment
 441     |> Enum.filter(fn %{"type" => t} -> t == "PropertyValue" end)
 442     |> Enum.map(fn fields -> Map.take(fields, ["name", "value"]) end)
 443     |> Enum.take(limit)
 444   end
 445
 446   def fields(%{fields: nil}), do: []
 447
 448   def fields(%{fields: fields}), do: fields
 449
 450   def follow_information_update(info, params) do
 451     info
 452     |> cast(params, [
 453       :hide_followers,
 454       :hide_follows,
 455       :follower_count,
 456       :following_count
 457     ])
 458   end
 459 end