git.squeep.com Git - akkoma/blob - lib/pleroma/user/info.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2019 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.User.Info do
   6   use Ecto.Schema
   7   import Ecto.Changeset
   8
   9   embedded_schema do
  10     field(:banner, :map, default: %{})
  11     field(:background, :map, default: %{})
  12     field(:source_data, :map, default: %{})
  13     field(:note_count, :integer, default: 0)
  14     field(:follower_count, :integer, default: 0)
  15     field(:locked, :boolean, default: false)
  16     field(:confirmation_pending, :boolean, default: false)
  17     field(:confirmation_token, :string, default: nil)
  18     field(:default_scope, :string, default: "public")
  19     field(:blocks, {:array, :string}, default: [])
  20     field(:domain_blocks, {:array, :string}, default: [])
  21     field(:mutes, {:array, :string}, default: [])
  22     field(:deactivated, :boolean, default: false)
  23     field(:no_rich_text, :boolean, default: false)
  24     field(:ap_enabled, :boolean, default: false)
  25     field(:is_moderator, :boolean, default: false)
  26     field(:is_admin, :boolean, default: false)
  27     field(:show_role, :boolean, default: true)
  28     field(:keys, :string, default: nil)
  29     field(:settings, :map, default: nil)
  30     field(:magic_key, :string, default: nil)
  31     field(:uri, :string, default: nil)
  32     field(:topic, :string, default: nil)
  33     field(:hub, :string, default: nil)
  34     field(:salmon, :string, default: nil)
  35     field(:hide_followers, :boolean, default: false)
  36     field(:hide_follows, :boolean, default: false)
  37     field(:pinned_activities, {:array, :string}, default: [])
  38     field(:flavour, :string, default: nil)
  39
  40     # Found in the wild
  41     # ap_id -> Where is this used?
  42     # bio -> Where is this used?
  43     # avatar -> Where is this used?
  44     # fqn -> Where is this used?
  45     # host -> Where is this used?
  46     # subject _> Where is this used?
  47   end
  48
  49   def set_activation_status(info, deactivated) do
  50     params = %{deactivated: deactivated}
  51
  52     info
  53     |> cast(params, [:deactivated])
  54     |> validate_required([:deactivated])
  55   end
  56
  57   def add_to_note_count(info, number) do
  58     set_note_count(info, info.note_count + number)
  59   end
  60
  61   def set_note_count(info, number) do
  62     params = %{note_count: Enum.max([0, number])}
  63
  64     info
  65     |> cast(params, [:note_count])
  66     |> validate_required([:note_count])
  67   end
  68
  69   def set_follower_count(info, number) do
  70     params = %{follower_count: Enum.max([0, number])}
  71
  72     info
  73     |> cast(params, [:follower_count])
  74     |> validate_required([:follower_count])
  75   end
  76
  77   def set_mutes(info, mutes) do
  78     params = %{mutes: mutes}
  79
  80     info
  81     |> cast(params, [:mutes])
  82     |> validate_required([:mutes])
  83   end
  84
  85   def set_blocks(info, blocks) do
  86     params = %{blocks: blocks}
  87
  88     info
  89     |> cast(params, [:blocks])
  90     |> validate_required([:blocks])
  91   end
  92
  93   def add_to_mutes(info, muted) do
  94     set_mutes(info, Enum.uniq([muted | info.mutes]))
  95   end
  96
  97   def remove_from_mutes(info, muted) do
  98     set_mutes(info, List.delete(info.mutes, muted))
  99   end
 100
 101   def add_to_block(info, blocked) do
 102     set_blocks(info, Enum.uniq([blocked | info.blocks]))
 103   end
 104
 105   def remove_from_block(info, blocked) do
 106     set_blocks(info, List.delete(info.blocks, blocked))
 107   end
 108
 109   def set_domain_blocks(info, domain_blocks) do
 110     params = %{domain_blocks: domain_blocks}
 111
 112     info
 113     |> cast(params, [:domain_blocks])
 114     |> validate_required([:domain_blocks])
 115   end
 116
 117   def add_to_domain_block(info, domain_blocked) do
 118     set_domain_blocks(info, Enum.uniq([domain_blocked | info.domain_blocks]))
 119   end
 120
 121   def remove_from_domain_block(info, domain_blocked) do
 122     set_domain_blocks(info, List.delete(info.domain_blocks, domain_blocked))
 123   end
 124
 125   def set_keys(info, keys) do
 126     params = %{keys: keys}
 127
 128     info
 129     |> cast(params, [:keys])
 130     |> validate_required([:keys])
 131   end
 132
 133   def remote_user_creation(info, params) do
 134     info
 135     |> cast(params, [
 136       :ap_enabled,
 137       :source_data,
 138       :banner,
 139       :locked,
 140       :magic_key,
 141       :uri,
 142       :hub,
 143       :topic,
 144       :salmon
 145     ])
 146   end
 147
 148   def user_upgrade(info, params) do
 149     info
 150     |> cast(params, [
 151       :ap_enabled,
 152       :source_data,
 153       :banner,
 154       :locked,
 155       :magic_key
 156     ])
 157   end
 158
 159   def profile_update(info, params) do
 160     info
 161     |> cast(params, [
 162       :locked,
 163       :no_rich_text,
 164       :default_scope,
 165       :banner,
 166       :hide_follows,
 167       :hide_followers,
 168       :background,
 169       :show_role
 170     ])
 171   end
 172
 173   def confirmation_changeset(info, :confirmed) do
 174     confirmation_changeset(info, %{
 175       confirmation_pending: false,
 176       confirmation_token: nil
 177     })
 178   end
 179
 180   def confirmation_changeset(info, :unconfirmed) do
 181     confirmation_changeset(info, %{
 182       confirmation_pending: true,
 183       confirmation_token: :crypto.strong_rand_bytes(32) |> Base.url_encode64()
 184     })
 185   end
 186
 187   def confirmation_changeset(info, params) do
 188     cast(info, params, [:confirmation_pending, :confirmation_token])
 189   end
 190
 191   def mastodon_profile_update(info, params) do
 192     info
 193     |> cast(params, [
 194       :locked,
 195       :banner
 196     ])
 197   end
 198
 199   def mastodon_settings_update(info, settings) do
 200     params = %{settings: settings}
 201
 202     info
 203     |> cast(params, [:settings])
 204     |> validate_required([:settings])
 205   end
 206
 207   def mastodon_flavour_update(info, flavour) do
 208     params = %{flavour: flavour}
 209
 210     info
 211     |> cast(params, [:flavour])
 212     |> validate_required([:flavour])
 213   end
 214
 215   def set_source_data(info, source_data) do
 216     params = %{source_data: source_data}
 217
 218     info
 219     |> cast(params, [:source_data])
 220     |> validate_required([:source_data])
 221   end
 222
 223   def admin_api_update(info, params) do
 224     info
 225     |> cast(params, [
 226       :is_moderator,
 227       :is_admin,
 228       :show_role
 229     ])
 230   end
 231
 232   def add_pinnned_activity(info, %Pleroma.Activity{id: id}) do
 233     if id not in info.pinned_activities do
 234       max_pinned_statuses = Pleroma.Config.get([:instance, :max_pinned_statuses], 0)
 235       params = %{pinned_activities: info.pinned_activities ++ [id]}
 236
 237       info
 238       |> cast(params, [:pinned_activities])
 239       |> validate_length(:pinned_activities,
 240         max: max_pinned_statuses,
 241         message: "You have already pinned the maximum number of statuses"
 242       )
 243     else
 244       change(info)
 245     end
 246   end
 247
 248   def remove_pinnned_activity(info, %Pleroma.Activity{id: id}) do
 249     params = %{pinned_activities: List.delete(info.pinned_activities, id)}
 250
 251     cast(info, params, [:pinned_activities])
 252   end
 253 end