git.squeep.com Git - akkoma/blob - lib/pleroma/object/containment.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2020 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Object.Containment do
   6   @moduledoc """
   7   This module contains some useful functions for containing objects to specific
   8   origins and determining those origins.  They previously lived in the
   9   ActivityPub `Transmogrifier` module.
  10
  11   Object containment is an important step in validating remote objects to prevent
  12   spoofing, therefore removal of object containment functions is NOT recommended.
  13   """
  14   def get_actor(%{"actor" => actor}) when is_binary(actor) do
  15     actor
  16   end
  17
  18   def get_actor(%{"actor" => actor}) when is_list(actor) do
  19     if is_binary(Enum.at(actor, 0)) do
  20       Enum.at(actor, 0)
  21     else
  22       Enum.find(actor, fn %{"type" => type} -> type in ["Person", "Service", "Application"] end)
  23       |> Map.get("id")
  24     end
  25   end
  26
  27   def get_actor(%{"actor" => %{"id" => id}}) when is_bitstring(id) do
  28     id
  29   end
  30
  31   def get_actor(%{"actor" => nil, "attributedTo" => actor}) when not is_nil(actor) do
  32     get_actor(%{"actor" => actor})
  33   end
  34
  35   # TODO: We explicitly allow 'tag' URIs through, due to references to legacy OStatus
  36   # objects being present in the test suite environment.  Once these objects are
  37   # removed, please also remove this.
  38   if Mix.env() == :test do
  39     defp compare_uris(_, %URI{scheme: "tag"}), do: :ok
  40   end
  41
  42   defp compare_uris(%URI{host: host} = _id_uri, %URI{host: host} = _other_uri), do: :ok
  43   defp compare_uris(_id_uri, _other_uri), do: :error
  44
  45   @doc """
  46   Checks that an imported AP object's actor matches the domain it came from.
  47   """
  48   def contain_origin(_id, %{"actor" => nil}), do: :error
  49
  50   def contain_origin(id, %{"actor" => _actor} = params) do
  51     id_uri = URI.parse(id)
  52     actor_uri = URI.parse(get_actor(params))
  53
  54     compare_uris(actor_uri, id_uri)
  55   end
  56
  57   def contain_origin(id, %{"attributedTo" => actor} = params),
  58     do: contain_origin(id, Map.put(params, "actor", actor))
  59
  60   def contain_origin(_id, _data), do: :error
  61
  62   def contain_origin_from_id(id, %{"id" => other_id} = _params) when is_binary(other_id) do
  63     id_uri = URI.parse(id)
  64     other_uri = URI.parse(other_id)
  65
  66     compare_uris(id_uri, other_uri)
  67   end
  68
  69   def contain_origin_from_id(_id, _data), do: :error
  70
  71   def contain_child(%{"object" => %{"id" => id, "attributedTo" => _} = object}),
  72     do: contain_origin(id, object)
  73
  74   def contain_child(_), do: :ok
  75 end