git.squeep.com Git - akkoma/blob - lib/pleroma/user/info.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2019 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.User.Info do
   6   use Ecto.Schema
   7   import Ecto.Changeset
   8
   9   alias Pleroma.User.Info
  10
  11   @type t :: %__MODULE__{}
  12
  13   embedded_schema do
  14     field(:banner, :map, default: %{})
  15     field(:background, :map, default: %{})
  16     field(:source_data, :map, default: %{})
  17     field(:note_count, :integer, default: 0)
  18     field(:follower_count, :integer, default: 0)
  19     field(:locked, :boolean, default: false)
  20     field(:confirmation_pending, :boolean, default: false)
  21     field(:confirmation_token, :string, default: nil)
  22     field(:default_scope, :string, default: "public")
  23     field(:blocks, {:array, :string}, default: [])
  24     field(:domain_blocks, {:array, :string}, default: [])
  25     field(:mutes, {:array, :string}, default: [])
  26     field(:muted_reblogs, {:array, :string}, default: [])
  27     field(:subscribers, {:array, :string}, default: [])
  28     field(:deactivated, :boolean, default: false)
  29     field(:no_rich_text, :boolean, default: false)
  30     field(:ap_enabled, :boolean, default: false)
  31     field(:is_moderator, :boolean, default: false)
  32     field(:is_admin, :boolean, default: false)
  33     field(:show_role, :boolean, default: true)
  34     field(:keys, :string, default: nil)
  35     field(:settings, :map, default: nil)
  36     field(:magic_key, :string, default: nil)
  37     field(:uri, :string, default: nil)
  38     field(:topic, :string, default: nil)
  39     field(:hub, :string, default: nil)
  40     field(:salmon, :string, default: nil)
  41     field(:hide_followers, :boolean, default: false)
  42     field(:hide_follows, :boolean, default: false)
  43     field(:hide_favorites, :boolean, default: true)
  44     field(:pinned_activities, {:array, :string}, default: [])
  45     field(:mascot, :map, default: nil)
  46     field(:emoji, {:array, :map}, default: [])
  47
  48     field(:notification_settings, :map,
  49       default: %{
  50         "followers" => true,
  51         "follows" => true,
  52         "non_follows" => true,
  53         "non_followers" => true
  54       }
  55     )
  56
  57     # Found in the wild
  58     # ap_id -> Where is this used?
  59     # bio -> Where is this used?
  60     # avatar -> Where is this used?
  61     # fqn -> Where is this used?
  62     # host -> Where is this used?
  63     # subject _> Where is this used?
  64   end
  65
  66   def set_activation_status(info, deactivated) do
  67     params = %{deactivated: deactivated}
  68
  69     info
  70     |> cast(params, [:deactivated])
  71     |> validate_required([:deactivated])
  72   end
  73
  74   def update_notification_settings(info, settings) do
  75     settings =
  76       settings
  77       |> Enum.map(fn {k, v} -> {k, v in [true, "true", "True", "1"]} end)
  78       |> Map.new()
  79
  80     notification_settings =
  81       info.notification_settings
  82       |> Map.merge(settings)
  83       |> Map.take(["followers", "follows", "non_follows", "non_followers"])
  84
  85     params = %{notification_settings: notification_settings}
  86
  87     info
  88     |> cast(params, [:notification_settings])
  89     |> validate_required([:notification_settings])
  90   end
  91
  92   def add_to_note_count(info, number) do
  93     set_note_count(info, info.note_count + number)
  94   end
  95
  96   def set_note_count(info, number) do
  97     params = %{note_count: Enum.max([0, number])}
  98
  99     info
 100     |> cast(params, [:note_count])
 101     |> validate_required([:note_count])
 102   end
 103
 104   def set_follower_count(info, number) do
 105     params = %{follower_count: Enum.max([0, number])}
 106
 107     info
 108     |> cast(params, [:follower_count])
 109     |> validate_required([:follower_count])
 110   end
 111
 112   def set_mutes(info, mutes) do
 113     params = %{mutes: mutes}
 114
 115     info
 116     |> cast(params, [:mutes])
 117     |> validate_required([:mutes])
 118   end
 119
 120   def set_blocks(info, blocks) do
 121     params = %{blocks: blocks}
 122
 123     info
 124     |> cast(params, [:blocks])
 125     |> validate_required([:blocks])
 126   end
 127
 128   def set_subscribers(info, subscribers) do
 129     params = %{subscribers: subscribers}
 130
 131     info
 132     |> cast(params, [:subscribers])
 133     |> validate_required([:subscribers])
 134   end
 135
 136   def add_to_mutes(info, muted) do
 137     set_mutes(info, Enum.uniq([muted | info.mutes]))
 138   end
 139
 140   def remove_from_mutes(info, muted) do
 141     set_mutes(info, List.delete(info.mutes, muted))
 142   end
 143
 144   def add_to_block(info, blocked) do
 145     set_blocks(info, Enum.uniq([blocked | info.blocks]))
 146   end
 147
 148   def remove_from_block(info, blocked) do
 149     set_blocks(info, List.delete(info.blocks, blocked))
 150   end
 151
 152   def add_to_subscribers(info, subscribed) do
 153     set_subscribers(info, Enum.uniq([subscribed | info.subscribers]))
 154   end
 155
 156   def remove_from_subscribers(info, subscribed) do
 157     set_subscribers(info, List.delete(info.subscribers, subscribed))
 158   end
 159
 160   def set_domain_blocks(info, domain_blocks) do
 161     params = %{domain_blocks: domain_blocks}
 162
 163     info
 164     |> cast(params, [:domain_blocks])
 165     |> validate_required([:domain_blocks])
 166   end
 167
 168   def add_to_domain_block(info, domain_blocked) do
 169     set_domain_blocks(info, Enum.uniq([domain_blocked | info.domain_blocks]))
 170   end
 171
 172   def remove_from_domain_block(info, domain_blocked) do
 173     set_domain_blocks(info, List.delete(info.domain_blocks, domain_blocked))
 174   end
 175
 176   def set_keys(info, keys) do
 177     params = %{keys: keys}
 178
 179     info
 180     |> cast(params, [:keys])
 181     |> validate_required([:keys])
 182   end
 183
 184   def remote_user_creation(info, params) do
 185     info
 186     |> cast(params, [
 187       :ap_enabled,
 188       :source_data,
 189       :banner,
 190       :locked,
 191       :magic_key,
 192       :uri,
 193       :hub,
 194       :topic,
 195       :salmon
 196     ])
 197   end
 198
 199   def user_upgrade(info, params) do
 200     info
 201     |> cast(params, [
 202       :ap_enabled,
 203       :source_data,
 204       :banner,
 205       :locked,
 206       :magic_key
 207     ])
 208   end
 209
 210   def profile_update(info, params) do
 211     info
 212     |> cast(params, [
 213       :locked,
 214       :no_rich_text,
 215       :default_scope,
 216       :banner,
 217       :hide_follows,
 218       :hide_followers,
 219       :hide_favorites,
 220       :background,
 221       :show_role
 222     ])
 223   end
 224
 225   @spec confirmation_changeset(Info.t(), keyword()) :: Changeset.t()
 226   def confirmation_changeset(info, opts) do
 227     need_confirmation? = Keyword.get(opts, :need_confirmation)
 228
 229     params =
 230       if need_confirmation? do
 231         %{
 232           confirmation_pending: true,
 233           confirmation_token: :crypto.strong_rand_bytes(32) |> Base.url_encode64()
 234         }
 235       else
 236         %{
 237           confirmation_pending: false,
 238           confirmation_token: nil
 239         }
 240       end
 241
 242     cast(info, params, [:confirmation_pending, :confirmation_token])
 243   end
 244
 245   def mastodon_settings_update(info, settings) do
 246     params = %{settings: settings}
 247
 248     info
 249     |> cast(params, [:settings])
 250     |> validate_required([:settings])
 251   end
 252
 253   def mascot_update(info, url) do
 254     params = %{mascot: url}
 255
 256     info
 257     |> cast(params, [:mascot])
 258     |> validate_required([:mascot])
 259   end
 260
 261   def set_source_data(info, source_data) do
 262     params = %{source_data: source_data}
 263
 264     info
 265     |> cast(params, [:source_data])
 266     |> validate_required([:source_data])
 267   end
 268
 269   def admin_api_update(info, params) do
 270     info
 271     |> cast(params, [
 272       :is_moderator,
 273       :is_admin,
 274       :show_role
 275     ])
 276   end
 277
 278   def add_pinnned_activity(info, %Pleroma.Activity{id: id}) do
 279     if id not in info.pinned_activities do
 280       max_pinned_statuses = Pleroma.Config.get([:instance, :max_pinned_statuses], 0)
 281       params = %{pinned_activities: info.pinned_activities ++ [id]}
 282
 283       info
 284       |> cast(params, [:pinned_activities])
 285       |> validate_length(:pinned_activities,
 286         max: max_pinned_statuses,
 287         message: "You have already pinned the maximum number of statuses"
 288       )
 289     else
 290       change(info)
 291     end
 292   end
 293
 294   def remove_pinnned_activity(info, %Pleroma.Activity{id: id}) do
 295     params = %{pinned_activities: List.delete(info.pinned_activities, id)}
 296
 297     cast(info, params, [:pinned_activities])
 298   end
 299
 300   def roles(%Info{is_moderator: is_moderator, is_admin: is_admin}) do
 301     %{
 302       admin: is_admin,
 303       moderator: is_moderator
 304     }
 305   end
 306
 307   def add_reblog_mute(info, ap_id) do
 308     params = %{muted_reblogs: info.muted_reblogs ++ [ap_id]}
 309
 310     cast(info, params, [:muted_reblogs])
 311   end
 312
 313   def remove_reblog_mute(info, ap_id) do
 314     params = %{muted_reblogs: List.delete(info.muted_reblogs, ap_id)}
 315
 316     cast(info, params, [:muted_reblogs])
 317   end
 318 end