git.squeep.com Git - akkoma/blob - lib/pleroma/object/fetcher.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2019 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Object.Fetcher do
   6   alias Pleroma.HTTP
   7   alias Pleroma.Object
   8   alias Pleroma.Object.Containment
   9   alias Pleroma.Web.ActivityPub.Transmogrifier
  10   alias Pleroma.Web.OStatus
  11
  12   require Logger
  13
  14   defp reinject_object(data) do
  15     Logger.debug("Reinjecting object #{data["id"]}")
  16
  17     with data <- Transmogrifier.fix_object(data),
  18          {:ok, object} <- Object.create(data) do
  19       {:ok, object}
  20     else
  21       e ->
  22         Logger.error("Error while processing object: #{inspect(e)}")
  23         {:error, e}
  24     end
  25   end
  26
  27   # TODO:
  28   # This will create a Create activity, which we need internally at the moment.
  29   def fetch_object_from_id(id, options \\ []) do
  30     if object = Object.get_cached_by_ap_id(id) do
  31       {:ok, object}
  32     else
  33       Logger.info("Fetching #{id} via AP")
  34
  35       with {:ok, data} <- fetch_and_contain_remote_object_from_id(id),
  36            nil <- Object.normalize(data, false),
  37            params <- %{
  38              "type" => "Create",
  39              "to" => data["to"],
  40              "cc" => data["cc"],
  41              "actor" => data["actor"] || data["attributedTo"],
  42              "object" => data
  43            },
  44            :ok <- Containment.contain_origin(id, params),
  45            {:ok, activity} <- Transmogrifier.handle_incoming(params, options),
  46            {:object, _data, %Object{} = object} <-
  47              {:object, data, Object.normalize(activity, false)} do
  48         {:ok, object}
  49       else
  50         {:error, {:reject, nil}} ->
  51           {:reject, nil}
  52
  53         {:object, data, nil} ->
  54           reinject_object(data)
  55
  56         object = %Object{} ->
  57           {:ok, object}
  58
  59         _e ->
  60           Logger.info("Couldn't get object via AP, trying out OStatus fetching...")
  61
  62           case OStatus.fetch_activity_from_url(id) do
  63             {:ok, [activity | _]} -> {:ok, Object.normalize(activity, false)}
  64             e -> e
  65           end
  66       end
  67     end
  68   end
  69
  70   def fetch_object_from_id!(id, options \\ []) do
  71     with {:ok, object} <- fetch_object_from_id(id, options) do
  72       object
  73     else
  74       _e ->
  75         nil
  76     end
  77   end
  78
  79   def fetch_and_contain_remote_object_from_id(id) do
  80     Logger.info("Fetching object #{id} via AP")
  81
  82     with true <- String.starts_with?(id, "http"),
  83          {:ok, %{body: body, status: code}} when code in 200..299 <-
  84            HTTP.get(
  85              id,
  86              [{:Accept, "application/activity+json"}]
  87            ),
  88          {:ok, data} <- Jason.decode(body),
  89          :ok <- Containment.contain_origin_from_id(id, data) do
  90       {:ok, data}
  91     else
  92       {:ok, %{status: code}} when code in [404, 410] ->
  93         {:error, "Object has been deleted"}
  94
  95       e ->
  96         {:error, e}
  97     end
  98   end
  99 end