git.squeep.com Git - akkoma/blob - lib/pleroma/plugs/oauth_plug.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2019 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Plugs.OAuthPlug do
   6   import Plug.Conn
   7   import Ecto.Query
   8
   9   alias Pleroma.{
  10     User,
  11     Repo,
  12     Web.OAuth.Token
  13   }
  14
  15   @realm_reg Regex.compile!("Bearer\:?\s+(.*)$", "i")
  16
  17   def init(options), do: options
  18
  19   def call(%{assigns: %{user: %User{}}} = conn, _), do: conn
  20
  21   def call(conn, _) do
  22     with {:ok, token_str} <- fetch_token_str(conn),
  23          {:ok, user, token_record} <- fetch_user_and_token(token_str) do
  24       conn
  25       |> assign(:token, token_record)
  26       |> assign(:user, user)
  27     else
  28       _ -> conn
  29     end
  30   end
  31
  32   # Gets user by token
  33   #
  34   @spec fetch_user_and_token(String.t()) :: {:ok, User.t(), Token.t()} | nil
  35   defp fetch_user_and_token(token) do
  36     query =
  37       from(t in Token,
  38         where: t.token == ^token,
  39         join: user in assoc(t, :user),
  40         preload: [user: user]
  41       )
  42
  43     with %Token{user: %{info: %{deactivated: false} = _} = user} = token_record <- Repo.one(query) do
  44       {:ok, user, token_record}
  45     end
  46   end
  47
  48   # Gets token from session by :oauth_token key
  49   #
  50   @spec fetch_token_from_session(Plug.Conn.t()) :: :no_token_found | {:ok, String.t()}
  51   defp fetch_token_from_session(conn) do
  52     case get_session(conn, :oauth_token) do
  53       nil -> :no_token_found
  54       token -> {:ok, token}
  55     end
  56   end
  57
  58   # Gets token from headers
  59   #
  60   @spec fetch_token_str(Plug.Conn.t()) :: :no_token_found | {:ok, String.t()}
  61   defp fetch_token_str(%Plug.Conn{} = conn) do
  62     headers = get_req_header(conn, "authorization")
  63
  64     with :no_token_found <- fetch_token_str(headers),
  65          do: fetch_token_from_session(conn)
  66   end
  67
  68   @spec fetch_token_str(Keyword.t()) :: :no_token_found | {:ok, String.t()}
  69   defp fetch_token_str([]), do: :no_token_found
  70
  71   defp fetch_token_str([token | tail]) do
  72     trimmed_token = String.trim(token)
  73
  74     case Regex.run(@realm_reg, trimmed_token) do
  75       [_, match] -> {:ok, String.trim(match)}
  76       _ -> fetch_token_str(tail)
  77     end
  78   end
  79 end