git.squeep.com Git - akkoma/blob - lib/pleroma/upload.ex

   1 defmodule Pleroma.Upload do
   2   alias Ecto.UUID
   3   alias Pleroma.Web
   4
   5   def store(%Plug.Upload{} = file, should_dedupe) do
   6     content_type = get_content_type(file.path)
   7     uuid = get_uuid(file, should_dedupe)
   8     name = get_name(file, uuid, content_type, should_dedupe)
   9     upload_folder = get_upload_path(uuid, should_dedupe)
  10     url_path = get_url(name, uuid, should_dedupe)
  11
  12     File.mkdir_p!(upload_folder)
  13     result_file = Path.join(upload_folder, name)
  14
  15     if File.exists?(result_file) do
  16       File.rm!(file.path)
  17     else
  18       File.cp!(file.path, result_file)
  19     end
  20
  21     %{
  22       "type" => "Document",
  23       "url" => [
  24         %{
  25           "type" => "Link",
  26           "mediaType" => content_type,
  27           "href" => url_path
  28         }
  29       ],
  30       "name" => name
  31     }
  32   end
  33
  34   def store(%{"img" => "data:image/" <> image_data}, should_dedupe) do
  35     parsed = Regex.named_captures(~r/(?<filetype>jpeg|png|gif);base64,(?<data>.*)/, image_data)
  36     data = Base.decode64!(parsed["data"], ignore: :whitespace)
  37     uuid = UUID.generate()
  38     uuidpath = Path.join(upload_path(), uuid)
  39     uuid = UUID.generate()
  40
  41     File.mkdir_p!(upload_path())
  42
  43     File.write!(uuidpath, data)
  44
  45     content_type = get_content_type(uuidpath)
  46
  47     name =
  48       create_name(
  49         String.downcase(Base.encode16(:crypto.hash(:sha256, data))),
  50         parsed["filetype"],
  51         content_type
  52       )
  53
  54     upload_folder = get_upload_path(uuid, should_dedupe)
  55     url_path = get_url(name, uuid, should_dedupe)
  56
  57     File.mkdir_p!(upload_folder)
  58     result_file = Path.join(upload_folder, name)
  59
  60     if should_dedupe do
  61       if !File.exists?(result_file) do
  62         File.rename(uuidpath, result_file)
  63       else
  64         File.rm!(uuidpath)
  65       end
  66     else
  67       File.rename(uuidpath, result_file)
  68     end
  69
  70     %{
  71       "type" => "Image",
  72       "url" => [
  73         %{
  74           "type" => "Link",
  75           "mediaType" => content_type,
  76           "href" => url_path
  77         }
  78       ],
  79       "name" => name
  80     }
  81   end
  82
  83   def upload_path do
  84     settings = Application.get_env(:pleroma, Pleroma.Upload)
  85     Keyword.fetch!(settings, :uploads)
  86   end
  87
  88   defp create_name(uuid, ext, type) do
  89     case type do
  90       "application/octet-stream" ->
  91         String.downcase(Enum.join([uuid, ext], "."))
  92
  93       "audio/mpeg" ->
  94         String.downcase(Enum.join([uuid, "mp3"], "."))
  95
  96       _ ->
  97         String.downcase(Enum.join([uuid, List.last(String.split(type, "/"))], "."))
  98     end
  99   end
 100
 101   defp get_uuid(file, should_dedupe) do
 102     if should_dedupe do
 103       Base.encode16(:crypto.hash(:sha256, File.read!(file.path)))
 104     else
 105       UUID.generate()
 106     end
 107   end
 108
 109   defp get_name(file, uuid, type, should_dedupe) do
 110     if should_dedupe do
 111       create_name(uuid, List.last(String.split(file.filename, ".")), type)
 112     else
 113       unless String.contains?(file.filename, ".") do
 114         case type do
 115           "image/png" -> file.filename <> ".png"
 116           "image/jpeg" -> file.filename <> ".jpg"
 117           "image/gif" -> file.filename <> ".gif"
 118           "video/webm" -> file.filename <> ".webm"
 119           "video/mp4" -> file.filename <> ".mp4"
 120           "audio/mpeg" -> file.filename <> ".mp3"
 121           "audio/ogg" -> file.filename <> ".ogg"
 122           "audio/wav" -> file.filename <> ".wav"
 123           _ -> file.filename
 124         end
 125       else
 126         file.filename
 127       end
 128     end
 129   end
 130
 131   defp get_upload_path(uuid, should_dedupe) do
 132     if should_dedupe do
 133       upload_path()
 134     else
 135       Path.join(upload_path(), uuid)
 136     end
 137   end
 138
 139   defp get_url(name, uuid, should_dedupe) do
 140     if should_dedupe do
 141       url_for(:cow_uri.urlencode(name))
 142     else
 143       url_for(Path.join(uuid, :cow_uri.urlencode(name)))
 144     end
 145   end
 146
 147   defp url_for(file) do
 148     "#{Web.base_url()}/media/#{file}"
 149   end
 150
 151   def get_content_type(file) do
 152     match =
 153       File.open(file, [:read], fn f ->
 154         case IO.binread(f, 8) do
 155           <<0x89, 0x50, 0x4E, 0x47, 0x0D, 0x0A, 0x1A, 0x0A>> ->
 156             "image/png"
 157
 158           <<0x47, 0x49, 0x46, 0x38, _, 0x61, _, _>> ->
 159             "image/gif"
 160
 161           <<0xFF, 0xD8, 0xFF, _, _, _, _, _>> ->
 162             "image/jpeg"
 163
 164           <<0x1A, 0x45, 0xDF, 0xA3, _, _, _, _>> ->
 165             "video/webm"
 166
 167           <<0x00, 0x00, 0x00, _, 0x66, 0x74, 0x79, 0x70>> ->
 168             "video/mp4"
 169
 170           <<0x49, 0x44, 0x33, _, _, _, _, _>> ->
 171             "audio/mpeg"
 172
 173           <<255, 251, _, 68, 0, 0, 0, 0>> ->
 174             "audio/mpeg"
 175
 176           <<0x4F, 0x67, 0x67, 0x53, 0x00, 0x02, 0x00, 0x00>> ->
 177             "audio/ogg"
 178
 179           <<0x52, 0x49, 0x46, 0x46, _, _, _, _>> ->
 180             "audio/wav"
 181
 182           _ ->
 183             "application/octet-stream"
 184         end
 185       end)
 186
 187     case match do
 188       {:ok, type} -> type
 189       _e -> "application/octet-stream"
 190     end
 191   end
 192 end