git.squeep.com Git - akkoma/blob - lib/pleroma/object.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2019 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Object do
   6   use Ecto.Schema
   7
   8   alias Pleroma.Repo
   9   alias Pleroma.Object
  10   alias Pleroma.User
  11   alias Pleroma.Activity
  12   alias Pleroma.ObjectTombstone
  13
  14   import Ecto.Query
  15   import Ecto.Changeset
  16
  17   schema "objects" do
  18     field(:data, :map)
  19
  20     timestamps()
  21   end
  22
  23   def create(data) do
  24     Object.change(%Object{}, %{data: data})
  25     |> Repo.insert()
  26   end
  27
  28   def change(struct, params \\ %{}) do
  29     struct
  30     |> cast(params, [:data])
  31     |> validate_required([:data])
  32     |> unique_constraint(:ap_id, name: :objects_unique_apid_index)
  33   end
  34
  35   def get_by_ap_id(nil), do: nil
  36
  37   def get_by_ap_id(ap_id) do
  38     Repo.one(from(object in Object, where: fragment("(?)->>'id' = ?", object.data, ^ap_id)))
  39   end
  40
  41   def normalize(%{"id" => ap_id}), do: normalize(ap_id)
  42   def normalize(ap_id) when is_binary(ap_id), do: get_cached_by_ap_id(ap_id)
  43   def normalize(_), do: nil
  44
  45   # Owned objects can only be mutated by their owner
  46   def authorize_mutation(%Object{data: %{"actor" => actor}}, %User{ap_id: ap_id}),
  47     do: actor == ap_id
  48
  49   # Legacy objects can be mutated by anybody
  50   def authorize_mutation(%Object{}, %User{}), do: true
  51
  52   def get_cached_by_ap_id(ap_id) do
  53     key = "object:#{ap_id}"
  54
  55     Cachex.fetch!(:object_cache, key, fn _ ->
  56       object = get_by_ap_id(ap_id)
  57
  58       if object do
  59         {:commit, object}
  60       else
  61         {:ignore, object}
  62       end
  63     end)
  64   end
  65
  66   def context_mapping(context) do
  67     Object.change(%Object{}, %{data: %{"id" => context}})
  68   end
  69
  70   def make_tombstone(%Object{data: %{"id" => id, "type" => type}}, deleted \\ DateTime.utc_now()) do
  71     %ObjectTombstone{
  72       id: id,
  73       formerType: type,
  74       deleted: deleted
  75     }
  76     |> Map.from_struct()
  77   end
  78
  79   def swap_object_with_tombstone(object) do
  80     tombstone = make_tombstone(object)
  81
  82     object
  83     |> Object.change(%{data: tombstone})
  84     |> Repo.update()
  85   end
  86
  87   def delete(%Object{data: %{"id" => id}} = object) do
  88     with {:ok, _obj} = swap_object_with_tombstone(object),
  89          Repo.delete_all(Activity.by_object_ap_id(id)),
  90          {:ok, true} <- Cachex.del(:object_cache, "object:#{id}") do
  91       {:ok, object}
  92     end
  93   end
  94
  95   def set_cache(%Object{data: %{"id" => ap_id}} = object) do
  96     Cachex.put(:object_cache, "object:#{ap_id}", object)
  97     {:ok, object}
  98   end
  99
 100   def update_and_set_cache(changeset) do
 101     with {:ok, object} <- Repo.update(changeset) do
 102       set_cache(object)
 103     else
 104       e -> e
 105     end
 106   end
 107 end