git.squeep.com Git - akkoma/blob - lib/pleroma/notification.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2019 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Notification do
   6   use Ecto.Schema
   7
   8   alias Pleroma.User
   9   alias Pleroma.Activity
  10   alias Pleroma.Notification
  11   alias Pleroma.Repo
  12   alias Pleroma.Web.CommonAPI.Utils
  13   alias Pleroma.Web.CommonAPI
  14
  15   import Ecto.Query
  16
  17   schema "notifications" do
  18     field(:seen, :boolean, default: false)
  19     belongs_to(:user, User, type: Pleroma.FlakeId)
  20     belongs_to(:activity, Activity, type: Pleroma.FlakeId)
  21
  22     timestamps()
  23   end
  24
  25   # TODO: Make generic and unify (see activity_pub.ex)
  26   defp restrict_max(query, %{"max_id" => max_id}) do
  27     from(activity in query, where: activity.id < ^max_id)
  28   end
  29
  30   defp restrict_max(query, _), do: query
  31
  32   defp restrict_since(query, %{"since_id" => since_id}) do
  33     from(activity in query, where: activity.id > ^since_id)
  34   end
  35
  36   defp restrict_since(query, _), do: query
  37
  38   def for_user(user, opts \\ %{}) do
  39     from(
  40       n in Notification,
  41       where: n.user_id == ^user.id,
  42       order_by: [desc: n.id],
  43       join: activity in assoc(n, :activity),
  44       preload: [activity: activity],
  45       limit: 20,
  46       where:
  47         fragment(
  48           "? not in (SELECT ap_id FROM users WHERE info->'disabled' @> 'true')",
  49           activity.actor
  50         )
  51     )
  52     |> restrict_since(opts)
  53     |> restrict_max(opts)
  54     |> Repo.all()
  55   end
  56
  57   def set_read_up_to(%{id: user_id} = _user, id) do
  58     query =
  59       from(
  60         n in Notification,
  61         where: n.user_id == ^user_id,
  62         where: n.id <= ^id,
  63         update: [
  64           set: [seen: true]
  65         ]
  66       )
  67
  68     Repo.update_all(query, [])
  69   end
  70
  71   def get(%{id: user_id} = _user, id) do
  72     query =
  73       from(
  74         n in Notification,
  75         where: n.id == ^id,
  76         join: activity in assoc(n, :activity),
  77         preload: [activity: activity]
  78       )
  79
  80     notification = Repo.one(query)
  81
  82     case notification do
  83       %{user_id: ^user_id} ->
  84         {:ok, notification}
  85
  86       _ ->
  87         {:error, "Cannot get notification"}
  88     end
  89   end
  90
  91   def clear(user) do
  92     from(n in Notification, where: n.user_id == ^user.id)
  93     |> Repo.delete_all()
  94   end
  95
  96   def dismiss(%{id: user_id} = _user, id) do
  97     notification = Repo.get(Notification, id)
  98
  99     case notification do
 100       %{user_id: ^user_id} ->
 101         Repo.delete(notification)
 102
 103       _ ->
 104         {:error, "Cannot dismiss notification"}
 105     end
 106   end
 107
 108   def create_notifications(%Activity{data: %{"to" => _, "type" => type}} = activity)
 109       when type in ["Create", "Like", "Announce", "Follow"] do
 110     users = get_notified_from_activity(activity)
 111
 112     notifications = Enum.map(users, fn user -> create_notification(activity, user) end)
 113     {:ok, notifications}
 114   end
 115
 116   def create_notifications(_), do: {:ok, []}
 117
 118   # TODO move to sql, too.
 119   def create_notification(%Activity{} = activity, %User{} = user) do
 120     unless User.blocks?(user, %{ap_id: activity.data["actor"]}) or
 121              CommonAPI.thread_muted?(user, activity) or user.ap_id == activity.data["actor"] or
 122              (activity.data["type"] == "Follow" and
 123                 Enum.any?(Notification.for_user(user), fn notif ->
 124                   notif.activity.data["type"] == "Follow" and
 125                     notif.activity.data["actor"] == activity.data["actor"]
 126                 end)) do
 127       notification = %Notification{user_id: user.id, activity: activity}
 128       {:ok, notification} = Repo.insert(notification)
 129       Pleroma.Web.Streamer.stream("user", notification)
 130       Pleroma.Web.Push.send(notification)
 131       notification
 132     end
 133   end
 134
 135   def get_notified_from_activity(activity, local_only \\ true)
 136
 137   def get_notified_from_activity(
 138         %Activity{data: %{"to" => _, "type" => type} = _data} = activity,
 139         local_only
 140       )
 141       when type in ["Create", "Like", "Announce", "Follow"] do
 142     recipients =
 143       []
 144       |> Utils.maybe_notify_to_recipients(activity)
 145       |> Utils.maybe_notify_mentioned_recipients(activity)
 146       |> Enum.uniq()
 147
 148     User.get_users_from_set(recipients, local_only)
 149   end
 150
 151   def get_notified_from_activity(_, _local_only), do: []
 152 end