git.squeep.com Git - akkoma/blob - lib/pleroma/pagination.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2019 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Pagination do
   6   @moduledoc """
   7   Implements Mastodon-compatible pagination.
   8   """
   9
  10   import Ecto.Query
  11   import Ecto.Changeset
  12
  13   alias Pleroma.Repo
  14
  15   @default_limit 20
  16
  17   def fetch_paginated(query, params, type \\ :keyset)
  18
  19   def fetch_paginated(query, params, :keyset) do
  20     options = cast_params(params)
  21
  22     query
  23     |> paginate(options, :keyset)
  24     |> Repo.all()
  25     |> enforce_order(options)
  26   end
  27
  28   def fetch_paginated(query, params, :offset) do
  29     options = cast_params(params)
  30
  31     query
  32     |> paginate(options, :offset)
  33     |> Repo.all()
  34   end
  35
  36   def paginate(query, options, method \\ :keyset)
  37
  38   def paginate(query, options, :keyset) do
  39     query
  40     |> restrict(:min_id, options)
  41     |> restrict(:since_id, options)
  42     |> restrict(:max_id, options)
  43     |> restrict(:order, options)
  44     |> restrict(:limit, options)
  45   end
  46
  47   def paginate(query, options, :offset) do
  48     query
  49     |> restrict(:offset, options)
  50     |> restrict(:limit, options)
  51   end
  52
  53   defp cast_params(params) do
  54     param_types = %{
  55       min_id: :string,
  56       since_id: :string,
  57       max_id: :string,
  58       offset: :integer,
  59       limit: :integer
  60     }
  61
  62     params =
  63       Enum.reduce(params, %{}, fn
  64         {key, _value}, acc when is_atom(key) -> Map.drop(acc, [key])
  65         {key, value}, acc -> Map.put(acc, key, value)
  66       end)
  67
  68     changeset = cast({%{}, param_types}, params, Map.keys(param_types))
  69     changeset.changes
  70   end
  71
  72   defp restrict(query, :min_id, %{min_id: min_id}) do
  73     where(query, [q], q.id > ^min_id)
  74   end
  75
  76   defp restrict(query, :since_id, %{since_id: since_id}) do
  77     where(query, [q], q.id > ^since_id)
  78   end
  79
  80   defp restrict(query, :max_id, %{max_id: max_id}) do
  81     where(query, [q], q.id < ^max_id)
  82   end
  83
  84   defp restrict(query, :order, %{min_id: _}) do
  85     order_by(query, [u], fragment("? asc nulls last", u.id))
  86   end
  87
  88   defp restrict(query, :order, _options) do
  89     order_by(query, [u], fragment("? desc nulls last", u.id))
  90   end
  91
  92   defp restrict(query, :offset, %{offset: offset}) do
  93     offset(query, ^offset)
  94   end
  95
  96   defp restrict(query, :limit, options) do
  97     limit = Map.get(options, :limit, @default_limit)
  98
  99     query
 100     |> limit(^limit)
 101   end
 102
 103   defp restrict(query, _, _), do: query
 104
 105   defp enforce_order(result, %{min_id: _}) do
 106     result
 107     |> Enum.reverse()
 108   end
 109
 110   defp enforce_order(result, _), do: result
 111 end