git.squeep.com Git - akkoma/blob - lib/pleroma/object.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2019 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Object do
   6   use Ecto.Schema
   7
   8   alias Pleroma.Activity
   9   alias Pleroma.Object
  10   alias Pleroma.ObjectTombstone
  11   alias Pleroma.Repo
  12   alias Pleroma.User
  13
  14   import Ecto.Query
  15   import Ecto.Changeset
  16
  17   require Logger
  18
  19   schema "objects" do
  20     field(:data, :map)
  21
  22     timestamps()
  23   end
  24
  25   def create(data) do
  26     Object.change(%Object{}, %{data: data})
  27     |> Repo.insert()
  28   end
  29
  30   def change(struct, params \\ %{}) do
  31     struct
  32     |> cast(params, [:data])
  33     |> validate_required([:data])
  34     |> unique_constraint(:ap_id, name: :objects_unique_apid_index)
  35   end
  36
  37   def get_by_ap_id(nil), do: nil
  38
  39   def get_by_ap_id(ap_id) do
  40     Repo.one(from(object in Object, where: fragment("(?)->>'id' = ?", object.data, ^ap_id)))
  41   end
  42
  43   # If we pass an Activity to Object.normalize(), we can try to use the preloaded object.
  44   # Use this whenever possible, especially when walking graphs in an O(N) loop!
  45   def normalize(%Activity{object: %Object{} = object}), do: object
  46
  47   # Catch and log Object.normalize() calls where the Activity's child object is not
  48   # preloaded.
  49   def normalize(%Activity{data: %{"object" => %{"id" => ap_id}}}) do
  50     Logger.info(
  51       "Object.normalize() called without preloaded object (#{ap_id}).  Consider preloading the object!"
  52     )
  53
  54     normalize(ap_id)
  55   end
  56
  57   def normalize(%Activity{data: %{"object" => ap_id}}) do
  58     Logger.info(
  59       "Object.normalize() called without preloaded object (#{ap_id}).  Consider preloading the object!"
  60     )
  61
  62     normalize(ap_id)
  63   end
  64
  65   # Old way, try fetching the object through cache.
  66   def normalize(%{"id" => ap_id}), do: normalize(ap_id)
  67   def normalize(ap_id) when is_binary(ap_id), do: get_cached_by_ap_id(ap_id)
  68   def normalize(_), do: nil
  69
  70   # Owned objects can only be mutated by their owner
  71   def authorize_mutation(%Object{data: %{"actor" => actor}}, %User{ap_id: ap_id}),
  72     do: actor == ap_id
  73
  74   # Legacy objects can be mutated by anybody
  75   def authorize_mutation(%Object{}, %User{}), do: true
  76
  77   def get_cached_by_ap_id(ap_id) do
  78     key = "object:#{ap_id}"
  79
  80     Cachex.fetch!(:object_cache, key, fn _ ->
  81       object = get_by_ap_id(ap_id)
  82
  83       if object do
  84         {:commit, object}
  85       else
  86         {:ignore, object}
  87       end
  88     end)
  89   end
  90
  91   def context_mapping(context) do
  92     Object.change(%Object{}, %{data: %{"id" => context}})
  93   end
  94
  95   def make_tombstone(%Object{data: %{"id" => id, "type" => type}}, deleted \\ DateTime.utc_now()) do
  96     %ObjectTombstone{
  97       id: id,
  98       formerType: type,
  99       deleted: deleted
 100     }
 101     |> Map.from_struct()
 102   end
 103
 104   def swap_object_with_tombstone(object) do
 105     tombstone = make_tombstone(object)
 106
 107     object
 108     |> Object.change(%{data: tombstone})
 109     |> Repo.update()
 110   end
 111
 112   def delete(%Object{data: %{"id" => id}} = object) do
 113     with {:ok, _obj} = swap_object_with_tombstone(object),
 114          deleted_activity = Activity.delete_by_ap_id(id),
 115          {:ok, true} <- Cachex.del(:object_cache, "object:#{id}") do
 116       {:ok, object, deleted_activity}
 117     end
 118   end
 119
 120   def set_cache(%Object{data: %{"id" => ap_id}} = object) do
 121     Cachex.put(:object_cache, "object:#{ap_id}", object)
 122     {:ok, object}
 123   end
 124
 125   def update_and_set_cache(changeset) do
 126     with {:ok, object} <- Repo.update(changeset) do
 127       set_cache(object)
 128     else
 129       e -> e
 130     end
 131   end
 132 end