git.squeep.com Git - akkoma/blob - lib/pleroma/plugs/oauth_plug.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2019 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Plugs.OAuthPlug do
   6   import Plug.Conn
   7   import Ecto.Query
   8
   9   alias Pleroma.Repo
  10   alias Pleroma.User
  11   alias Pleroma.Web.OAuth.Token
  12
  13   @realm_reg Regex.compile!("Bearer\:?\s+(.*)$", "i")
  14
  15   def init(options), do: options
  16
  17   def call(%{assigns: %{user: %User{}}} = conn, _), do: conn
  18
  19   def call(conn, _) do
  20     with {:ok, token_str} <- fetch_token_str(conn),
  21          {:ok, user, token_record} <- fetch_user_and_token(token_str) do
  22       conn
  23       |> assign(:token, token_record)
  24       |> assign(:user, user)
  25     else
  26       _ -> conn
  27     end
  28   end
  29
  30   # Gets user by token
  31   #
  32   @spec fetch_user_and_token(String.t()) :: {:ok, User.t(), Token.t()} | nil
  33   defp fetch_user_and_token(token) do
  34     query =
  35       from(t in Token,
  36         where: t.token == ^token,
  37         join: user in assoc(t, :user),
  38         preload: [user: user]
  39       )
  40
  41     # credo:disable-for-next-line Credo.Check.Readability.MaxLineLength
  42     with %Token{user: %{info: %{deactivated: false} = _} = user} = token_record <- Repo.one(query) do
  43       {:ok, user, token_record}
  44     end
  45   end
  46
  47   # Gets token from session by :oauth_token key
  48   #
  49   @spec fetch_token_from_session(Plug.Conn.t()) :: :no_token_found | {:ok, String.t()}
  50   defp fetch_token_from_session(conn) do
  51     case get_session(conn, :oauth_token) do
  52       nil -> :no_token_found
  53       token -> {:ok, token}
  54     end
  55   end
  56
  57   # Gets token from headers
  58   #
  59   @spec fetch_token_str(Plug.Conn.t()) :: :no_token_found | {:ok, String.t()}
  60   defp fetch_token_str(%Plug.Conn{} = conn) do
  61     headers = get_req_header(conn, "authorization")
  62
  63     with :no_token_found <- fetch_token_str(headers),
  64          do: fetch_token_from_session(conn)
  65   end
  66
  67   @spec fetch_token_str(Keyword.t()) :: :no_token_found | {:ok, String.t()}
  68   defp fetch_token_str([]), do: :no_token_found
  69
  70   defp fetch_token_str([token | tail]) do
  71     trimmed_token = String.trim(token)
  72
  73     case Regex.run(@realm_reg, trimmed_token) do
  74       [_, match] -> {:ok, String.trim(match)}
  75       _ -> fetch_token_str(tail)
  76     end
  77   end
  78 end