git.squeep.com Git - akkoma/blob - lib/pleroma/plugs/http_security_plug.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2019 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Plugs.HTTPSecurityPlug do
   6   alias Pleroma.Config
   7   import Plug.Conn
   8
   9   require Logger
  10
  11   def init(opts), do: opts
  12
  13   def call(conn, _options) do
  14     if Config.get([:http_security, :enabled]) do
  15       conn
  16       |> merge_resp_headers(headers())
  17       |> maybe_send_sts_header(Config.get([:http_security, :sts]))
  18     else
  19       conn
  20     end
  21   end
  22
  23   defp headers do
  24     referrer_policy = Config.get([:http_security, :referrer_policy])
  25     report_uri = Config.get([:http_security, :report_uri])
  26
  27     headers = [
  28       {"x-xss-protection", "1; mode=block"},
  29       {"x-permitted-cross-domain-policies", "none"},
  30       {"x-frame-options", "DENY"},
  31       {"x-content-type-options", "nosniff"},
  32       {"referrer-policy", referrer_policy},
  33       {"x-download-options", "noopen"},
  34       {"content-security-policy", csp_string() <> ";"}
  35     ]
  36
  37     if report_uri do
  38       report_group = %{
  39         "group" => "csp-endpoint",
  40         "max-age" => 10_886_400,
  41         "endpoints" => [
  42           %{"url" => report_uri}
  43         ]
  44       }
  45
  46       headers ++ [{"reply-to", Jason.encode!(report_group)}]
  47     else
  48       headers
  49     end
  50   end
  51
  52   defp csp_string do
  53     scheme = Config.get([Pleroma.Web.Endpoint, :url])[:scheme]
  54     static_url = Pleroma.Web.Endpoint.static_url()
  55     websocket_url = Pleroma.Web.Endpoint.websocket_url()
  56     report_uri = Config.get([:http_security, :report_uri])
  57
  58     connect_src = "connect-src 'self' #{static_url} #{websocket_url}"
  59
  60     connect_src =
  61       if Pleroma.Config.get(:env) == :dev do
  62         connect_src <> " http://localhost:3035/"
  63       else
  64         connect_src
  65       end
  66
  67     script_src =
  68       if Pleroma.Config.get(:env) == :dev do
  69         "script-src 'self' 'unsafe-eval'"
  70       else
  71         "script-src 'self'"
  72       end
  73
  74     main_part = [
  75       "default-src 'none'",
  76       "base-uri 'self'",
  77       "frame-ancestors 'none'",
  78       "img-src 'self' data: https:",
  79       "media-src 'self' https:",
  80       "style-src 'self' 'unsafe-inline'",
  81       "font-src 'self'",
  82       "manifest-src 'self'",
  83       connect_src,
  84       script_src
  85     ]
  86
  87     report = if report_uri, do: ["report-uri #{report_uri}; report-to csp-endpoint"], else: []
  88
  89     insecure = if scheme == "https", do: ["upgrade-insecure-requests"], else: []
  90
  91     (main_part ++ report ++ insecure)
  92     |> Enum.join("; ")
  93   end
  94
  95   def warn_if_disabled do
  96     unless Config.get([:http_security, :enabled]) do
  97       Logger.warn("HTTP Security is disabled. Add this line to you config to enable it:
  98
  99       config :pleroma, :http_security, enabled: true
 100       ")
 101     end
 102   end
 103
 104   defp maybe_send_sts_header(conn, true) do
 105     max_age_sts = Config.get([:http_security, :sts_max_age])
 106     max_age_ct = Config.get([:http_security, :ct_max_age])
 107
 108     merge_resp_headers(conn, [
 109       {"strict-transport-security", "max-age=#{max_age_sts}; includeSubDomains"},
 110       {"expect-ct", "enforce, max-age=#{max_age_ct}"}
 111     ])
 112   end
 113
 114   defp maybe_send_sts_header(conn, _), do: conn
 115 end