git.squeep.com Git - akkoma/blob - lib/pleroma/object/fetcher.ex

   1 defmodule Pleroma.Object.Fetcher do
   2   alias Pleroma.Object
   3   alias Pleroma.Object.Containment
   4   alias Pleroma.Web.ActivityPub.Transmogrifier
   5   alias Pleroma.Web.OStatus
   6
   7   require Logger
   8
   9   @httpoison Application.get_env(:pleroma, :httpoison)
  10
  11   defp reinject_object(data) do
  12     Logger.debug("Reinjecting object #{data["id"]}")
  13
  14     with data <- Transmogrifier.fix_object(data),
  15          {:ok, object} <- Object.create(data) do
  16       {:ok, object}
  17     else
  18       e ->
  19         Logger.error("Error while processing object: #{inspect(e)}")
  20         {:error, e}
  21     end
  22   end
  23
  24   # TODO:
  25   # This will create a Create activity, which we need internally at the moment.
  26   def fetch_object_from_id(id) do
  27     if object = Object.get_cached_by_ap_id(id) do
  28       {:ok, object}
  29     else
  30       Logger.info("Fetching #{id} via AP")
  31
  32       with {:ok, data} <- fetch_and_contain_remote_object_from_id(id),
  33            nil <- Object.normalize(data, false),
  34            params <- %{
  35              "type" => "Create",
  36              "to" => data["to"],
  37              "cc" => data["cc"],
  38              "actor" => data["actor"] || data["attributedTo"],
  39              "object" => data
  40            },
  41            :ok <- Containment.contain_origin(id, params),
  42            {:ok, activity} <- Transmogrifier.handle_incoming(params),
  43            {:object, _data, %Object{} = object} <-
  44              {:object, data, Object.normalize(activity, false)} do
  45         {:ok, object}
  46       else
  47         {:error, {:reject, nil}} ->
  48           {:reject, nil}
  49
  50         {:object, data, nil} ->
  51           reinject_object(data)
  52
  53         object = %Object{} ->
  54           {:ok, object}
  55
  56         _e ->
  57           Logger.info("Couldn't get object via AP, trying out OStatus fetching...")
  58
  59           case OStatus.fetch_activity_from_url(id) do
  60             {:ok, [activity | _]} -> {:ok, Object.normalize(activity, false)}
  61             e -> e
  62           end
  63       end
  64     end
  65   end
  66
  67   def fetch_object_from_id!(id) do
  68     with {:ok, object} <- fetch_object_from_id(id) do
  69       object
  70     else
  71       _e ->
  72         nil
  73     end
  74   end
  75
  76   def fetch_and_contain_remote_object_from_id(id) do
  77     Logger.info("Fetching object #{id} via AP")
  78
  79     with true <- String.starts_with?(id, "http"),
  80          {:ok, %{body: body, status: code}} when code in 200..299 <-
  81            @httpoison.get(
  82              id,
  83              [{:Accept, "application/activity+json"}]
  84            ),
  85          {:ok, data} <- Jason.decode(body),
  86          :ok <- Containment.contain_origin_from_id(id, data) do
  87       {:ok, data}
  88     else
  89       e ->
  90         {:error, e}
  91     end
  92   end
  93 end