git.squeep.com Git - akkoma/blob - lib/pleroma/plugs/authentication_plug.ex

   1 defmodule Pleroma.Plugs.AuthenticationPlug do
   2   alias Comeonin.Pbkdf2
   3   import Plug.Conn
   4   alias Pleroma.User
   5
   6   def init(options) do
   7     options
   8   end
   9
  10   def call(%{assigns: %{user: %User{}}} = conn, _), do: conn
  11
  12   def call(conn, opts) do
  13     with {:ok, username, password} <- decode_header(conn),
  14          {:ok, user} <- opts[:fetcher].(username),
  15          false <- !!user.info["deactivated"],
  16          saved_user_id <- get_session(conn, :user_id),
  17          legacy_password <- String.starts_with?(user.password_hash, "$6$"),
  18          update_legacy_password <-
  19            !(Map.has_key?(opts, :update_legacy_password) && opts[:update_legacy_password] == false),
  20          {:ok, verified_user} <- verify(user, password, saved_user_id) do
  21       if legacy_password and update_legacy_password do
  22         User.reset_password(verified_user, %{
  23           :password => password,
  24           :password_confirmation => password
  25         })
  26       end
  27
  28       conn
  29       |> assign(:user, verified_user)
  30       |> put_session(:user_id, verified_user.id)
  31     else
  32       _ -> conn |> halt_or_continue(opts)
  33     end
  34   end
  35
  36   # Short-circuit if we have a cookie with the id for the given user.
  37   defp verify(%{id: id} = user, _password, id) do
  38     {:ok, user}
  39   end
  40
  41   defp verify(nil, _password, _user_id) do
  42     Pbkdf2.dummy_checkpw()
  43     :error
  44   end
  45
  46   defp verify(user, password, _user_id) do
  47     is_legacy = String.starts_with?(user.password_hash, "$6$")
  48
  49     valid =
  50       cond do
  51         is_legacy ->
  52           :crypt.crypt(password, user.password_hash) == user.password_hash
  53
  54         true ->
  55           Pbkdf2.checkpw(password, user.password_hash)
  56       end
  57
  58     if valid do
  59       {:ok, user}
  60     else
  61       :error
  62     end
  63   end
  64
  65   defp decode_header(conn) do
  66     with ["Basic " <> header] <- get_req_header(conn, "authorization"),
  67          {:ok, userinfo} <- Base.decode64(header),
  68          [username, password] <- String.split(userinfo, ":", parts: 2) do
  69       {:ok, username, password}
  70     end
  71   end
  72
  73   defp halt_or_continue(conn, %{optional: true}) do
  74     conn |> assign(:user, nil)
  75   end
  76
  77   defp halt_or_continue(conn, _) do
  78     conn
  79     |> put_resp_content_type("application/json")
  80     |> send_resp(403, Jason.encode!(%{error: "Invalid credentials."}))
  81     |> halt
  82   end
  83 end