git.squeep.com Git - akkoma/blob - lib/pleroma/uploaders/s3.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2019 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Uploaders.S3 do
   6   @behaviour Pleroma.Uploaders.Uploader
   7   require Logger
   8
   9   alias Pleroma.Config
  10
  11   # The file name is re-encoded with S3's constraints here to comply with previous
  12   # links with less strict filenames
  13   def get_file(file) do
  14     config = Config.get([__MODULE__])
  15     bucket = Keyword.fetch!(config, :bucket)
  16
  17     bucket_with_namespace =
  18       cond do
  19         truncated_namespace = Keyword.get(config, :truncated_namespace) ->
  20           truncated_namespace
  21
  22         namespace = Keyword.get(config, :bucket_namespace) ->
  23           namespace <> ":" <> bucket
  24
  25         true ->
  26           bucket
  27       end
  28
  29     {:ok,
  30      {:url,
  31       Path.join([
  32         Keyword.fetch!(config, :public_endpoint),
  33         bucket_with_namespace,
  34         strict_encode(URI.decode(file))
  35       ])}}
  36   end
  37
  38   def put_file(%Pleroma.Upload{} = upload) do
  39     config = Config.get([__MODULE__])
  40     bucket = Keyword.get(config, :bucket)
  41
  42     s3_name = strict_encode(upload.path)
  43
  44     op =
  45       upload.tempfile
  46       |> ExAws.S3.Upload.stream_file()
  47       |> ExAws.S3.upload(bucket, s3_name, [
  48         {:acl, :public_read},
  49         {:content_type, upload.content_type}
  50       ])
  51
  52     case ExAws.request(op) do
  53       {:ok, _} ->
  54         {:ok, {:file, s3_name}}
  55
  56       error ->
  57         Logger.error("#{__MODULE__}: #{inspect(error)}")
  58         {:error, "S3 Upload failed"}
  59     end
  60   end
  61
  62   @regex Regex.compile!("[^0-9a-zA-Z!.*/'()_-]")
  63   def strict_encode(name) do
  64     String.replace(name, @regex, "-")
  65   end
  66 end