git.squeep.com Git - akkoma/blob - lib/pleroma/plugs/instance_static.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2019 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Plugs.InstanceStatic do
   6   @moduledoc """
   7   This is a shim to call `Plug.Static` but with runtime `from` configuration.
   8
   9   Mountpoints are defined directly in the module to avoid calling the configuration for every request including non-static ones.
  10   """
  11   @behaviour Plug
  12
  13   def file_path(path) do
  14     instance_path =
  15       Path.join(Pleroma.Config.get([:instance, :static_dir], "instance/static/"), path)
  16
  17     if File.exists?(instance_path) do
  18       instance_path
  19     else
  20       Path.join(Application.app_dir(:pleroma, "priv/static/"), path)
  21     end
  22   end
  23
  24   @only ~w(index.html static emoji packs sounds images instance favicon.png sw.js sw-pleroma.js)
  25
  26   def init(opts) do
  27     opts
  28     |> Keyword.put(:from, "__unconfigured_instance_static_plug")
  29     |> Keyword.put(:at, "/__unconfigured_instance_static_plug")
  30     |> Plug.Static.init()
  31   end
  32
  33   for only <- @only do
  34     at = Plug.Router.Utils.split("/")
  35
  36     def call(%{request_path: "/" <> unquote(only) <> _} = conn, opts) do
  37       call_static(
  38         conn,
  39         opts,
  40         unquote(at),
  41         Pleroma.Config.get([:instance, :static_dir], "instance/static")
  42       )
  43     end
  44   end
  45
  46   def call(conn, _) do
  47     conn
  48   end
  49
  50   defp call_static(conn, opts, at, from) do
  51     opts =
  52       opts
  53       |> Map.put(:from, from)
  54       |> Map.put(:at, at)
  55
  56     Plug.Static.call(conn, opts)
  57   end
  58 end