git.squeep.com Git - akkoma/blob - lib/pleroma/plugs/admin_secret_authentication_plug.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2020 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Plugs.AdminSecretAuthenticationPlug do
   6   import Plug.Conn
   7
   8   alias Pleroma.User
   9   alias Pleroma.Plugs.OAuthScopesPlug
  10
  11   def init(options) do
  12     options
  13   end
  14
  15   def secret_token do
  16     Pleroma.Config.get(:admin_token)
  17   end
  18
  19   def call(%{assigns: %{user: %User{}}} = conn, _), do: conn
  20
  21   def call(conn, _) do
  22     if secret_token() do
  23       authenticate(conn)
  24     else
  25       conn
  26     end
  27   end
  28
  29   def authenticate(%{params: %{"admin_token" => admin_token}} = conn) do
  30     if admin_token == secret_token() do
  31       assign_admin_user(conn)
  32     else
  33       conn
  34     end
  35   end
  36
  37   def authenticate(conn) do
  38     token = secret_token()
  39
  40     case get_req_header(conn, "x-admin-token") do
  41       [^token] -> assign_admin_user(conn)
  42       _ -> conn
  43     end
  44   end
  45
  46   defp assign_admin_user(conn) do
  47     conn
  48     |> assign(:user, %User{is_admin: true})
  49     |> OAuthScopesPlug.skip_plug()
  50   end
  51 end