git.squeep.com Git - akkoma/blob - lib/pleroma/object/containment.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2019 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Object.Containment do
   6   @moduledoc """
   7   This module contains some useful functions for containing objects to specific
   8   origins and determining those origins.  They previously lived in the
   9   ActivityPub `Transmogrifier` module.
  10
  11   Object containment is an important step in validating remote objects to prevent
  12   spoofing, therefore removal of object containment functions is NOT recommended.
  13   """
  14   def get_actor(%{"actor" => actor}) when is_binary(actor) do
  15     actor
  16   end
  17
  18   def get_actor(%{"actor" => actor}) when is_list(actor) do
  19     if is_binary(Enum.at(actor, 0)) do
  20       Enum.at(actor, 0)
  21     else
  22       Enum.find(actor, fn %{"type" => type} -> type in ["Person", "Service", "Application"] end)
  23       |> Map.get("id")
  24     end
  25   end
  26
  27   def get_actor(%{"actor" => %{"id" => id}}) when is_bitstring(id) do
  28     id
  29   end
  30
  31   def get_actor(%{"actor" => nil, "attributedTo" => actor}) when not is_nil(actor) do
  32     get_actor(%{"actor" => actor})
  33   end
  34
  35   def get_object(%{"object" => id}) when is_binary(id) do
  36     id
  37   end
  38
  39   def get_object(%{"object" => %{"id" => id}}) when is_binary(id) do
  40     id
  41   end
  42
  43   def get_object(_) do
  44     nil
  45   end
  46
  47   @doc """
  48   Checks that an imported AP object's actor matches the domain it came from.
  49   """
  50   def contain_origin(_id, %{"actor" => nil}), do: :error
  51
  52   def contain_origin(id, %{"actor" => _actor} = params) do
  53     id_uri = URI.parse(id)
  54     actor_uri = URI.parse(get_actor(params))
  55
  56     if id_uri.host == actor_uri.host do
  57       :ok
  58     else
  59       :error
  60     end
  61   end
  62
  63   def contain_origin(id, %{"attributedTo" => actor} = params),
  64     do: contain_origin(id, Map.put(params, "actor", actor))
  65
  66   def contain_origin_from_id(_id, %{"id" => nil}), do: :error
  67
  68   def contain_origin_from_id(id, %{"id" => other_id} = _params) do
  69     id_uri = URI.parse(id)
  70     other_uri = URI.parse(other_id)
  71
  72     if id_uri.host == other_uri.host do
  73       :ok
  74     else
  75       :error
  76     end
  77   end
  78
  79   def contain_child(%{"object" => %{"id" => id, "attributedTo" => _} = object}),
  80     do: contain_origin(id, object)
  81
  82   def contain_child(_), do: :ok
  83 end