git.squeep.com Git - akkoma/blob - lib/pleroma/plugs/authentication_plug.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2020 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Plugs.AuthenticationPlug do
   6   alias Comeonin.Pbkdf2
   7   alias Pleroma.Plugs.OAuthScopesPlug
   8   alias Pleroma.User
   9
  10   import Plug.Conn
  11
  12   require Logger
  13
  14   def init(options), do: options
  15
  16   def checkpw(password, "$6" <> _ = password_hash) do
  17     :crypt.crypt(password, password_hash) == password_hash
  18   end
  19
  20   def checkpw(password, "$pbkdf2" <> _ = password_hash) do
  21     Pbkdf2.checkpw(password, password_hash)
  22   end
  23
  24   def checkpw(_password, _password_hash) do
  25     Logger.error("Password hash not recognized")
  26     false
  27   end
  28
  29   def call(%{assigns: %{user: %User{}}} = conn, _), do: conn
  30
  31   def call(
  32         %{
  33           assigns: %{
  34             auth_user: %{password_hash: password_hash} = auth_user,
  35             auth_credentials: %{password: password}
  36           }
  37         } = conn,
  38         _
  39       ) do
  40     if Pbkdf2.checkpw(password, password_hash) do
  41       conn
  42       |> assign(:user, auth_user)
  43       |> OAuthScopesPlug.skip_plug()
  44     else
  45       conn
  46     end
  47   end
  48
  49   def call(%{assigns: %{auth_credentials: %{password: _}}} = conn, _) do
  50     Pbkdf2.dummy_checkpw()
  51     conn
  52   end
  53
  54   def call(conn, _), do: conn
  55 end