git.squeep.com Git - akkoma/blob - lib/pleroma/plugs/http_security_plug.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2020 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Plugs.HTTPSecurityPlug do
   6   alias Pleroma.Config
   7   import Plug.Conn
   8
   9   require Logger
  10
  11   def init(opts), do: opts
  12
  13   def call(conn, _options) do
  14     if Config.get([:http_security, :enabled]) do
  15       conn
  16       |> merge_resp_headers(headers())
  17       |> maybe_send_sts_header(Config.get([:http_security, :sts]))
  18     else
  19       conn
  20     end
  21   end
  22
  23   defp headers do
  24     referrer_policy = Config.get([:http_security, :referrer_policy])
  25     report_uri = Config.get([:http_security, :report_uri])
  26
  27     headers = [
  28       {"x-xss-protection", "1; mode=block"},
  29       {"x-permitted-cross-domain-policies", "none"},
  30       {"x-frame-options", "DENY"},
  31       {"x-content-type-options", "nosniff"},
  32       {"referrer-policy", referrer_policy},
  33       {"x-download-options", "noopen"},
  34       {"content-security-policy", csp_string()}
  35     ]
  36
  37     if report_uri do
  38       report_group = %{
  39         "group" => "csp-endpoint",
  40         "max-age" => 10_886_400,
  41         "endpoints" => [
  42           %{"url" => report_uri}
  43         ]
  44       }
  45
  46       [{"reply-to", Jason.encode!(report_group)} | headers]
  47     else
  48       headers
  49     end
  50   end
  51
  52   static_csp_rules = [
  53     "default-src 'none'",
  54     "base-uri 'self'",
  55     "frame-ancestors 'none'",
  56     "style-src 'self' 'unsafe-inline'",
  57     "font-src 'self'",
  58     "manifest-src 'self'"
  59   ]
  60
  61   @csp_start [Enum.join(static_csp_rules, ";") <> ";"]
  62
  63   defp csp_string do
  64     scheme = Config.get([Pleroma.Web.Endpoint, :url])[:scheme]
  65     static_url = Pleroma.Web.Endpoint.static_url()
  66     websocket_url = Pleroma.Web.Endpoint.websocket_url()
  67     report_uri = Config.get([:http_security, :report_uri])
  68
  69     img_src = "img-src 'self' data: blob:"
  70     media_src = "media-src 'self'"
  71
  72     {img_src, media_src} =
  73       if Config.get([:media_proxy, :enabled]) &&
  74            !Config.get([:media_proxy, :proxy_opts, :redirect_on_failure]) do
  75         sources = get_proxy_and_attachment_sources()
  76         {[img_src, sources], [media_src, sources]}
  77       else
  78         {[img_src, " https:"], [media_src, " https:"]}
  79       end
  80
  81     connect_src = ["connect-src 'self' blob: ", static_url, ?\s, websocket_url]
  82
  83     connect_src =
  84       if Pleroma.Config.get(:env) == :dev do
  85         [connect_src, " http://localhost:3035/"]
  86       else
  87         connect_src
  88       end
  89
  90     script_src =
  91       if Pleroma.Config.get(:env) == :dev do
  92         "script-src 'self' 'unsafe-eval'"
  93       else
  94         "script-src 'self'"
  95       end
  96
  97     report = if report_uri, do: ["report-uri ", report_uri, ";report-to csp-endpoint"]
  98     insecure = if scheme == "https", do: "upgrade-insecure-requests"
  99
 100     @csp_start
 101     |> add_csp_param(img_src)
 102     |> add_csp_param(media_src)
 103     |> add_csp_param(connect_src)
 104     |> add_csp_param(script_src)
 105     |> add_csp_param(insecure)
 106     |> add_csp_param(report)
 107     |> :erlang.iolist_to_binary()
 108   end
 109
 110   defp get_proxy_and_attachment_sources do
 111     media_proxy_whitelist =
 112       Enum.reduce(Config.get([:media_proxy, :whitelist]), [], fn host, acc ->
 113         add_source(acc, host)
 114       end)
 115
 116     upload_base_url =
 117       if Config.get([Pleroma.Upload, :base_url]),
 118         do: URI.parse(Config.get([Pleroma.Upload, :base_url])).host
 119
 120     s3_endpoint =
 121       if Config.get([Pleroma.Upload, :uploader]) == Pleroma.Uploaders.S3,
 122         do: URI.parse(Config.get([Pleroma.Uploaders.S3, :public_endpoint])).host
 123
 124     []
 125     |> add_source(upload_base_url)
 126     |> add_source(s3_endpoint)
 127     |> add_source(media_proxy_whitelist)
 128   end
 129
 130   defp add_source(iodata, nil), do: iodata
 131   defp add_source(iodata, source), do: [[?\s, source] | iodata]
 132
 133   defp add_csp_param(csp_iodata, nil), do: csp_iodata
 134
 135   defp add_csp_param(csp_iodata, param), do: [[param, ?;] | csp_iodata]
 136
 137   def warn_if_disabled do
 138     unless Config.get([:http_security, :enabled]) do
 139       Logger.warn("
 140                                  .i;;;;i.
 141                                iYcviii;vXY:
 142                              .YXi       .i1c.
 143                             .YC.     .    in7.
 144                            .vc.   ......   ;1c.
 145                            i7,   ..        .;1;
 146                           i7,   .. ...      .Y1i
 147                          ,7v     .6MMM@;     .YX,
 148                         .7;.   ..IMMMMMM1     :t7.
 149                        .;Y.     ;$MMMMMM9.     :tc.
 150                        vY.   .. .nMMM@MMU.      ;1v.
 151                       i7i   ...  .#MM@M@C. .....:71i
 152                      it:   ....   $MMM@9;.,i;;;i,;tti
 153                     :t7.  .....   0MMMWv.,iii:::,,;St.
 154                    .nC.   .....   IMMMQ..,::::::,.,czX.
 155                   .ct:   ....... .ZMMMI..,:::::::,,:76Y.
 156                   c2:   ......,i..Y$M@t..:::::::,,..inZY
 157                  vov   ......:ii..c$MBc..,,,,,,,,,,..iI9i
 158                 i9Y   ......iii:..7@MA,..,,,,,,,,,....;AA:
 159                iIS.  ......:ii::..;@MI....,............;Ez.
 160               .I9.  ......:i::::...8M1..................C0z.
 161              .z9;  ......:i::::,.. .i:...................zWX.
 162              vbv  ......,i::::,,.      ................. :AQY
 163             c6Y.  .,...,::::,,..:t0@@QY. ................ :8bi
 164            :6S. ..,,...,:::,,,..EMMMMMMI. ............... .;bZ,
 165           :6o,  .,,,,..:::,,,..i#MMMMMM#v.................  YW2.
 166          .n8i ..,,,,,,,::,,,,.. tMMMMM@C:.................. .1Wn
 167          7Uc. .:::,,,,,::,,,,..   i1t;,..................... .UEi
 168          7C...::::::::::::,,,,..        ....................  vSi.
 169          ;1;...,,::::::,.........       ..................    Yz:
 170           v97,.........                                     .voC.
 171            izAotX7777777777777777777777777777777777777777Y7n92:
 172              .;CoIIIIIUAA666666699999ZZZZZZZZZZZZZZZZZZZZ6ov.
 173
 174 HTTP Security is disabled. Please re-enable it to prevent users from attacking
 175 your instance and your users via malicious posts:
 176
 177       config :pleroma, :http_security, enabled: true
 178       ")
 179     end
 180   end
 181
 182   defp maybe_send_sts_header(conn, true) do
 183     max_age_sts = Config.get([:http_security, :sts_max_age])
 184     max_age_ct = Config.get([:http_security, :ct_max_age])
 185
 186     merge_resp_headers(conn, [
 187       {"strict-transport-security", "max-age=#{max_age_sts}; includeSubDomains"},
 188       {"expect-ct", "enforce, max-age=#{max_age_ct}"}
 189     ])
 190   end
 191
 192   defp maybe_send_sts_header(conn, _), do: conn
 193 end