git.squeep.com Git - akkoma/blob - lib/pleroma/plugs/oauth_plug.ex

   1 defmodule Pleroma.Plugs.OAuthPlug do
   2   import Plug.Conn
   3   import Ecto.Query
   4
   5   alias Pleroma.{
   6     User,
   7     Repo,
   8     Web.OAuth.Token
   9   }
  10
  11   @realm_reg Regex.compile!("Bearer\:?\s+(.*)$", "i")
  12
  13   def init(options), do: options
  14
  15   def call(%{assigns: %{user: %User{}}} = conn, _), do: conn
  16
  17   def call(conn, _) do
  18     with {:ok, token} <- fetch_token(conn),
  19          {:ok, user} <- fetch_user(token) do
  20       assign(conn, :user, user)
  21     else
  22       _ -> conn
  23     end
  24   end
  25
  26   # Gets user by token
  27   #
  28   @spec fetch_user(String.t()) :: {:ok, User.t()} | nil
  29   defp fetch_user(token) do
  30     query = from(q in Token, where: q.token == ^token, preload: [:user])
  31
  32     with %Token{user: %{info: %{deactivated: false} = _} = user} <- Repo.one(query) do
  33       {:ok, user}
  34     end
  35   end
  36
  37   # Gets token from session by :oauth_token key
  38   #
  39   @spec fetch_token_from_session(Plug.Conn.t()) :: :no_token_found | {:ok, String.t()}
  40   defp fetch_token_from_session(conn) do
  41     case get_session(conn, :oauth_token) do
  42       nil -> :no_token_found
  43       token -> {:ok, token}
  44     end
  45   end
  46
  47   # Gets token from headers
  48   #
  49   @spec fetch_token(Plug.Conn.t()) :: :no_token_found | {:ok, String.t()}
  50   defp fetch_token(%Plug.Conn{} = conn) do
  51     headers = get_req_header(conn, "authorization")
  52
  53     with :no_token_found <- fetch_token(headers),
  54          do: fetch_token_from_session(conn)
  55   end
  56
  57   @spec fetch_token(Keyword.t()) :: :no_token_found | {:ok, String.t()}
  58   defp fetch_token([]), do: :no_token_found
  59
  60   defp fetch_token([token | tail]) do
  61     trimmed_token = String.trim(token)
  62
  63     case Regex.run(@realm_reg, trimmed_token) do
  64       [_, match] -> {:ok, String.trim(match)}
  65       _ -> fetch_token(tail)
  66     end
  67   end
  68 end