git.squeep.com Git - akkoma/blob - lib/pleroma/uploaders/s3.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2020 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Uploaders.S3 do
   6   @behaviour Pleroma.Uploaders.Uploader
   7   require Logger
   8
   9   alias Pleroma.Config
  10
  11   # The file name is re-encoded with S3's constraints here to comply with previous
  12   # links with less strict filenames
  13   @impl true
  14   def get_file(file) do
  15     config = Config.get([__MODULE__])
  16     bucket = Keyword.fetch!(config, :bucket)
  17
  18     bucket_with_namespace =
  19       cond do
  20         truncated_namespace = Keyword.get(config, :truncated_namespace) ->
  21           truncated_namespace
  22
  23         namespace = Keyword.get(config, :bucket_namespace) ->
  24           namespace <> ":" <> bucket
  25
  26         true ->
  27           bucket
  28       end
  29
  30     {:ok,
  31      {:url,
  32       Path.join([
  33         Keyword.fetch!(config, :public_endpoint),
  34         bucket_with_namespace,
  35         strict_encode(URI.decode(file))
  36       ])}}
  37   end
  38
  39   @impl true
  40   def put_file(%Pleroma.Upload{} = upload) do
  41     config = Config.get([__MODULE__])
  42     bucket = Keyword.get(config, :bucket)
  43     streaming = Keyword.get(config, :streaming_enabled)
  44
  45     s3_name = strict_encode(upload.path)
  46
  47     op =
  48       if streaming do
  49         upload.tempfile
  50         |> ExAws.S3.Upload.stream_file()
  51         |> ExAws.S3.upload(bucket, s3_name, [
  52           {:acl, :public_read},
  53           {:content_type, upload.content_type}
  54         ])
  55       else
  56         {:ok, file_data} = File.read(upload.tempfile)
  57
  58         ExAws.S3.put_object(bucket, s3_name, file_data, [
  59           {:acl, :public_read},
  60           {:content_type, upload.content_type}
  61         ])
  62       end
  63
  64     case ExAws.request(op) do
  65       {:ok, _} ->
  66         {:ok, {:file, s3_name}}
  67
  68       error ->
  69         Logger.error("#{__MODULE__}: #{inspect(error)}")
  70         {:error, "S3 Upload failed"}
  71     end
  72   end
  73
  74   @impl true
  75   def delete_file(file) do
  76     [__MODULE__, :bucket]
  77     |> Config.get()
  78     |> ExAws.S3.delete_object(file)
  79     |> ExAws.request()
  80     |> case do
  81       {:ok, %{status_code: 204}} -> :ok
  82       error -> {:error, inspect(error)}
  83     end
  84   end
  85
  86   @regex Regex.compile!("[^0-9a-zA-Z!.*/'()_-]")
  87   def strict_encode(name) do
  88     String.replace(name, @regex, "-")
  89   end
  90 end