git.squeep.com Git - akkoma/blob - lib/pleroma/upload.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2020 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Upload do
   6   @moduledoc """
   7   Manage user uploads
   8
   9   Options:
  10   * `:type`: presets for activity type (defaults to Document) and size limits from app configuration
  11   * `:description`: upload alternative text
  12   * `:base_url`: override base url
  13   * `:uploader`: override uploader
  14   * `:filters`: override filters
  15   * `:size_limit`: override size limit
  16   * `:activity_type`: override activity type
  17
  18   The `%Pleroma.Upload{}` struct: all documented fields are meant to be overwritten in filters:
  19
  20   * `:id` - the upload id.
  21   * `:name` - the upload file name.
  22   * `:path` - the upload path: set at first to `id/name` but can be changed. Keep in mind that the path
  23     is once created permanent and changing it (especially in uploaders) is probably a bad idea!
  24   * `:tempfile` - path to the temporary file. Prefer in-place changes on the file rather than changing the
  25   path as the temporary file is also tracked by `Plug.Upload{}` and automatically deleted once the request is over.
  26
  27   Related behaviors:
  28
  29   * `Pleroma.Uploaders.Uploader`
  30   * `Pleroma.Upload.Filter`
  31
  32   """
  33   alias Ecto.UUID
  34   require Logger
  35
  36   @type source ::
  37           Plug.Upload.t()
  38           | (data_uri_string :: String.t())
  39           | {:from_local, name :: String.t(), id :: String.t(), path :: String.t()}
  40           | map()
  41
  42   @type option ::
  43           {:type, :avatar | :banner | :background}
  44           | {:description, String.t()}
  45           | {:activity_type, String.t()}
  46           | {:size_limit, nil | non_neg_integer()}
  47           | {:uploader, module()}
  48           | {:filters, [module()]}
  49
  50   @type t :: %__MODULE__{
  51           id: String.t(),
  52           name: String.t(),
  53           tempfile: String.t(),
  54           content_type: String.t(),
  55           path: String.t()
  56         }
  57   defstruct [:id, :name, :tempfile, :content_type, :path]
  58
  59   @spec store(source, options :: [option()]) :: {:ok, Map.t()} | {:error, any()}
  60   def store(upload, opts \\ []) do
  61     opts = get_opts(opts)
  62
  63     with {:ok, upload} <- prepare_upload(upload, opts),
  64          upload = %__MODULE__{upload | path: upload.path || "#{upload.id}/#{upload.name}"},
  65          {:ok, upload} <- Pleroma.Upload.Filter.filter(opts.filters, upload),
  66          {:ok, url_spec} <- Pleroma.Uploaders.Uploader.put_file(opts.uploader, upload) do
  67       {:ok,
  68        %{
  69          "type" => opts.activity_type,
  70          "mediaType" => upload.content_type,
  71          "url" => [
  72            %{
  73              "type" => "Link",
  74              "mediaType" => upload.content_type,
  75              "href" => url_from_spec(upload, opts.base_url, url_spec)
  76            }
  77          ],
  78          "name" => Map.get(opts, :description) || upload.name
  79        }}
  80     else
  81       {:error, error} ->
  82         Logger.error(
  83           "#{__MODULE__} store (using #{inspect(opts.uploader)}) failed: #{inspect(error)}"
  84         )
  85
  86         {:error, error}
  87     end
  88   end
  89
  90   def char_unescaped?(char) do
  91     URI.char_unreserved?(char) or char == ?/
  92   end
  93
  94   defp get_opts(opts) do
  95     {size_limit, activity_type} =
  96       case Keyword.get(opts, :type) do
  97         :banner ->
  98           {Pleroma.Config.get!([:instance, :banner_upload_limit]), "Image"}
  99
 100         :avatar ->
 101           {Pleroma.Config.get!([:instance, :avatar_upload_limit]), "Image"}
 102
 103         :background ->
 104           {Pleroma.Config.get!([:instance, :background_upload_limit]), "Image"}
 105
 106         _ ->
 107           {Pleroma.Config.get!([:instance, :upload_limit]), "Document"}
 108       end
 109
 110     %{
 111       activity_type: Keyword.get(opts, :activity_type, activity_type),
 112       size_limit: Keyword.get(opts, :size_limit, size_limit),
 113       uploader: Keyword.get(opts, :uploader, Pleroma.Config.get([__MODULE__, :uploader])),
 114       filters: Keyword.get(opts, :filters, Pleroma.Config.get([__MODULE__, :filters])),
 115       description: Keyword.get(opts, :description),
 116       base_url:
 117         Keyword.get(
 118           opts,
 119           :base_url,
 120           Pleroma.Config.get([__MODULE__, :base_url], Pleroma.Web.base_url())
 121         )
 122     }
 123   end
 124
 125   defp prepare_upload(%Plug.Upload{} = file, opts) do
 126     with :ok <- check_file_size(file.path, opts.size_limit),
 127          {:ok, content_type, name} <- Pleroma.MIME.file_mime_type(file.path, file.filename) do
 128       {:ok,
 129        %__MODULE__{
 130          id: UUID.generate(),
 131          name: name,
 132          tempfile: file.path,
 133          content_type: content_type
 134        }}
 135     end
 136   end
 137
 138   defp prepare_upload(%{img: "data:image/" <> image_data}, opts) do
 139     parsed = Regex.named_captures(~r/(?<filetype>jpeg|png|gif);base64,(?<data>.*)/, image_data)
 140     data = Base.decode64!(parsed["data"], ignore: :whitespace)
 141     hash = String.downcase(Base.encode16(:crypto.hash(:sha256, data)))
 142
 143     with :ok <- check_binary_size(data, opts.size_limit),
 144          tmp_path <- tempfile_for_image(data),
 145          {:ok, content_type, name} <-
 146            Pleroma.MIME.bin_mime_type(data, hash <> "." <> parsed["filetype"]) do
 147       {:ok,
 148        %__MODULE__{
 149          id: UUID.generate(),
 150          name: name,
 151          tempfile: tmp_path,
 152          content_type: content_type
 153        }}
 154     end
 155   end
 156
 157   # For Mix.Tasks.MigrateLocalUploads
 158   defp prepare_upload(%__MODULE__{tempfile: path} = upload, _opts) do
 159     with {:ok, content_type} <- Pleroma.MIME.file_mime_type(path) do
 160       {:ok, %__MODULE__{upload | content_type: content_type}}
 161     end
 162   end
 163
 164   defp check_binary_size(binary, size_limit)
 165        when is_integer(size_limit) and size_limit > 0 and byte_size(binary) >= size_limit do
 166     {:error, :file_too_large}
 167   end
 168
 169   defp check_binary_size(_, _), do: :ok
 170
 171   defp check_file_size(path, size_limit) when is_integer(size_limit) and size_limit > 0 do
 172     with {:ok, %{size: size}} <- File.stat(path),
 173          true <- size <= size_limit do
 174       :ok
 175     else
 176       false -> {:error, :file_too_large}
 177       error -> error
 178     end
 179   end
 180
 181   defp check_file_size(_, _), do: :ok
 182
 183   # Creates a tempfile using the Plug.Upload Genserver which cleans them up
 184   # automatically.
 185   defp tempfile_for_image(data) do
 186     {:ok, tmp_path} = Plug.Upload.random_file("profile_pics")
 187     {:ok, tmp_file} = File.open(tmp_path, [:write, :raw, :binary])
 188     IO.binwrite(tmp_file, data)
 189
 190     tmp_path
 191   end
 192
 193   defp url_from_spec(%__MODULE__{name: name}, base_url, {:file, path}) do
 194     path =
 195       URI.encode(path, &char_unescaped?/1) <>
 196         if Pleroma.Config.get([__MODULE__, :link_name], false) do
 197           "?name=#{URI.encode(name, &char_unescaped?/1)}"
 198         else
 199           ""
 200         end
 201
 202     prefix =
 203       if is_nil(Pleroma.Config.get([__MODULE__, :base_url])) do
 204         "media"
 205       else
 206         ""
 207       end
 208
 209     [base_url, prefix, path]
 210     |> Path.join()
 211   end
 212
 213   defp url_from_spec(_upload, _base_url, {:url, url}), do: url
 214 end