git.squeep.com Git - akkoma/blob - lib/pleroma/pagination.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2019 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Pagination do
   6   @moduledoc """
   7   Implements Mastodon-compatible pagination.
   8   """
   9
  10   import Ecto.Query
  11   import Ecto.Changeset
  12
  13   alias Pleroma.Repo
  14
  15   @default_limit 20
  16   @page_keys ["max_id", "min_id", "limit", "since_id", "order"]
  17
  18   def page_keys, do: @page_keys
  19
  20   def fetch_paginated(query, params, type \\ :keyset)
  21
  22   def fetch_paginated(query, %{"total" => true} = params, :keyset) do
  23     total = Repo.aggregate(query, :count, :id)
  24
  25     %{
  26       total: total,
  27       items: fetch_paginated(query, Map.drop(params, ["total"]), :keyset)
  28     }
  29   end
  30
  31   def fetch_paginated(query, params, :keyset) do
  32     options = cast_params(params)
  33
  34     query
  35     |> paginate(options, :keyset)
  36     |> Repo.all()
  37     |> enforce_order(options)
  38   end
  39
  40   def fetch_paginated(query, %{"total" => true} = params, :offset) do
  41     total = Repo.aggregate(query, :count, :id)
  42
  43     %{
  44       total: total,
  45       items: fetch_paginated(query, Map.drop(params, ["total"]), :offset)
  46     }
  47   end
  48
  49   def fetch_paginated(query, params, :offset) do
  50     options = cast_params(params)
  51
  52     query
  53     |> paginate(options, :offset)
  54     |> Repo.all()
  55   end
  56
  57   def paginate(query, options, method \\ :keyset)
  58
  59   def paginate(query, options, :keyset) do
  60     query
  61     |> restrict(:min_id, options)
  62     |> restrict(:since_id, options)
  63     |> restrict(:max_id, options)
  64     |> restrict(:order, options)
  65     |> restrict(:limit, options)
  66   end
  67
  68   def paginate(query, options, :offset) do
  69     query
  70     |> restrict(:order, options)
  71     |> restrict(:offset, options)
  72     |> restrict(:limit, options)
  73   end
  74
  75   defp cast_params(params) do
  76     param_types = %{
  77       min_id: :string,
  78       since_id: :string,
  79       max_id: :string,
  80       offset: :integer,
  81       limit: :integer
  82     }
  83
  84     params =
  85       Enum.reduce(params, %{}, fn
  86         {key, _value}, acc when is_atom(key) -> Map.drop(acc, [key])
  87         {key, value}, acc -> Map.put(acc, key, value)
  88       end)
  89
  90     changeset = cast({%{}, param_types}, params, Map.keys(param_types))
  91     changeset.changes
  92   end
  93
  94   defp restrict(query, :min_id, %{min_id: min_id}) do
  95     where(query, [q], q.id > ^min_id)
  96   end
  97
  98   defp restrict(query, :since_id, %{since_id: since_id}) do
  99     where(query, [q], q.id > ^since_id)
 100   end
 101
 102   defp restrict(query, :max_id, %{max_id: max_id}) do
 103     where(query, [q], q.id < ^max_id)
 104   end
 105
 106   defp restrict(query, :order, %{min_id: _}) do
 107     order_by(query, [u], fragment("? asc nulls last", u.id))
 108   end
 109
 110   defp restrict(query, :order, _options) do
 111     order_by(query, [u], fragment("? desc nulls last", u.id))
 112   end
 113
 114   defp restrict(query, :offset, %{offset: offset}) do
 115     offset(query, ^offset)
 116   end
 117
 118   defp restrict(query, :limit, options) do
 119     limit = Map.get(options, :limit, @default_limit)
 120
 121     query
 122     |> limit(^limit)
 123   end
 124
 125   defp restrict(query, _, _), do: query
 126
 127   defp enforce_order(result, %{min_id: _}) do
 128     result
 129     |> Enum.reverse()
 130   end
 131
 132   defp enforce_order(result, _), do: result
 133 end