git.squeep.com Git - akkoma/blob - lib/pleroma/plugs/oauth_plug.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2018 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Plugs.OAuthPlug do
   6   import Plug.Conn
   7   import Ecto.Query
   8
   9   alias Pleroma.{
  10     User,
  11     Repo,
  12     Web.OAuth.Token
  13   }
  14
  15   @realm_reg Regex.compile!("Bearer\:?\s+(.*)$", "i")
  16
  17   def init(options), do: options
  18
  19   def call(%{assigns: %{user: %User{}}} = conn, _), do: conn
  20
  21   def call(conn, _) do
  22     with {:ok, token_str} <- fetch_token_str(conn),
  23          {:ok, user, token_record} <- fetch_user_and_token(token_str) do
  24       conn
  25       |> assign(:token, token_record)
  26       |> assign(:user, user)
  27     else
  28       _ -> conn
  29     end
  30   end
  31
  32   # Gets user by token
  33   #
  34   @spec fetch_user_and_token(String.t()) :: {:ok, User.t(), Token.t()} | nil
  35   defp fetch_user_and_token(token) do
  36     query = from(q in Token, where: q.token == ^token, preload: [:user])
  37
  38     with %Token{user: %{info: %{deactivated: false} = _} = user} = token_record <- Repo.one(query) do
  39       {:ok, user, token_record}
  40     end
  41   end
  42
  43   # Gets token from session by :oauth_token key
  44   #
  45   @spec fetch_token_from_session(Plug.Conn.t()) :: :no_token_found | {:ok, String.t()}
  46   defp fetch_token_from_session(conn) do
  47     case get_session(conn, :oauth_token) do
  48       nil -> :no_token_found
  49       token -> {:ok, token}
  50     end
  51   end
  52
  53   # Gets token from headers
  54   #
  55   @spec fetch_token_str(Plug.Conn.t()) :: :no_token_found | {:ok, String.t()}
  56   defp fetch_token_str(%Plug.Conn{} = conn) do
  57     headers = get_req_header(conn, "authorization")
  58
  59     with :no_token_found <- fetch_token_str(headers),
  60          do: fetch_token_from_session(conn)
  61   end
  62
  63   @spec fetch_token_str(Keyword.t()) :: :no_token_found | {:ok, String.t()}
  64   defp fetch_token_str([]), do: :no_token_found
  65
  66   defp fetch_token_str([token | tail]) do
  67     trimmed_token = String.trim(token)
  68
  69     case Regex.run(@realm_reg, trimmed_token) do
  70       [_, match] -> {:ok, String.trim(match)}
  71       _ -> fetch_token_str(tail)
  72     end
  73   end
  74 end