git.squeep.com Git - akkoma/blob - lib/pleroma/user/info.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2019 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.User.Info do
   6   use Ecto.Schema
   7   import Ecto.Changeset
   8
   9   alias Pleroma.User.Info
  10
  11   @type t :: %__MODULE__{}
  12
  13   embedded_schema do
  14     field(:banner, :map, default: %{})
  15     field(:background, :map, default: %{})
  16     field(:source_data, :map, default: %{})
  17     field(:note_count, :integer, default: 0)
  18     field(:follower_count, :integer, default: 0)
  19     field(:locked, :boolean, default: false)
  20     field(:confirmation_pending, :boolean, default: false)
  21     field(:confirmation_token, :string, default: nil)
  22     field(:default_scope, :string, default: "public")
  23     field(:blocks, {:array, :string}, default: [])
  24     field(:domain_blocks, {:array, :string}, default: [])
  25     field(:mutes, {:array, :string}, default: [])
  26     field(:muted_reblogs, {:array, :string}, default: [])
  27     field(:subscribers, {:array, :string}, default: [])
  28     field(:deactivated, :boolean, default: false)
  29     field(:no_rich_text, :boolean, default: false)
  30     field(:ap_enabled, :boolean, default: false)
  31     field(:is_moderator, :boolean, default: false)
  32     field(:is_admin, :boolean, default: false)
  33     field(:show_role, :boolean, default: true)
  34     field(:keys, :string, default: nil)
  35     field(:settings, :map, default: nil)
  36     field(:magic_key, :string, default: nil)
  37     field(:uri, :string, default: nil)
  38     field(:topic, :string, default: nil)
  39     field(:hub, :string, default: nil)
  40     field(:salmon, :string, default: nil)
  41     field(:hide_followers, :boolean, default: false)
  42     field(:hide_follows, :boolean, default: false)
  43     field(:hide_favorites, :boolean, default: true)
  44     field(:pinned_activities, {:array, :string}, default: [])
  45     field(:mascot, :map, default: nil)
  46     field(:emoji, {:array, :map}, default: [])
  47     field(:pleroma_settings_store, :map, default: %{})
  48
  49     field(:notification_settings, :map,
  50       default: %{
  51         "followers" => true,
  52         "follows" => true,
  53         "non_follows" => true,
  54         "non_followers" => true
  55       }
  56     )
  57
  58     field(:skip_thread_containment, :boolean, default: false)
  59
  60     # Found in the wild
  61     # ap_id -> Where is this used?
  62     # bio -> Where is this used?
  63     # avatar -> Where is this used?
  64     # fqn -> Where is this used?
  65     # host -> Where is this used?
  66     # subject _> Where is this used?
  67   end
  68
  69   def set_activation_status(info, deactivated) do
  70     params = %{deactivated: deactivated}
  71
  72     info
  73     |> cast(params, [:deactivated])
  74     |> validate_required([:deactivated])
  75   end
  76
  77   def update_notification_settings(info, settings) do
  78     settings =
  79       settings
  80       |> Enum.map(fn {k, v} -> {k, v in [true, "true", "True", "1"]} end)
  81       |> Map.new()
  82
  83     notification_settings =
  84       info.notification_settings
  85       |> Map.merge(settings)
  86       |> Map.take(["followers", "follows", "non_follows", "non_followers"])
  87
  88     params = %{notification_settings: notification_settings}
  89
  90     info
  91     |> cast(params, [:notification_settings])
  92     |> validate_required([:notification_settings])
  93   end
  94
  95   def add_to_note_count(info, number) do
  96     set_note_count(info, info.note_count + number)
  97   end
  98
  99   def set_note_count(info, number) do
 100     params = %{note_count: Enum.max([0, number])}
 101
 102     info
 103     |> cast(params, [:note_count])
 104     |> validate_required([:note_count])
 105   end
 106
 107   def set_follower_count(info, number) do
 108     params = %{follower_count: Enum.max([0, number])}
 109
 110     info
 111     |> cast(params, [:follower_count])
 112     |> validate_required([:follower_count])
 113   end
 114
 115   def set_mutes(info, mutes) do
 116     params = %{mutes: mutes}
 117
 118     info
 119     |> cast(params, [:mutes])
 120     |> validate_required([:mutes])
 121   end
 122
 123   def set_blocks(info, blocks) do
 124     params = %{blocks: blocks}
 125
 126     info
 127     |> cast(params, [:blocks])
 128     |> validate_required([:blocks])
 129   end
 130
 131   def set_subscribers(info, subscribers) do
 132     params = %{subscribers: subscribers}
 133
 134     info
 135     |> cast(params, [:subscribers])
 136     |> validate_required([:subscribers])
 137   end
 138
 139   def add_to_mutes(info, muted) do
 140     set_mutes(info, Enum.uniq([muted | info.mutes]))
 141   end
 142
 143   def remove_from_mutes(info, muted) do
 144     set_mutes(info, List.delete(info.mutes, muted))
 145   end
 146
 147   def add_to_block(info, blocked) do
 148     set_blocks(info, Enum.uniq([blocked | info.blocks]))
 149   end
 150
 151   def remove_from_block(info, blocked) do
 152     set_blocks(info, List.delete(info.blocks, blocked))
 153   end
 154
 155   def add_to_subscribers(info, subscribed) do
 156     set_subscribers(info, Enum.uniq([subscribed | info.subscribers]))
 157   end
 158
 159   def remove_from_subscribers(info, subscribed) do
 160     set_subscribers(info, List.delete(info.subscribers, subscribed))
 161   end
 162
 163   def set_domain_blocks(info, domain_blocks) do
 164     params = %{domain_blocks: domain_blocks}
 165
 166     info
 167     |> cast(params, [:domain_blocks])
 168     |> validate_required([:domain_blocks])
 169   end
 170
 171   def add_to_domain_block(info, domain_blocked) do
 172     set_domain_blocks(info, Enum.uniq([domain_blocked | info.domain_blocks]))
 173   end
 174
 175   def remove_from_domain_block(info, domain_blocked) do
 176     set_domain_blocks(info, List.delete(info.domain_blocks, domain_blocked))
 177   end
 178
 179   def set_keys(info, keys) do
 180     params = %{keys: keys}
 181
 182     info
 183     |> cast(params, [:keys])
 184     |> validate_required([:keys])
 185   end
 186
 187   def remote_user_creation(info, params) do
 188     info
 189     |> cast(params, [
 190       :ap_enabled,
 191       :source_data,
 192       :banner,
 193       :locked,
 194       :magic_key,
 195       :uri,
 196       :hub,
 197       :topic,
 198       :salmon
 199     ])
 200   end
 201
 202   def user_upgrade(info, params) do
 203     info
 204     |> cast(params, [
 205       :ap_enabled,
 206       :source_data,
 207       :banner,
 208       :locked,
 209       :magic_key
 210     ])
 211   end
 212
 213   def profile_update(info, params) do
 214     info
 215     |> cast(params, [
 216       :locked,
 217       :no_rich_text,
 218       :default_scope,
 219       :banner,
 220       :hide_follows,
 221       :hide_followers,
 222       :hide_favorites,
 223       :background,
 224       :show_role,
 225       :skip_thread_containment,
 226       :pleroma_settings_store
 227     ])
 228   end
 229
 230   @spec confirmation_changeset(Info.t(), keyword()) :: Changeset.t()
 231   def confirmation_changeset(info, opts) do
 232     need_confirmation? = Keyword.get(opts, :need_confirmation)
 233
 234     params =
 235       if need_confirmation? do
 236         %{
 237           confirmation_pending: true,
 238           confirmation_token: :crypto.strong_rand_bytes(32) |> Base.url_encode64()
 239         }
 240       else
 241         %{
 242           confirmation_pending: false,
 243           confirmation_token: nil
 244         }
 245       end
 246
 247     cast(info, params, [:confirmation_pending, :confirmation_token])
 248   end
 249
 250   def mastodon_settings_update(info, settings) do
 251     params = %{settings: settings}
 252
 253     info
 254     |> cast(params, [:settings])
 255     |> validate_required([:settings])
 256   end
 257
 258   def mascot_update(info, url) do
 259     params = %{mascot: url}
 260
 261     info
 262     |> cast(params, [:mascot])
 263     |> validate_required([:mascot])
 264   end
 265
 266   def set_source_data(info, source_data) do
 267     params = %{source_data: source_data}
 268
 269     info
 270     |> cast(params, [:source_data])
 271     |> validate_required([:source_data])
 272   end
 273
 274   def admin_api_update(info, params) do
 275     info
 276     |> cast(params, [
 277       :is_moderator,
 278       :is_admin,
 279       :show_role
 280     ])
 281   end
 282
 283   def add_pinnned_activity(info, %Pleroma.Activity{id: id}) do
 284     if id not in info.pinned_activities do
 285       max_pinned_statuses = Pleroma.Config.get([:instance, :max_pinned_statuses], 0)
 286       params = %{pinned_activities: info.pinned_activities ++ [id]}
 287
 288       info
 289       |> cast(params, [:pinned_activities])
 290       |> validate_length(:pinned_activities,
 291         max: max_pinned_statuses,
 292         message: "You have already pinned the maximum number of statuses"
 293       )
 294     else
 295       change(info)
 296     end
 297   end
 298
 299   def remove_pinnned_activity(info, %Pleroma.Activity{id: id}) do
 300     params = %{pinned_activities: List.delete(info.pinned_activities, id)}
 301
 302     cast(info, params, [:pinned_activities])
 303   end
 304
 305   def roles(%Info{is_moderator: is_moderator, is_admin: is_admin}) do
 306     %{
 307       admin: is_admin,
 308       moderator: is_moderator
 309     }
 310   end
 311
 312   def add_reblog_mute(info, ap_id) do
 313     params = %{muted_reblogs: info.muted_reblogs ++ [ap_id]}
 314
 315     cast(info, params, [:muted_reblogs])
 316   end
 317
 318   def remove_reblog_mute(info, ap_id) do
 319     params = %{muted_reblogs: List.delete(info.muted_reblogs, ap_id)}
 320
 321     cast(info, params, [:muted_reblogs])
 322   end
 323 end