git.squeep.com Git - akkoma/blob - lib/pleroma/object/fetcher.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2019 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Object.Fetcher do
   6   alias Pleroma.HTTP
   7   alias Pleroma.Object
   8   alias Pleroma.Object.Containment
   9   alias Pleroma.Repo
  10   alias Pleroma.Signature
  11   alias Pleroma.Web.ActivityPub.InternalFetchActor
  12   alias Pleroma.Web.ActivityPub.Transmogrifier
  13
  14   require Logger
  15   require Pleroma.Constants
  16
  17   defp touch_changeset(changeset) do
  18     updated_at =
  19       NaiveDateTime.utc_now()
  20       |> NaiveDateTime.truncate(:second)
  21
  22     Ecto.Changeset.put_change(changeset, :updated_at, updated_at)
  23   end
  24
  25   defp maybe_reinject_internal_fields(data, %{data: %{} = old_data}) do
  26     internal_fields = Map.take(old_data, Pleroma.Constants.object_internal_fields())
  27
  28     Map.merge(data, internal_fields)
  29   end
  30
  31   defp maybe_reinject_internal_fields(data, _), do: data
  32
  33   @spec reinject_object(struct(), map()) :: {:ok, Object.t()} | {:error, any()}
  34   defp reinject_object(struct, data) do
  35     Logger.debug("Reinjecting object #{data["id"]}")
  36
  37     with data <- Transmogrifier.fix_object(data),
  38          data <- maybe_reinject_internal_fields(data, struct),
  39          changeset <- Object.change(struct, %{data: data}),
  40          changeset <- touch_changeset(changeset),
  41          {:ok, object} <- Repo.insert_or_update(changeset) do
  42       {:ok, object}
  43     else
  44       e ->
  45         Logger.error("Error while processing object: #{inspect(e)}")
  46         {:error, e}
  47     end
  48   end
  49
  50   def refetch_object(%Object{data: %{"id" => id}} = object) do
  51     with {:local, false} <- {:local, String.starts_with?(id, Pleroma.Web.base_url() <> "/")},
  52          {:ok, data} <- fetch_and_contain_remote_object_from_id(id),
  53          {:ok, object} <- reinject_object(object, data) do
  54       {:ok, object}
  55     else
  56       {:local, true} -> object
  57       e -> {:error, e}
  58     end
  59   end
  60
  61   # TODO:
  62   # This will create a Create activity, which we need internally at the moment.
  63   def fetch_object_from_id(id, options \\ []) do
  64     with {:fetch_object, nil} <- {:fetch_object, Object.get_cached_by_ap_id(id)},
  65          {:fetch, {:ok, data}} <- {:fetch, fetch_and_contain_remote_object_from_id(id)},
  66          {:normalize, nil} <- {:normalize, Object.normalize(data, false)},
  67          params <- prepare_activity_params(data),
  68          {:containment, :ok} <- {:containment, Containment.contain_origin(id, params)},
  69          {:ok, activity} <- Transmogrifier.handle_incoming(params, options),
  70          {:object, _data, %Object{} = object} <-
  71            {:object, data, Object.normalize(activity, false)} do
  72       {:ok, object}
  73     else
  74       {:containment, _} ->
  75         {:error, "Object containment failed."}
  76
  77       {:error, {:reject, nil}} ->
  78         {:reject, nil}
  79
  80       {:object, data, nil} ->
  81         reinject_object(%Object{}, data)
  82
  83       {:normalize, object = %Object{}} ->
  84         {:ok, object}
  85
  86       {:fetch_object, %Object{} = object} ->
  87         {:ok, object}
  88
  89       e ->
  90         e
  91     end
  92   end
  93
  94   defp prepare_activity_params(data) do
  95     %{
  96       "type" => "Create",
  97       "to" => data["to"],
  98       "cc" => data["cc"],
  99       # Should we seriously keep this attributedTo thing?
 100       "actor" => data["actor"] || data["attributedTo"],
 101       "object" => data
 102     }
 103   end
 104
 105   def fetch_object_from_id!(id, options \\ []) do
 106     with {:ok, object} <- fetch_object_from_id(id, options) do
 107       object
 108     else
 109       _e ->
 110         nil
 111     end
 112   end
 113
 114   defp make_signature(id, date) do
 115     uri = URI.parse(id)
 116
 117     signature =
 118       InternalFetchActor.get_actor()
 119       |> Signature.sign(%{
 120         "(request-target)": "get #{uri.path}",
 121         host: uri.host,
 122         date: date
 123       })
 124
 125     [{:Signature, signature}]
 126   end
 127
 128   defp sign_fetch(headers, id, date) do
 129     if Pleroma.Config.get([:activitypub, :sign_object_fetches]) do
 130       headers ++ make_signature(id, date)
 131     else
 132       headers
 133     end
 134   end
 135
 136   defp maybe_date_fetch(headers, date) do
 137     if Pleroma.Config.get([:activitypub, :sign_object_fetches]) do
 138       headers ++ [{:Date, date}]
 139     else
 140       headers
 141     end
 142   end
 143
 144   def fetch_and_contain_remote_object_from_id(id) when is_binary(id) do
 145     Logger.info("Fetching object #{id} via AP")
 146
 147     date = Pleroma.Signature.signed_date()
 148
 149     headers =
 150       [{:Accept, "application/activity+json"}]
 151       |> maybe_date_fetch(date)
 152       |> sign_fetch(id, date)
 153
 154     Logger.debug("Fetch headers: #{inspect(headers)}")
 155
 156     with true <- String.starts_with?(id, "http"),
 157          {:ok, %{body: body, status: code}} when code in 200..299 <- HTTP.get(id, headers),
 158          {:ok, data} <- Jason.decode(body),
 159          :ok <- Containment.contain_origin_from_id(id, data) do
 160       {:ok, data}
 161     else
 162       {:ok, %{status: code}} when code in [404, 410] ->
 163         {:error, "Object has been deleted"}
 164
 165       e ->
 166         {:error, e}
 167     end
 168   end
 169
 170   def fetch_and_contain_remote_object_from_id(%{"id" => id}),
 171     do: fetch_and_contain_remote_object_from_id(id)
 172
 173   def fetch_and_contain_remote_object_from_id(_id), do: {:error, "id must be a string"}
 174 end