git.squeep.com Git - akkoma/blob - lib/pleroma/uploaders/s3.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2020 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Uploaders.S3 do
   6   @behaviour Pleroma.Uploaders.Uploader
   7   require Logger
   8
   9   alias Pleroma.Config
  10
  11   # The file name is re-encoded with S3's constraints here to comply with previous
  12   # links with less strict filenames
  13   @impl true
  14   def get_file(file) do
  15     config = Config.get([__MODULE__])
  16     bucket = Keyword.fetch!(config, :bucket)
  17
  18     bucket_with_namespace =
  19       cond do
  20         truncated_namespace = Keyword.get(config, :truncated_namespace) ->
  21           truncated_namespace
  22
  23         namespace = Keyword.get(config, :bucket_namespace) ->
  24           namespace <> ":" <> bucket
  25
  26         true ->
  27           bucket
  28       end
  29
  30     {:ok,
  31      {:url,
  32       Path.join([
  33         Keyword.fetch!(config, :public_endpoint),
  34         bucket_with_namespace,
  35         strict_encode(URI.decode(file))
  36       ])}}
  37   end
  38
  39   @impl true
  40   def put_file(%Pleroma.Upload{} = upload) do
  41     config = Config.get([__MODULE__])
  42     bucket = Keyword.get(config, :bucket)
  43     streaming = Keyword.get(config, :streaming_enabled)
  44
  45     s3_name = strict_encode(upload.path)
  46
  47     op =
  48       if streaming do
  49         op =
  50           upload.tempfile
  51           |> ExAws.S3.Upload.stream_file()
  52           |> ExAws.S3.upload(bucket, s3_name, [
  53             {:acl, :public_read},
  54             {:content_type, upload.content_type}
  55           ])
  56
  57         # set s3 upload timeout to respect :upload pool timeout
  58         # timeout should be slightly larger, so s3 can retry upload on fail
  59         timeout = Pleroma.HTTP.AdapterHelper.pool_timeout(:upload) + 1_000
  60         opts = Keyword.put(op.opts, :timeout, timeout)
  61         Map.put(op, :opts, opts)
  62       else
  63         {:ok, file_data} = File.read(upload.tempfile)
  64
  65         ExAws.S3.put_object(bucket, s3_name, file_data, [
  66           {:acl, :public_read},
  67           {:content_type, upload.content_type}
  68         ])
  69       end
  70
  71     case ExAws.request(op) do
  72       {:ok, _} ->
  73         {:ok, {:file, s3_name}}
  74
  75       error ->
  76         Logger.error("#{__MODULE__}: #{inspect(error)}")
  77         {:error, "S3 Upload failed"}
  78     end
  79   end
  80
  81   @impl true
  82   def delete_file(file) do
  83     [__MODULE__, :bucket]
  84     |> Config.get()
  85     |> ExAws.S3.delete_object(file)
  86     |> ExAws.request()
  87     |> case do
  88       {:ok, %{status_code: 204}} -> :ok
  89       error -> {:error, inspect(error)}
  90     end
  91   end
  92
  93   @regex Regex.compile!("[^0-9a-zA-Z!.*/'()_-]")
  94   def strict_encode(name) do
  95     String.replace(name, @regex, "-")
  96   end
  97 end