git.squeep.com Git - akkoma/blob - lib/pleroma/signature.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2020 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Signature do
   6   @behaviour HTTPSignatures.Adapter
   7
   8   alias Pleroma.Keys
   9   alias Pleroma.User
  10   alias Pleroma.Web.ActivityPub.ActivityPub
  11
  12   def key_id_to_actor_id(key_id) do
  13     uri =
  14       URI.parse(key_id)
  15       |> Map.put(:fragment, nil)
  16
  17     uri =
  18       if not is_nil(uri.path) and String.ends_with?(uri.path, "/publickey") do
  19         Map.put(uri, :path, String.replace(uri.path, "/publickey", ""))
  20       else
  21         uri
  22       end
  23
  24     case uri do
  25       %URI{scheme: scheme} when scheme in ["https", "http"] ->
  26         {:ok, URI.to_string(uri)}
  27
  28       _ ->
  29         case Pleroma.Web.WebFinger.finger(URI.to_string(uri)) do
  30           %{"ap_id" => ap_id} -> {:ok, ap_id}
  31           _ -> {:error, URI.to_string(uri)}
  32         end
  33     end
  34   end
  35
  36   def fetch_public_key(conn) do
  37     with %{"keyId" => kid} <- HTTPSignatures.signature_for_conn(conn),
  38          {:ok, actor_id} <- key_id_to_actor_id(kid),
  39          {:ok, public_key} <- User.get_public_key_for_ap_id(actor_id) do
  40       {:ok, public_key}
  41     else
  42       e ->
  43         {:error, e}
  44     end
  45   end
  46
  47   def refetch_public_key(conn) do
  48     with %{"keyId" => kid} <- HTTPSignatures.signature_for_conn(conn),
  49          {:ok, actor_id} <- key_id_to_actor_id(kid),
  50          {:ok, _user} <- ActivityPub.make_user_from_ap_id(actor_id),
  51          {:ok, public_key} <- User.get_public_key_for_ap_id(actor_id) do
  52       {:ok, public_key}
  53     else
  54       e ->
  55         {:error, e}
  56     end
  57   end
  58
  59   def sign(%User{} = user, headers) do
  60     with {:ok, %{keys: keys}} <- User.ensure_keys_present(user),
  61          {:ok, private_key, _} <- Keys.keys_from_pem(keys) do
  62       HTTPSignatures.sign(private_key, user.ap_id <> "#main-key", headers)
  63     end
  64   end
  65
  66   def signed_date, do: signed_date(NaiveDateTime.utc_now())
  67
  68   def signed_date(%NaiveDateTime{} = date) do
  69     Timex.format!(date, "{WDshort}, {0D} {Mshort} {YYYY} {h24}:{m}:{s} GMT")
  70   end
  71 end