git.squeep.com Git - akkoma/blob - lib/pleroma/plugs/authentication_plug.ex

   1 defmodule Pleroma.Plugs.AuthenticationPlug do
   2   alias Comeonin.Pbkdf2
   3   import Plug.Conn
   4   alias Pleroma.User
   5
   6   def init(options) do
   7     options
   8   end
   9
  10   def call(%{assigns: %{user: %User{}}} = conn, _), do: conn
  11
  12   def call(conn, opts) do
  13     with {:ok, username, password} <- decode_header(conn),
  14          {:ok, user} <- opts[:fetcher].(username),
  15          false <- !!user.info["deactivated"],
  16          saved_user_id <- get_session(conn, :user_id),
  17          {:ok, verified_user} <- verify(user, password, saved_user_id)
  18     do
  19       conn
  20       |> assign(:user, verified_user)
  21       |> put_session(:user_id, verified_user.id)
  22     else
  23       _ -> conn |> halt_or_continue(opts)
  24     end
  25   end
  26
  27   # Short-circuit if we have a cookie with the id for the given user.
  28   defp verify(%{id: id} = user, _password, id) do
  29     {:ok, user}
  30   end
  31
  32   defp verify(nil, _password, _user_id) do
  33     Pbkdf2.dummy_checkpw
  34     :error
  35   end
  36
  37   defp verify(user, password, _user_id) do
  38     if Pbkdf2.checkpw(password, user.password_hash) do
  39       {:ok, user}
  40     else
  41       :error
  42     end
  43   end
  44
  45   defp decode_header(conn) do
  46     with ["Basic " <> header] <- get_req_header(conn, "authorization"),
  47          {:ok, userinfo} <- Base.decode64(header),
  48          [username, password] <- String.split(userinfo, ":", parts: 2)
  49     do
  50       {:ok, username, password}
  51     end
  52   end
  53
  54   defp halt_or_continue(conn, %{optional: true}) do
  55     conn |> assign(:user, nil)
  56   end
  57
  58   defp halt_or_continue(conn, _) do
  59     conn
  60     |> put_resp_content_type("application/json")
  61     |> send_resp(403, Poison.encode!(%{error: "Invalid credentials."}))
  62     |> halt
  63   end
  64 end