git.squeep.com Git - akkoma/blob - lib/pleroma/upload.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2020 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Upload do
   6   @moduledoc """
   7   Manage user uploads
   8
   9   Options:
  10   * `:type`: presets for activity type (defaults to Document) and size limits from app configuration
  11   * `:description`: upload alternative text
  12   * `:base_url`: override base url
  13   * `:uploader`: override uploader
  14   * `:filters`: override filters
  15   * `:size_limit`: override size limit
  16   * `:activity_type`: override activity type
  17
  18   The `%Pleroma.Upload{}` struct: all documented fields are meant to be overwritten in filters:
  19
  20   * `:id` - the upload id.
  21   * `:name` - the upload file name.
  22   * `:path` - the upload path: set at first to `id/name` but can be changed. Keep in mind that the path
  23     is once created permanent and changing it (especially in uploaders) is probably a bad idea!
  24   * `:tempfile` - path to the temporary file. Prefer in-place changes on the file rather than changing the
  25   path as the temporary file is also tracked by `Plug.Upload{}` and automatically deleted once the request is over.
  26
  27   Related behaviors:
  28
  29   * `Pleroma.Uploaders.Uploader`
  30   * `Pleroma.Upload.Filter`
  31
  32   """
  33   alias Ecto.UUID
  34   require Logger
  35
  36   @type source ::
  37           Plug.Upload.t()
  38           | (data_uri_string :: String.t())
  39           | {:from_local, name :: String.t(), id :: String.t(), path :: String.t()}
  40           | map()
  41
  42   @type option ::
  43           {:type, :avatar | :banner | :background}
  44           | {:description, String.t()}
  45           | {:activity_type, String.t()}
  46           | {:size_limit, nil | non_neg_integer()}
  47           | {:uploader, module()}
  48           | {:filters, [module()]}
  49
  50   @type t :: %__MODULE__{
  51           id: String.t(),
  52           name: String.t(),
  53           tempfile: String.t(),
  54           content_type: String.t(),
  55           path: String.t()
  56         }
  57   defstruct [:id, :name, :tempfile, :content_type, :path]
  58
  59   @spec store(source, options :: [option()]) :: {:ok, Map.t()} | {:error, any()}
  60   def store(upload, opts \\ []) do
  61     opts = get_opts(opts)
  62
  63     with {:ok, upload} <- prepare_upload(upload, opts),
  64          upload = %__MODULE__{upload | path: upload.path || "#{upload.id}/#{upload.name}"},
  65          {:ok, upload} <- Pleroma.Upload.Filter.filter(opts.filters, upload),
  66          {:ok, url_spec} <- Pleroma.Uploaders.Uploader.put_file(opts.uploader, upload) do
  67       {:ok,
  68        %{
  69          "type" => opts.activity_type,
  70          "url" => [
  71            %{
  72              "type" => "Link",
  73              "mediaType" => upload.content_type,
  74              "href" => url_from_spec(upload, opts.base_url, url_spec)
  75            }
  76          ],
  77          "name" => Map.get(opts, :description) || upload.name
  78        }}
  79     else
  80       {:error, error} ->
  81         Logger.error(
  82           "#{__MODULE__} store (using #{inspect(opts.uploader)}) failed: #{inspect(error)}"
  83         )
  84
  85         {:error, error}
  86     end
  87   end
  88
  89   def char_unescaped?(char) do
  90     URI.char_unreserved?(char) or char == ?/
  91   end
  92
  93   defp get_opts(opts) do
  94     {size_limit, activity_type} =
  95       case Keyword.get(opts, :type) do
  96         :banner ->
  97           {Pleroma.Config.get!([:instance, :banner_upload_limit]), "Image"}
  98
  99         :avatar ->
 100           {Pleroma.Config.get!([:instance, :avatar_upload_limit]), "Image"}
 101
 102         :background ->
 103           {Pleroma.Config.get!([:instance, :background_upload_limit]), "Image"}
 104
 105         _ ->
 106           {Pleroma.Config.get!([:instance, :upload_limit]), "Document"}
 107       end
 108
 109     %{
 110       activity_type: Keyword.get(opts, :activity_type, activity_type),
 111       size_limit: Keyword.get(opts, :size_limit, size_limit),
 112       uploader: Keyword.get(opts, :uploader, Pleroma.Config.get([__MODULE__, :uploader])),
 113       filters: Keyword.get(opts, :filters, Pleroma.Config.get([__MODULE__, :filters])),
 114       description: Keyword.get(opts, :description),
 115       base_url:
 116         Keyword.get(
 117           opts,
 118           :base_url,
 119           Pleroma.Config.get([__MODULE__, :base_url], Pleroma.Web.base_url())
 120         )
 121     }
 122   end
 123
 124   defp prepare_upload(%Plug.Upload{} = file, opts) do
 125     with :ok <- check_file_size(file.path, opts.size_limit),
 126          {:ok, content_type, name} <- Pleroma.MIME.file_mime_type(file.path, file.filename) do
 127       {:ok,
 128        %__MODULE__{
 129          id: UUID.generate(),
 130          name: name,
 131          tempfile: file.path,
 132          content_type: content_type
 133        }}
 134     end
 135   end
 136
 137   defp prepare_upload(%{"img" => "data:image/" <> image_data}, opts) do
 138     parsed = Regex.named_captures(~r/(?<filetype>jpeg|png|gif);base64,(?<data>.*)/, image_data)
 139     data = Base.decode64!(parsed["data"], ignore: :whitespace)
 140     hash = String.downcase(Base.encode16(:crypto.hash(:sha256, data)))
 141
 142     with :ok <- check_binary_size(data, opts.size_limit),
 143          tmp_path <- tempfile_for_image(data),
 144          {:ok, content_type, name} <-
 145            Pleroma.MIME.bin_mime_type(data, hash <> "." <> parsed["filetype"]) do
 146       {:ok,
 147        %__MODULE__{
 148          id: UUID.generate(),
 149          name: name,
 150          tempfile: tmp_path,
 151          content_type: content_type
 152        }}
 153     end
 154   end
 155
 156   # For Mix.Tasks.MigrateLocalUploads
 157   defp prepare_upload(%__MODULE__{tempfile: path} = upload, _opts) do
 158     with {:ok, content_type} <- Pleroma.MIME.file_mime_type(path) do
 159       {:ok, %__MODULE__{upload | content_type: content_type}}
 160     end
 161   end
 162
 163   defp check_binary_size(binary, size_limit)
 164        when is_integer(size_limit) and size_limit > 0 and byte_size(binary) >= size_limit do
 165     {:error, :file_too_large}
 166   end
 167
 168   defp check_binary_size(_, _), do: :ok
 169
 170   defp check_file_size(path, size_limit) when is_integer(size_limit) and size_limit > 0 do
 171     with {:ok, %{size: size}} <- File.stat(path),
 172          true <- size <= size_limit do
 173       :ok
 174     else
 175       false -> {:error, :file_too_large}
 176       error -> error
 177     end
 178   end
 179
 180   defp check_file_size(_, _), do: :ok
 181
 182   # Creates a tempfile using the Plug.Upload Genserver which cleans them up
 183   # automatically.
 184   defp tempfile_for_image(data) do
 185     {:ok, tmp_path} = Plug.Upload.random_file("profile_pics")
 186     {:ok, tmp_file} = File.open(tmp_path, [:write, :raw, :binary])
 187     IO.binwrite(tmp_file, data)
 188
 189     tmp_path
 190   end
 191
 192   defp url_from_spec(%__MODULE__{name: name}, base_url, {:file, path}) do
 193     path =
 194       URI.encode(path, &char_unescaped?/1) <>
 195         if Pleroma.Config.get([__MODULE__, :link_name], false) do
 196           "?name=#{URI.encode(name, &char_unescaped?/1)}"
 197         else
 198           ""
 199         end
 200
 201     prefix =
 202       if is_nil(Pleroma.Config.get([__MODULE__, :base_url])) do
 203         "media"
 204       else
 205         ""
 206       end
 207
 208     [base_url, prefix, path]
 209     |> Path.join()
 210   end
 211
 212   defp url_from_spec(_upload, _base_url, {:url, url}), do: url
 213 end