git.squeep.com Git - akkoma/blob - lib/pleroma/plugs/authentication_plug.ex

   1 defmodule Pleroma.Plugs.AuthenticationPlug do
   2   alias Comeonin.Pbkdf2
   3   import Plug.Conn
   4
   5   def init(options) do
   6     options
   7   end
   8
   9   def call(conn, opts) do
  10     with {:ok, username, password} <- decode_header(conn),
  11          {:ok, user} <- opts[:fetcher].(username),
  12          saved_user_id <- get_session(conn, :user_id),
  13          {:ok, verified_user} <- verify(user, password, saved_user_id)
  14     do
  15       conn
  16       |> assign(:user, verified_user)
  17       |> put_session(:user_id, verified_user.id)
  18     else
  19       _ -> conn |> halt_or_continue(opts)
  20     end
  21   end
  22
  23   # Short-circuit if we have a cookie with the id for the given user.
  24   defp verify(%{id: id} = user, _password, id) do
  25     {:ok, user}
  26   end
  27
  28   defp verify(nil, _password, _user_id) do
  29     Pbkdf2.dummy_checkpw
  30     :error
  31   end
  32
  33   defp verify(user, password, _user_id) do
  34     if Pbkdf2.checkpw(password, user.password_hash) do
  35       {:ok, user}
  36     else
  37       :error
  38     end
  39   end
  40
  41   defp decode_header(conn) do
  42     with ["Basic " <> header] <- get_req_header(conn, "authorization"),
  43          {:ok, userinfo} <- Base.decode64(header),
  44          [username, password] <- String.split(userinfo, ":")
  45     do
  46       {:ok, username, password}
  47     end
  48   end
  49
  50   defp halt_or_continue(conn, %{optional: true}) do
  51     conn |> assign(:user, nil)
  52   end
  53
  54   defp halt_or_continue(conn, _) do
  55     conn
  56     |> put_resp_content_type("application/json")
  57     |> send_resp(403, Poison.encode!(%{error: "Invalid credentials."}))
  58     |> halt
  59   end
  60 end