git.squeep.com Git - akkoma/blob - lib/pleroma/reverse_proxy/client/tesla.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2020 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.ReverseProxy.Client.Tesla do
   6   @behaviour Pleroma.ReverseProxy.Client
   7
   8   @type headers() :: [{String.t(), String.t()}]
   9   @type status() :: pos_integer()
  10
  11   @spec request(atom(), String.t(), headers(), String.t(), keyword()) ::
  12           {:ok, status(), headers}
  13           | {:ok, status(), headers, map()}
  14           | {:error, atom() | String.t()}
  15           | no_return()
  16
  17   @impl true
  18   def request(method, url, headers, body, opts \\ []) do
  19     check_adapter()
  20
  21     opts = Keyword.put(opts, :body_as, :chunks)
  22
  23     with {:ok, response} <-
  24            Pleroma.HTTP.request(
  25              method,
  26              url,
  27              body,
  28              headers,
  29              Keyword.put(opts, :adapter, opts)
  30            ) do
  31       if is_map(response.body) and method != :head do
  32         {:ok, response.status, response.headers, response.body}
  33       else
  34         {:ok, response.status, response.headers}
  35       end
  36     else
  37       {:error, error} -> {:error, error}
  38     end
  39   end
  40
  41   @impl true
  42   @spec stream_body(map()) ::
  43           {:ok, binary(), map()} | {:error, atom() | String.t()} | :done | no_return()
  44   def stream_body(%{pid: pid, opts: opts, fin: true}) do
  45     # if connection was reused, but in tesla were redirects,
  46     # tesla returns new opened connection, which must be closed manually
  47     if opts[:old_conn], do: Tesla.Adapter.Gun.close(pid)
  48     # if there were redirects we need to checkout old conn
  49     conn = opts[:old_conn] || opts[:conn]
  50
  51     if conn, do: :ok = Pleroma.Pool.Connections.checkout(conn, self(), :gun_connections)
  52
  53     :done
  54   end
  55
  56   def stream_body(client) do
  57     case read_chunk!(client) do
  58       {:fin, body} ->
  59         {:ok, body, Map.put(client, :fin, true)}
  60
  61       {:nofin, part} ->
  62         {:ok, part, client}
  63
  64       {:error, error} ->
  65         {:error, error}
  66     end
  67   end
  68
  69   defp read_chunk!(%{pid: pid, stream: stream, opts: opts}) do
  70     adapter = check_adapter()
  71     adapter.read_chunk(pid, stream, opts)
  72   end
  73
  74   @impl true
  75   @spec close(map) :: :ok | no_return()
  76   def close(%{pid: pid}) do
  77     adapter = check_adapter()
  78     adapter.close(pid)
  79   end
  80
  81   defp check_adapter do
  82     adapter = Application.get_env(:tesla, :adapter)
  83
  84     unless adapter == Tesla.Adapter.Gun do
  85       raise "#{adapter} doesn't support reading body in chunks"
  86     end
  87
  88     adapter
  89   end
  90 end