git.squeep.com Git - akkoma/blob - lib/pleroma/telemetry/logger.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2021 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Telemetry.Logger do
   6   @moduledoc "Transforms Pleroma telemetry events to logs"
   7
   8   require Logger
   9
  10   @events [
  11     [:pleroma, :repo, :query]
  12   ]
  13   def attach do
  14     :telemetry.attach_many(
  15       "pleroma-logger",
  16       @events,
  17       &Pleroma.Telemetry.Logger.handle_event/4,
  18       []
  19     )
  20   end
  21
  22   # Passing anonymous functions instead of strings to logger is intentional,
  23   # that way strings won't be concatenated if the message is going to be thrown
  24   # out anyway due to higher log level configured
  25
  26   def handle_event(
  27         [:pleroma, :repo, :query] = _name,
  28         %{query_time: query_time} = measurements,
  29         %{source: source} = metadata,
  30         config
  31       ) do
  32     logging_config = Pleroma.Config.get([:telemetry, :slow_queries_logging], [])
  33
  34     if logging_config[:enabled] &&
  35          logging_config[:min_duration] &&
  36          query_time > logging_config[:min_duration] and
  37          (is_nil(logging_config[:exclude_sources]) or
  38             source not in logging_config[:exclude_sources]) do
  39       log_slow_query(measurements, metadata, config)
  40     else
  41       :ok
  42     end
  43   end
  44
  45   defp log_slow_query(
  46          %{query_time: query_time} = _measurements,
  47          %{source: _source, query: query, params: query_params, repo: repo} = _metadata,
  48          _config
  49        ) do
  50     sql_explain =
  51       with {:ok, %{rows: explain_result_rows}} <-
  52              repo.query("EXPLAIN " <> query, query_params, log: false) do
  53         Enum.map_join(explain_result_rows, "\n", & &1)
  54       end
  55
  56     {:current_stacktrace, stacktrace} = Process.info(self(), :current_stacktrace)
  57
  58     pleroma_stacktrace =
  59       Enum.filter(stacktrace, fn
  60         {__MODULE__, _, _, _} ->
  61           false
  62
  63         {mod, _, _, _} ->
  64           mod
  65           |> to_string()
  66           |> String.starts_with?("Elixir.Pleroma.")
  67       end)
  68
  69     Logger.warn(fn ->
  70       """
  71       Slow query!
  72
  73       Total time: #{round(query_time / 1_000)} ms
  74
  75       #{query}
  76
  77       #{inspect(query_params, limit: :infinity)}
  78
  79       #{sql_explain}
  80
  81       #{Exception.format_stacktrace(pleroma_stacktrace)}
  82       """
  83     end)
  84   end
  85 end