git.squeep.com Git - akkoma/blob - lib/pleroma/plugs/http_security_plug.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2019 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Plugs.HTTPSecurityPlug do
   6   alias Pleroma.Config
   7   import Plug.Conn
   8
   9   def init(opts), do: opts
  10
  11   def call(conn, _options) do
  12     if Config.get([:http_security, :enabled]) do
  13       conn
  14       |> merge_resp_headers(headers())
  15       |> maybe_send_sts_header(Config.get([:http_security, :sts]))
  16     else
  17       conn
  18     end
  19   end
  20
  21   defp headers do
  22     referrer_policy = Config.get([:http_security, :referrer_policy])
  23
  24     [
  25       {"x-xss-protection", "1; mode=block"},
  26       {"x-permitted-cross-domain-policies", "none"},
  27       {"x-frame-options", "DENY"},
  28       {"x-content-type-options", "nosniff"},
  29       {"referrer-policy", referrer_policy},
  30       {"x-download-options", "noopen"},
  31       {"content-security-policy", csp_string() <> ";"}
  32     ]
  33   end
  34
  35   defp csp_string do
  36     scheme = Config.get([Pleroma.Web.Endpoint, :url])[:scheme]
  37     websocket_url = String.replace(Pleroma.Web.Endpoint.static_url(), "http", "ws")
  38
  39     connect_src =
  40       if Mix.env() == :dev do
  41         "connect-src 'self' http://localhost:3035/ " <> websocket_url
  42       else
  43         "connect-src 'self' " <> websocket_url
  44       end
  45
  46     script_src =
  47       if Mix.env() == :dev do
  48         "script-src 'self' 'unsafe-eval'"
  49       else
  50         "script-src 'self'"
  51       end
  52
  53     [
  54       "default-src 'none'",
  55       "base-uri 'self'",
  56       "frame-ancestors 'none'",
  57       "img-src 'self' data: https:",
  58       "media-src 'self' https:",
  59       "style-src 'self' 'unsafe-inline'",
  60       "font-src 'self'",
  61       "manifest-src 'self'",
  62       connect_src,
  63       script_src,
  64       if scheme == "https" do
  65         "upgrade-insecure-requests"
  66       end
  67     ]
  68     |> Enum.join("; ")
  69   end
  70
  71   defp maybe_send_sts_header(conn, true) do
  72     max_age_sts = Config.get([:http_security, :sts_max_age])
  73     max_age_ct = Config.get([:http_security, :ct_max_age])
  74
  75     merge_resp_headers(conn, [
  76       {"strict-transport-security", "max-age=#{max_age_sts}; includeSubDomains"},
  77       {"expect-ct", "enforce, max-age=#{max_age_ct}"}
  78     ])
  79   end
  80
  81   defp maybe_send_sts_header(conn, _), do: conn
  82 end