git.squeep.com Git - akkoma/blob - lib/pleroma/plugs/authentication_plug.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2019 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Plugs.AuthenticationPlug do
   6   alias Comeonin.Pbkdf2
   7   import Plug.Conn
   8   alias Pleroma.User
   9   require Logger
  10
  11   def init(options) do
  12     options
  13   end
  14
  15   def checkpw(password, password_hash) do
  16     cond do
  17       String.starts_with?(password_hash, "$pbkdf2") ->
  18         Pbkdf2.checkpw(password, password_hash)
  19
  20       String.starts_with?(password_hash, "$6") ->
  21         :crypt.crypt(password, password_hash) == password_hash
  22
  23       true ->
  24         Logger.error("Password hash not recognized")
  25         false
  26     end
  27   end
  28
  29   def call(%{assigns: %{user: %User{}}} = conn, _), do: conn
  30
  31   def call(
  32         %{
  33           assigns: %{
  34             auth_user: %{password_hash: password_hash} = auth_user,
  35             auth_credentials: %{password: password}
  36           }
  37         } = conn,
  38         _
  39       ) do
  40     if Pbkdf2.checkpw(password, password_hash) do
  41       conn
  42       |> assign(:user, auth_user)
  43     else
  44       conn
  45     end
  46   end
  47
  48   def call(%{assigns: %{auth_credentials: %{password: _}}} = conn, _) do
  49     Pbkdf2.dummy_checkpw()
  50     conn
  51   end
  52
  53   def call(conn, _), do: conn
  54 end