git.squeep.com Git - akkoma/blob - lib/pleroma/upload.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2019 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Upload do
   6   @moduledoc """
   7   # Upload
   8
   9   Options:
  10   * `:type`: presets for activity type (defaults to Document) and size limits from app configuration
  11   * `:description`: upload alternative text
  12   * `:base_url`: override base url
  13   * `:uploader`: override uploader
  14   * `:filters`: override filters
  15   * `:size_limit`: override size limit
  16   * `:activity_type`: override activity type
  17
  18   The `%Pleroma.Upload{}` struct: all documented fields are meant to be overwritten in filters:
  19
  20   * `:id` - the upload id.
  21   * `:name` - the upload file name.
  22   * `:path` - the upload path: set at first to `id/name` but can be changed. Keep in mind that the path
  23     is once created permanent and changing it (especially in uploaders) is probably a bad idea!
  24   * `:tempfile` - path to the temporary file. Prefer in-place changes on the file rather than changing the
  25   path as the temporary file is also tracked by `Plug.Upload{}` and automatically deleted once the request is over.
  26
  27   Related behaviors:
  28
  29   * `Pleroma.Uploaders.Uploader`
  30   * `Pleroma.Upload.Filter`
  31
  32   """
  33   alias Ecto.UUID
  34   require Logger
  35
  36   @type source ::
  37           Plug.Upload.t()
  38           | (data_uri_string :: String.t())
  39           | {:from_local, name :: String.t(), id :: String.t(), path :: String.t()}
  40
  41   @type option ::
  42           {:type, :avatar | :banner | :background}
  43           | {:description, String.t()}
  44           | {:activity_type, String.t()}
  45           | {:size_limit, nil | non_neg_integer()}
  46           | {:uploader, module()}
  47           | {:filters, [module()]}
  48
  49   @type t :: %__MODULE__{
  50           id: String.t(),
  51           name: String.t(),
  52           tempfile: String.t(),
  53           content_type: String.t(),
  54           path: String.t()
  55         }
  56   defstruct [:id, :name, :tempfile, :content_type, :path]
  57
  58   @spec store(source, options :: [option()]) :: {:ok, Map.t()} | {:error, any()}
  59   def store(upload, opts \\ []) do
  60     opts = get_opts(opts)
  61
  62     with {:ok, upload} <- prepare_upload(upload, opts),
  63          upload = %__MODULE__{upload | path: upload.path || "#{upload.id}/#{upload.name}"},
  64          {:ok, upload} <- Pleroma.Upload.Filter.filter(opts.filters, upload),
  65          {:ok, url_spec} <- Pleroma.Uploaders.Uploader.put_file(opts.uploader, upload) do
  66       {:ok,
  67        %{
  68          "type" => opts.activity_type,
  69          "url" => [
  70            %{
  71              "type" => "Link",
  72              "mediaType" => upload.content_type,
  73              "href" => url_from_spec(upload, opts.base_url, url_spec)
  74            }
  75          ],
  76          "name" => Map.get(opts, :description) || upload.name
  77        }}
  78     else
  79       {:error, error} ->
  80         Logger.error(
  81           "#{__MODULE__} store (using #{inspect(opts.uploader)}) failed: #{inspect(error)}"
  82         )
  83
  84         {:error, error}
  85     end
  86   end
  87
  88   def char_unescaped?(char) do
  89     URI.char_unreserved?(char) or char == ?/
  90   end
  91
  92   defp get_opts(opts) do
  93     {size_limit, activity_type} =
  94       case Keyword.get(opts, :type) do
  95         :banner ->
  96           {Pleroma.Config.get!([:instance, :banner_upload_limit]), "Image"}
  97
  98         :avatar ->
  99           {Pleroma.Config.get!([:instance, :avatar_upload_limit]), "Image"}
 100
 101         :background ->
 102           {Pleroma.Config.get!([:instance, :background_upload_limit]), "Image"}
 103
 104         _ ->
 105           {Pleroma.Config.get!([:instance, :upload_limit]), "Document"}
 106       end
 107
 108     opts = %{
 109       activity_type: Keyword.get(opts, :activity_type, activity_type),
 110       size_limit: Keyword.get(opts, :size_limit, size_limit),
 111       uploader: Keyword.get(opts, :uploader, Pleroma.Config.get([__MODULE__, :uploader])),
 112       filters: Keyword.get(opts, :filters, Pleroma.Config.get([__MODULE__, :filters])),
 113       description: Keyword.get(opts, :description),
 114       base_url:
 115         Keyword.get(
 116           opts,
 117           :base_url,
 118           Pleroma.Config.get([__MODULE__, :base_url], Pleroma.Web.base_url())
 119         )
 120     }
 121
 122     # TODO: 1.0+ : remove old config compatibility
 123     opts =
 124       if Pleroma.Config.get([__MODULE__, :strip_exif]) == true &&
 125            !Enum.member?(opts.filters, Pleroma.Upload.Filter.Mogrify) do
 126         Logger.warn("""
 127         Pleroma: configuration `:instance, :strip_exif` is deprecated, please instead set:
 128
 129           :pleroma, Pleroma.Upload, [filters: [Pleroma.Upload.Filter.Mogrify]]
 130
 131           :pleroma, Pleroma.Upload.Filter.Mogrify, args: ["strip", "auto-orient"]
 132         """)
 133
 134         Pleroma.Config.put([Pleroma.Upload.Filter.Mogrify], args: ["strip", "auto-orient"])
 135         Map.put(opts, :filters, opts.filters ++ [Pleroma.Upload.Filter.Mogrify])
 136       else
 137         opts
 138       end
 139
 140     if Pleroma.Config.get([:instance, :dedupe_media]) == true &&
 141          !Enum.member?(opts.filters, Pleroma.Upload.Filter.Dedupe) do
 142       Logger.warn("""
 143       Pleroma: configuration `:instance, :dedupe_media` is deprecated, please instead set:
 144
 145       :pleroma, Pleroma.Upload, [filters: [Pleroma.Upload.Filter.Dedupe]]
 146       """)
 147
 148       Map.put(opts, :filters, opts.filters ++ [Pleroma.Upload.Filter.Dedupe])
 149     else
 150       opts
 151     end
 152   end
 153
 154   defp prepare_upload(%Plug.Upload{} = file, opts) do
 155     with :ok <- check_file_size(file.path, opts.size_limit),
 156          {:ok, content_type, name} <- Pleroma.MIME.file_mime_type(file.path, file.filename) do
 157       {:ok,
 158        %__MODULE__{
 159          id: UUID.generate(),
 160          name: name,
 161          tempfile: file.path,
 162          content_type: content_type
 163        }}
 164     end
 165   end
 166
 167   defp prepare_upload(%{"img" => "data:image/" <> image_data}, opts) do
 168     parsed = Regex.named_captures(~r/(?<filetype>jpeg|png|gif);base64,(?<data>.*)/, image_data)
 169     data = Base.decode64!(parsed["data"], ignore: :whitespace)
 170     hash = String.downcase(Base.encode16(:crypto.hash(:sha256, data)))
 171
 172     with :ok <- check_binary_size(data, opts.size_limit),
 173          tmp_path <- tempfile_for_image(data),
 174          {:ok, content_type, name} <-
 175            Pleroma.MIME.bin_mime_type(data, hash <> "." <> parsed["filetype"]) do
 176       {:ok,
 177        %__MODULE__{
 178          id: UUID.generate(),
 179          name: name,
 180          tempfile: tmp_path,
 181          content_type: content_type
 182        }}
 183     end
 184   end
 185
 186   # For Mix.Tasks.MigrateLocalUploads
 187   defp prepare_upload(%__MODULE__{tempfile: path} = upload, _opts) do
 188     with {:ok, content_type} <- Pleroma.MIME.file_mime_type(path) do
 189       {:ok, %__MODULE__{upload | content_type: content_type}}
 190     end
 191   end
 192
 193   defp check_binary_size(binary, size_limit)
 194        when is_integer(size_limit) and size_limit > 0 and byte_size(binary) >= size_limit do
 195     {:error, :file_too_large}
 196   end
 197
 198   defp check_binary_size(_, _), do: :ok
 199
 200   defp check_file_size(path, size_limit) when is_integer(size_limit) and size_limit > 0 do
 201     with {:ok, %{size: size}} <- File.stat(path),
 202          true <- size <= size_limit do
 203       :ok
 204     else
 205       false -> {:error, :file_too_large}
 206       error -> error
 207     end
 208   end
 209
 210   defp check_file_size(_, _), do: :ok
 211
 212   # Creates a tempfile using the Plug.Upload Genserver which cleans them up
 213   # automatically.
 214   defp tempfile_for_image(data) do
 215     {:ok, tmp_path} = Plug.Upload.random_file("profile_pics")
 216     {:ok, tmp_file} = File.open(tmp_path, [:write, :raw, :binary])
 217     IO.binwrite(tmp_file, data)
 218
 219     tmp_path
 220   end
 221
 222   defp url_from_spec(%__MODULE__{name: name}, base_url, {:file, path}) do
 223     path =
 224       URI.encode(path, &char_unescaped?/1) <>
 225         if Pleroma.Config.get([__MODULE__, :link_name], false) do
 226           "?name=#{URI.encode(name, &char_unescaped?/1)}"
 227         else
 228           ""
 229         end
 230
 231     [base_url, "media", path]
 232     |> Path.join()
 233   end
 234
 235   defp url_from_spec(_upload, _base_url, {:url, url}), do: url
 236 end