git.squeep.com Git - akkoma/blob - lib/pleroma/user/info.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2019 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.User.Info do
   6   use Ecto.Schema
   7   import Ecto.Changeset
   8
   9   alias Pleroma.User.Info
  10
  11   @type t :: %__MODULE__{}
  12
  13   embedded_schema do
  14     field(:banner, :map, default: %{})
  15     field(:background, :map, default: %{})
  16     field(:source_data, :map, default: %{})
  17     field(:note_count, :integer, default: 0)
  18     field(:follower_count, :integer, default: 0)
  19     field(:locked, :boolean, default: false)
  20     field(:confirmation_pending, :boolean, default: false)
  21     field(:confirmation_token, :string, default: nil)
  22     field(:default_scope, :string, default: "public")
  23     field(:blocks, {:array, :string}, default: [])
  24     field(:domain_blocks, {:array, :string}, default: [])
  25     field(:mutes, {:array, :string}, default: [])
  26     field(:muted_reblogs, {:array, :string}, default: [])
  27     field(:subscribers, {:array, :string}, default: [])
  28     field(:deactivated, :boolean, default: false)
  29     field(:no_rich_text, :boolean, default: false)
  30     field(:ap_enabled, :boolean, default: false)
  31     field(:is_moderator, :boolean, default: false)
  32     field(:is_admin, :boolean, default: false)
  33     field(:show_role, :boolean, default: true)
  34     field(:keys, :string, default: nil)
  35     field(:settings, :map, default: nil)
  36     field(:magic_key, :string, default: nil)
  37     field(:uri, :string, default: nil)
  38     field(:topic, :string, default: nil)
  39     field(:hub, :string, default: nil)
  40     field(:salmon, :string, default: nil)
  41     field(:hide_followers, :boolean, default: false)
  42     field(:hide_follows, :boolean, default: false)
  43     field(:hide_favorites, :boolean, default: true)
  44     field(:pinned_activities, {:array, :string}, default: [])
  45     field(:flavour, :string, default: nil)
  46     field(:email_notifications, :map, default: %{"digest" => false})
  47
  48     field(:notification_settings, :map,
  49       default: %{"remote" => true, "local" => true, "followers" => true, "follows" => true}
  50     )
  51
  52     # Found in the wild
  53     # ap_id -> Where is this used?
  54     # bio -> Where is this used?
  55     # avatar -> Where is this used?
  56     # fqn -> Where is this used?
  57     # host -> Where is this used?
  58     # subject _> Where is this used?
  59   end
  60
  61   def set_activation_status(info, deactivated) do
  62     params = %{deactivated: deactivated}
  63
  64     info
  65     |> cast(params, [:deactivated])
  66     |> validate_required([:deactivated])
  67   end
  68
  69   def update_notification_settings(info, settings) do
  70     notification_settings =
  71       info.notification_settings
  72       |> Map.merge(settings)
  73       |> Map.take(["remote", "local", "followers", "follows"])
  74
  75     params = %{notification_settings: notification_settings}
  76
  77     info
  78     |> cast(params, [:notification_settings])
  79     |> validate_required([:notification_settings])
  80   end
  81
  82   @doc """
  83   Update email notifications in the given User.Info struct.
  84
  85   Examples:
  86
  87       iex> update_email_notifications(%Pleroma.User.Info{email_notifications: %{"digest" => false}}, %{"digest" => true})
  88       %Pleroma.User.Info{email_notifications: %{"digest" => true}}
  89
  90   """
  91   @spec update_email_notifications(t(), map()) :: Ecto.Changeset.t()
  92   def update_email_notifications(info, settings) do
  93     email_notifications =
  94       info.email_notifications
  95       |> Map.merge(settings)
  96       |> Map.take(["digest"])
  97
  98     params = %{email_notifications: email_notifications}
  99     fields = [:email_notifications]
 100
 101     info
 102     |> cast(params, fields)
 103     |> validate_required(fields)
 104   end
 105
 106   def add_to_note_count(info, number) do
 107     set_note_count(info, info.note_count + number)
 108   end
 109
 110   def set_note_count(info, number) do
 111     params = %{note_count: Enum.max([0, number])}
 112
 113     info
 114     |> cast(params, [:note_count])
 115     |> validate_required([:note_count])
 116   end
 117
 118   def set_follower_count(info, number) do
 119     params = %{follower_count: Enum.max([0, number])}
 120
 121     info
 122     |> cast(params, [:follower_count])
 123     |> validate_required([:follower_count])
 124   end
 125
 126   def set_mutes(info, mutes) do
 127     params = %{mutes: mutes}
 128
 129     info
 130     |> cast(params, [:mutes])
 131     |> validate_required([:mutes])
 132   end
 133
 134   def set_blocks(info, blocks) do
 135     params = %{blocks: blocks}
 136
 137     info
 138     |> cast(params, [:blocks])
 139     |> validate_required([:blocks])
 140   end
 141
 142   def set_subscribers(info, subscribers) do
 143     params = %{subscribers: subscribers}
 144
 145     info
 146     |> cast(params, [:subscribers])
 147     |> validate_required([:subscribers])
 148   end
 149
 150   def add_to_mutes(info, muted) do
 151     set_mutes(info, Enum.uniq([muted | info.mutes]))
 152   end
 153
 154   def remove_from_mutes(info, muted) do
 155     set_mutes(info, List.delete(info.mutes, muted))
 156   end
 157
 158   def add_to_block(info, blocked) do
 159     set_blocks(info, Enum.uniq([blocked | info.blocks]))
 160   end
 161
 162   def remove_from_block(info, blocked) do
 163     set_blocks(info, List.delete(info.blocks, blocked))
 164   end
 165
 166   def add_to_subscribers(info, subscribed) do
 167     set_subscribers(info, Enum.uniq([subscribed | info.subscribers]))
 168   end
 169
 170   def remove_from_subscribers(info, subscribed) do
 171     set_subscribers(info, List.delete(info.subscribers, subscribed))
 172   end
 173
 174   def set_domain_blocks(info, domain_blocks) do
 175     params = %{domain_blocks: domain_blocks}
 176
 177     info
 178     |> cast(params, [:domain_blocks])
 179     |> validate_required([:domain_blocks])
 180   end
 181
 182   def add_to_domain_block(info, domain_blocked) do
 183     set_domain_blocks(info, Enum.uniq([domain_blocked | info.domain_blocks]))
 184   end
 185
 186   def remove_from_domain_block(info, domain_blocked) do
 187     set_domain_blocks(info, List.delete(info.domain_blocks, domain_blocked))
 188   end
 189
 190   def set_keys(info, keys) do
 191     params = %{keys: keys}
 192
 193     info
 194     |> cast(params, [:keys])
 195     |> validate_required([:keys])
 196   end
 197
 198   def remote_user_creation(info, params) do
 199     info
 200     |> cast(params, [
 201       :ap_enabled,
 202       :source_data,
 203       :banner,
 204       :locked,
 205       :magic_key,
 206       :uri,
 207       :hub,
 208       :topic,
 209       :salmon
 210     ])
 211   end
 212
 213   def user_upgrade(info, params) do
 214     info
 215     |> cast(params, [
 216       :ap_enabled,
 217       :source_data,
 218       :banner,
 219       :locked,
 220       :magic_key
 221     ])
 222   end
 223
 224   def profile_update(info, params) do
 225     info
 226     |> cast(params, [
 227       :locked,
 228       :no_rich_text,
 229       :default_scope,
 230       :banner,
 231       :hide_follows,
 232       :hide_followers,
 233       :hide_favorites,
 234       :background,
 235       :show_role
 236     ])
 237   end
 238
 239   def confirmation_changeset(info, :confirmed) do
 240     confirmation_changeset(info, %{
 241       confirmation_pending: false,
 242       confirmation_token: nil
 243     })
 244   end
 245
 246   def confirmation_changeset(info, :unconfirmed) do
 247     confirmation_changeset(info, %{
 248       confirmation_pending: true,
 249       confirmation_token: :crypto.strong_rand_bytes(32) |> Base.url_encode64()
 250     })
 251   end
 252
 253   def confirmation_changeset(info, params) do
 254     cast(info, params, [:confirmation_pending, :confirmation_token])
 255   end
 256
 257   def mastodon_settings_update(info, settings) do
 258     params = %{settings: settings}
 259
 260     info
 261     |> cast(params, [:settings])
 262     |> validate_required([:settings])
 263   end
 264
 265   def mastodon_flavour_update(info, flavour) do
 266     params = %{flavour: flavour}
 267
 268     info
 269     |> cast(params, [:flavour])
 270     |> validate_required([:flavour])
 271   end
 272
 273   def set_source_data(info, source_data) do
 274     params = %{source_data: source_data}
 275
 276     info
 277     |> cast(params, [:source_data])
 278     |> validate_required([:source_data])
 279   end
 280
 281   def admin_api_update(info, params) do
 282     info
 283     |> cast(params, [
 284       :is_moderator,
 285       :is_admin,
 286       :show_role
 287     ])
 288   end
 289
 290   def add_pinnned_activity(info, %Pleroma.Activity{id: id}) do
 291     if id not in info.pinned_activities do
 292       max_pinned_statuses = Pleroma.Config.get([:instance, :max_pinned_statuses], 0)
 293       params = %{pinned_activities: info.pinned_activities ++ [id]}
 294
 295       info
 296       |> cast(params, [:pinned_activities])
 297       |> validate_length(:pinned_activities,
 298         max: max_pinned_statuses,
 299         message: "You have already pinned the maximum number of statuses"
 300       )
 301     else
 302       change(info)
 303     end
 304   end
 305
 306   def remove_pinnned_activity(info, %Pleroma.Activity{id: id}) do
 307     params = %{pinned_activities: List.delete(info.pinned_activities, id)}
 308
 309     cast(info, params, [:pinned_activities])
 310   end
 311
 312   def roles(%Info{is_moderator: is_moderator, is_admin: is_admin}) do
 313     %{
 314       admin: is_admin,
 315       moderator: is_moderator
 316     }
 317   end
 318
 319   def add_reblog_mute(info, ap_id) do
 320     params = %{muted_reblogs: info.muted_reblogs ++ [ap_id]}
 321
 322     cast(info, params, [:muted_reblogs])
 323   end
 324
 325   def remove_reblog_mute(info, ap_id) do
 326     params = %{muted_reblogs: List.delete(info.muted_reblogs, ap_id)}
 327
 328     cast(info, params, [:muted_reblogs])
 329   end
 330 end