git.squeep.com Git - akkoma/blob - lib/pleroma/pagination.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2019 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Pagination do
   6   @moduledoc """
   7   Implements Mastodon-compatible pagination.
   8   """
   9
  10   import Ecto.Query
  11   import Ecto.Changeset
  12
  13   alias Pleroma.Repo
  14
  15   @default_limit 20
  16
  17   def fetch_paginated(query, params) do
  18     options = cast_params(params)
  19
  20     query
  21     |> paginate(options)
  22     |> Repo.all()
  23     |> enforce_order(options)
  24   end
  25
  26   def paginate(query, options) do
  27     query
  28     |> restrict(:min_id, options)
  29     |> restrict(:since_id, options)
  30     |> restrict(:max_id, options)
  31     |> restrict(:order, options)
  32     |> restrict(:limit, options)
  33   end
  34
  35   defp cast_params(params) do
  36     param_types = %{
  37       min_id: :string,
  38       since_id: :string,
  39       max_id: :string,
  40       limit: :integer
  41     }
  42
  43     params =
  44       Enum.reduce(params, %{}, fn
  45         {key, _value}, acc when is_atom(key) -> Map.drop(acc, [key])
  46         {key, value}, acc -> Map.put(acc, key, value)
  47       end)
  48
  49     changeset = cast({%{}, param_types}, params, Map.keys(param_types))
  50     changeset.changes
  51   end
  52
  53   defp restrict(query, :min_id, %{min_id: min_id}) do
  54     where(query, [q], q.id > ^min_id)
  55   end
  56
  57   defp restrict(query, :since_id, %{since_id: since_id}) do
  58     where(query, [q], q.id > ^since_id)
  59   end
  60
  61   defp restrict(query, :max_id, %{max_id: max_id}) do
  62     where(query, [q], q.id < ^max_id)
  63   end
  64
  65   defp restrict(query, :order, %{min_id: _}) do
  66     order_by(query, [u], fragment("? asc nulls last", u.id))
  67   end
  68
  69   defp restrict(query, :order, _options) do
  70     order_by(query, [u], fragment("? desc nulls last", u.id))
  71   end
  72
  73   defp restrict(query, :limit, options) do
  74     limit = Map.get(options, :limit, @default_limit)
  75
  76     query
  77     |> limit(^limit)
  78   end
  79
  80   defp restrict(query, _, _), do: query
  81
  82   defp enforce_order(result, %{min_id: _}) do
  83     result
  84     |> Enum.reverse()
  85   end
  86
  87   defp enforce_order(result, _), do: result
  88 end