git.squeep.com Git - akkoma/blob - lib/pleroma/plugs/set_locale_plug.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2020 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 # NOTE: this module is based on https://github.com/smeevil/set_locale
   6 defmodule Pleroma.Plugs.SetLocalePlug do
   7   import Plug.Conn, only: [get_req_header: 2, assign: 3]
   8
   9   def init(_), do: nil
  10
  11   def call(conn, _) do
  12     locale = get_locale_from_header(conn) || Gettext.get_locale()
  13     Gettext.put_locale(locale)
  14     assign(conn, :locale, locale)
  15   end
  16
  17   defp get_locale_from_header(conn) do
  18     conn
  19     |> extract_accept_language()
  20     |> Enum.find(&supported_locale?/1)
  21   end
  22
  23   defp extract_accept_language(conn) do
  24     case get_req_header(conn, "accept-language") do
  25       [value | _] ->
  26         value
  27         |> String.split(",")
  28         |> Enum.map(&parse_language_option/1)
  29         |> Enum.sort(&(&1.quality > &2.quality))
  30         |> Enum.map(& &1.tag)
  31         |> Enum.reject(&is_nil/1)
  32         |> ensure_language_fallbacks()
  33
  34       _ ->
  35         []
  36     end
  37   end
  38
  39   defp supported_locale?(locale) do
  40     Pleroma.Web.Gettext
  41     |> Gettext.known_locales()
  42     |> Enum.member?(locale)
  43   end
  44
  45   defp parse_language_option(string) do
  46     captures = Regex.named_captures(~r/^\s?(?<tag>[\w\-]+)(?:;q=(?<quality>[\d\.]+))?$/i, string)
  47
  48     quality =
  49       case Float.parse(captures["quality"] || "1.0") do
  50         {val, _} -> val
  51         :error -> 1.0
  52       end
  53
  54     %{tag: captures["tag"], quality: quality}
  55   end
  56
  57   defp ensure_language_fallbacks(tags) do
  58     Enum.flat_map(tags, fn tag ->
  59       [language | _] = String.split(tag, "-")
  60       if Enum.member?(tags, language), do: [tag], else: [tag, language]
  61     end)
  62   end
  63 end