git.squeep.com Git - akkoma/blob - lib/pleroma/plugs/authentication_plug.ex

   1 defmodule Pleroma.Plugs.AuthenticationPlug do
   2   alias Comeonin.Pbkdf2
   3   import Plug.Conn
   4   alias Pleroma.User
   5
   6   def init(options) do
   7     options
   8   end
   9
  10   def call(%{assigns: %{user: %User{}}} = conn, _), do: conn
  11
  12   def call(conn, opts) do
  13     with {:ok, username, password} <- decode_header(conn),
  14          {:ok, user} <- opts[:fetcher].(username),
  15          saved_user_id <- get_session(conn, :user_id),
  16          {:ok, verified_user} <- verify(user, password, saved_user_id)
  17     do
  18       conn
  19       |> assign(:user, verified_user)
  20       |> put_session(:user_id, verified_user.id)
  21     else
  22       _ -> conn |> halt_or_continue(opts)
  23     end
  24   end
  25
  26   # Short-circuit if we have a cookie with the id for the given user.
  27   defp verify(%{id: id} = user, _password, id) do
  28     {:ok, user}
  29   end
  30
  31   defp verify(nil, _password, _user_id) do
  32     Pbkdf2.dummy_checkpw
  33     :error
  34   end
  35
  36   defp verify(user, password, _user_id) do
  37     if Pbkdf2.checkpw(password, user.password_hash) do
  38       {:ok, user}
  39     else
  40       :error
  41     end
  42   end
  43
  44   defp decode_header(conn) do
  45     with ["Basic " <> header] <- get_req_header(conn, "authorization"),
  46          {:ok, userinfo} <- Base.decode64(header),
  47          [username, password] <- String.split(userinfo, ":")
  48     do
  49       {:ok, username, password}
  50     end
  51   end
  52
  53   defp halt_or_continue(conn, %{optional: true}) do
  54     conn |> assign(:user, nil)
  55   end
  56
  57   defp halt_or_continue(conn, _) do
  58     conn
  59     |> put_resp_content_type("application/json")
  60     |> send_resp(403, Poison.encode!(%{error: "Invalid credentials."}))
  61     |> halt
  62   end
  63 end