git.squeep.com Git - akkoma/blob - lib/pleroma/mime.ex

   1 defmodule Pleroma.MIME do
   2   @moduledoc """
   3   Returns the mime-type of a binary and optionally a normalized file-name. Requires at least (the first) 8 bytes.
   4   """
   5   @default "application/octet-stream"
   6
   7   @spec file_mime_type(String.t()) ::
   8           {:ok, content_type :: String.t(), filename :: String.t()} | {:error, any()} | :error
   9   def file_mime_type(path, filename) do
  10     with {:ok, content_type} <- file_mime_type(path),
  11          filename <- fix_extension(filename, content_type) do
  12       {:ok, content_type, filename}
  13     end
  14   end
  15
  16   @spec file_mime_type(String.t()) :: {:ok, String.t()} | {:error, any()} | :error
  17   def file_mime_type(filename) do
  18     File.open(filename, [:read], fn f ->
  19       check_mime_type(IO.binread(f, 8))
  20     end)
  21   end
  22
  23   def bin_mime_type(binary, filename) do
  24     with {:ok, content_type} <- bin_mime_type(binary),
  25          filename <- fix_extension(filename, content_type) do
  26       {:ok, content_type, filename}
  27     end
  28   end
  29
  30   @spec bin_mime_type(binary()) :: {:ok, String.t()} | :error
  31   def bin_mime_type(<<head::binary-size(8), _::binary>>) do
  32     {:ok, check_mime_type(head)}
  33   end
  34
  35   def mime_type(<<_::binary>>), do: {:ok, @default}
  36
  37   def bin_mime_type(_), do: :error
  38
  39   defp fix_extension(filename, content_type) do
  40     parts = String.split(filename, ".")
  41
  42     new_filename =
  43       if length(parts) > 1 do
  44         Enum.drop(parts, -1) |> Enum.join(".")
  45       else
  46         Enum.join(parts)
  47       end
  48
  49     cond do
  50       content_type == "application/octet-stream" ->
  51         filename
  52
  53       ext = List.first(MIME.extensions(content_type)) ->
  54         new_filename <> "." <> ext
  55
  56       true ->
  57         Enum.join([new_filename, String.split(content_type, "/") |> List.last()], ".")
  58     end
  59   end
  60
  61   defp check_mime_type(<<0x89, 0x50, 0x4E, 0x47, 0x0D, 0x0A, 0x1A, 0x0A>>) do
  62     "image/png"
  63   end
  64
  65   defp check_mime_type(<<0x47, 0x49, 0x46, 0x38, _, 0x61, _, _>>) do
  66     "image/gif"
  67   end
  68
  69   defp check_mime_type(<<0xFF, 0xD8, 0xFF, _, _, _, _, _>>) do
  70     "image/jpeg"
  71   end
  72
  73   defp check_mime_type(<<0x1A, 0x45, 0xDF, 0xA3, _, _, _, _>>) do
  74     "video/webm"
  75   end
  76
  77   defp check_mime_type(<<0x00, 0x00, 0x00, _, 0x66, 0x74, 0x79, 0x70>>) do
  78     "video/mp4"
  79   end
  80
  81   defp check_mime_type(<<0x49, 0x44, 0x33, _, _, _, _, _>>) do
  82     "audio/mpeg"
  83   end
  84
  85   defp check_mime_type(<<255, 251, _, 68, 0, 0, 0, 0>>) do
  86     "audio/mpeg"
  87   end
  88
  89   defp check_mime_type(<<0x4F, 0x67, 0x67, 0x53, 0x00, 0x02, 0x00, 0x00>>) do
  90     "audio/ogg"
  91   end
  92
  93   defp check_mime_type(<<0x52, 0x49, 0x46, 0x46, _, _, _, _>>) do
  94     "audio/wav"
  95   end
  96
  97   defp check_mime_type(_) do
  98     @default
  99   end
 100 end