git.squeep.com Git - akkoma/blob - lib/pleroma/user/info.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2019 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.User.Info do
   6   use Ecto.Schema
   7   import Ecto.Changeset
   8
   9   alias Pleroma.User.Info
  10
  11   @type t :: %__MODULE__{}
  12
  13   embedded_schema do
  14     field(:banner, :map, default: %{})
  15     field(:background, :map, default: %{})
  16     field(:source_data, :map, default: %{})
  17     field(:note_count, :integer, default: 0)
  18     field(:follower_count, :integer, default: 0)
  19     # Should be filled in only for remote users
  20     field(:following_count, :integer, default: nil)
  21     field(:locked, :boolean, default: false)
  22     field(:confirmation_pending, :boolean, default: false)
  23     field(:confirmation_token, :string, default: nil)
  24     field(:default_scope, :string, default: "public")
  25     field(:blocks, {:array, :string}, default: [])
  26     field(:domain_blocks, {:array, :string}, default: [])
  27     field(:mutes, {:array, :string}, default: [])
  28     field(:muted_reblogs, {:array, :string}, default: [])
  29     field(:subscribers, {:array, :string}, default: [])
  30     field(:deactivated, :boolean, default: false)
  31     field(:no_rich_text, :boolean, default: false)
  32     field(:ap_enabled, :boolean, default: false)
  33     field(:is_moderator, :boolean, default: false)
  34     field(:is_admin, :boolean, default: false)
  35     field(:show_role, :boolean, default: true)
  36     field(:keys, :string, default: nil)
  37     field(:settings, :map, default: nil)
  38     field(:magic_key, :string, default: nil)
  39     field(:uri, :string, default: nil)
  40     field(:topic, :string, default: nil)
  41     field(:hub, :string, default: nil)
  42     field(:salmon, :string, default: nil)
  43     field(:hide_followers, :boolean, default: false)
  44     field(:hide_follows, :boolean, default: false)
  45     field(:hide_favorites, :boolean, default: true)
  46     field(:pinned_activities, {:array, :string}, default: [])
  47     field(:mascot, :map, default: nil)
  48     field(:emoji, {:array, :map}, default: [])
  49     field(:pleroma_settings_store, :map, default: %{})
  50
  51     field(:notification_settings, :map,
  52       default: %{
  53         "followers" => true,
  54         "follows" => true,
  55         "non_follows" => true,
  56         "non_followers" => true
  57       }
  58     )
  59
  60     field(:skip_thread_containment, :boolean, default: false)
  61
  62     # Found in the wild
  63     # ap_id -> Where is this used?
  64     # bio -> Where is this used?
  65     # avatar -> Where is this used?
  66     # fqn -> Where is this used?
  67     # host -> Where is this used?
  68     # subject _> Where is this used?
  69   end
  70
  71   def set_activation_status(info, deactivated) do
  72     params = %{deactivated: deactivated}
  73
  74     info
  75     |> cast(params, [:deactivated])
  76     |> validate_required([:deactivated])
  77   end
  78
  79   def update_notification_settings(info, settings) do
  80     settings =
  81       settings
  82       |> Enum.map(fn {k, v} -> {k, v in [true, "true", "True", "1"]} end)
  83       |> Map.new()
  84
  85     notification_settings =
  86       info.notification_settings
  87       |> Map.merge(settings)
  88       |> Map.take(["followers", "follows", "non_follows", "non_followers"])
  89
  90     params = %{notification_settings: notification_settings}
  91
  92     info
  93     |> cast(params, [:notification_settings])
  94     |> validate_required([:notification_settings])
  95   end
  96
  97   def add_to_note_count(info, number) do
  98     set_note_count(info, info.note_count + number)
  99   end
 100
 101   def set_note_count(info, number) do
 102     params = %{note_count: Enum.max([0, number])}
 103
 104     info
 105     |> cast(params, [:note_count])
 106     |> validate_required([:note_count])
 107   end
 108
 109   def set_follower_count(info, number) do
 110     params = %{follower_count: Enum.max([0, number])}
 111
 112     info
 113     |> cast(params, [:follower_count])
 114     |> validate_required([:follower_count])
 115   end
 116
 117   def set_mutes(info, mutes) do
 118     params = %{mutes: mutes}
 119
 120     info
 121     |> cast(params, [:mutes])
 122     |> validate_required([:mutes])
 123   end
 124
 125   def set_blocks(info, blocks) do
 126     params = %{blocks: blocks}
 127
 128     info
 129     |> cast(params, [:blocks])
 130     |> validate_required([:blocks])
 131   end
 132
 133   def set_subscribers(info, subscribers) do
 134     params = %{subscribers: subscribers}
 135
 136     info
 137     |> cast(params, [:subscribers])
 138     |> validate_required([:subscribers])
 139   end
 140
 141   def add_to_mutes(info, muted) do
 142     set_mutes(info, Enum.uniq([muted | info.mutes]))
 143   end
 144
 145   def remove_from_mutes(info, muted) do
 146     set_mutes(info, List.delete(info.mutes, muted))
 147   end
 148
 149   def add_to_block(info, blocked) do
 150     set_blocks(info, Enum.uniq([blocked | info.blocks]))
 151   end
 152
 153   def remove_from_block(info, blocked) do
 154     set_blocks(info, List.delete(info.blocks, blocked))
 155   end
 156
 157   def add_to_subscribers(info, subscribed) do
 158     set_subscribers(info, Enum.uniq([subscribed | info.subscribers]))
 159   end
 160
 161   def remove_from_subscribers(info, subscribed) do
 162     set_subscribers(info, List.delete(info.subscribers, subscribed))
 163   end
 164
 165   def set_domain_blocks(info, domain_blocks) do
 166     params = %{domain_blocks: domain_blocks}
 167
 168     info
 169     |> cast(params, [:domain_blocks])
 170     |> validate_required([:domain_blocks])
 171   end
 172
 173   def add_to_domain_block(info, domain_blocked) do
 174     set_domain_blocks(info, Enum.uniq([domain_blocked | info.domain_blocks]))
 175   end
 176
 177   def remove_from_domain_block(info, domain_blocked) do
 178     set_domain_blocks(info, List.delete(info.domain_blocks, domain_blocked))
 179   end
 180
 181   def set_keys(info, keys) do
 182     params = %{keys: keys}
 183
 184     info
 185     |> cast(params, [:keys])
 186     |> validate_required([:keys])
 187   end
 188
 189   def remote_user_creation(info, params) do
 190     info
 191     |> cast(params, [
 192       :ap_enabled,
 193       :source_data,
 194       :banner,
 195       :locked,
 196       :magic_key,
 197       :uri,
 198       :hub,
 199       :topic,
 200       :salmon,
 201       :hide_followers,
 202       :hide_follows,
 203       :follower_count,
 204       :following_count
 205     ])
 206   end
 207
 208   def user_upgrade(info, params) do
 209     info
 210     |> cast(params, [
 211       :ap_enabled,
 212       :source_data,
 213       :banner,
 214       :locked,
 215       :magic_key,
 216       :follower_count,
 217       :following_count,
 218       :hide_follows,
 219       :hide_followers
 220     ])
 221   end
 222
 223   def profile_update(info, params) do
 224     info
 225     |> cast(params, [
 226       :locked,
 227       :no_rich_text,
 228       :default_scope,
 229       :banner,
 230       :hide_follows,
 231       :hide_followers,
 232       :hide_favorites,
 233       :background,
 234       :show_role,
 235       :skip_thread_containment,
 236       :pleroma_settings_store
 237     ])
 238   end
 239
 240   @spec confirmation_changeset(Info.t(), keyword()) :: Changeset.t()
 241   def confirmation_changeset(info, opts) do
 242     need_confirmation? = Keyword.get(opts, :need_confirmation)
 243
 244     params =
 245       if need_confirmation? do
 246         %{
 247           confirmation_pending: true,
 248           confirmation_token: :crypto.strong_rand_bytes(32) |> Base.url_encode64()
 249         }
 250       else
 251         %{
 252           confirmation_pending: false,
 253           confirmation_token: nil
 254         }
 255       end
 256
 257     cast(info, params, [:confirmation_pending, :confirmation_token])
 258   end
 259
 260   def mastodon_settings_update(info, settings) do
 261     params = %{settings: settings}
 262
 263     info
 264     |> cast(params, [:settings])
 265     |> validate_required([:settings])
 266   end
 267
 268   def mascot_update(info, url) do
 269     params = %{mascot: url}
 270
 271     info
 272     |> cast(params, [:mascot])
 273     |> validate_required([:mascot])
 274   end
 275
 276   def set_source_data(info, source_data) do
 277     params = %{source_data: source_data}
 278
 279     info
 280     |> cast(params, [:source_data])
 281     |> validate_required([:source_data])
 282   end
 283
 284   def admin_api_update(info, params) do
 285     info
 286     |> cast(params, [
 287       :is_moderator,
 288       :is_admin,
 289       :show_role
 290     ])
 291   end
 292
 293   def add_pinnned_activity(info, %Pleroma.Activity{id: id}) do
 294     if id not in info.pinned_activities do
 295       max_pinned_statuses = Pleroma.Config.get([:instance, :max_pinned_statuses], 0)
 296       params = %{pinned_activities: info.pinned_activities ++ [id]}
 297
 298       info
 299       |> cast(params, [:pinned_activities])
 300       |> validate_length(:pinned_activities,
 301         max: max_pinned_statuses,
 302         message: "You have already pinned the maximum number of statuses"
 303       )
 304     else
 305       change(info)
 306     end
 307   end
 308
 309   def remove_pinnned_activity(info, %Pleroma.Activity{id: id}) do
 310     params = %{pinned_activities: List.delete(info.pinned_activities, id)}
 311
 312     cast(info, params, [:pinned_activities])
 313   end
 314
 315   def roles(%Info{is_moderator: is_moderator, is_admin: is_admin}) do
 316     %{
 317       admin: is_admin,
 318       moderator: is_moderator
 319     }
 320   end
 321
 322   def add_reblog_mute(info, ap_id) do
 323     params = %{muted_reblogs: info.muted_reblogs ++ [ap_id]}
 324
 325     cast(info, params, [:muted_reblogs])
 326   end
 327
 328   def remove_reblog_mute(info, ap_id) do
 329     params = %{muted_reblogs: List.delete(info.muted_reblogs, ap_id)}
 330
 331     cast(info, params, [:muted_reblogs])
 332   end
 333 end