git.squeep.com Git - akkoma/blob - lib/pleroma/list.ex

   1 defmodule Pleroma.List do
   2   use Ecto.Schema
   3   import Ecto.{Changeset, Query}
   4   alias Pleroma.{User, Repo, Activity}
   5
   6   schema "lists" do
   7     belongs_to(:user, Pleroma.User)
   8     field(:title, :string)
   9     field(:following, {:array, :string}, default: [])
  10
  11     timestamps()
  12   end
  13
  14   def title_changeset(list, attrs \\ %{}) do
  15     list
  16     |> cast(attrs, [:title])
  17     |> validate_required([:title])
  18   end
  19
  20   def follow_changeset(list, attrs \\ %{}) do
  21     list
  22     |> cast(attrs, [:following])
  23     |> validate_required([:following])
  24   end
  25
  26   def for_user(user, opts) do
  27     query =
  28       from(
  29         l in Pleroma.List,
  30         where: l.user_id == ^user.id,
  31         order_by: [desc: l.id],
  32         limit: 50
  33       )
  34
  35     Repo.all(query)
  36   end
  37
  38   def get(id, %{id: user_id} = _user) do
  39     query =
  40       from(
  41         l in Pleroma.List,
  42         where: l.id == ^id,
  43         where: l.user_id == ^user_id
  44       )
  45
  46     Repo.one(query)
  47   end
  48
  49   def get_following(%Pleroma.List{following: following} = list) do
  50     q =
  51       from(
  52         u in User,
  53         where: u.follower_address in ^following
  54       )
  55
  56     {:ok, Repo.all(q)}
  57   end
  58
  59   # Get lists the activity should be streamed to.
  60   def get_lists_from_activity(%Activity{actor: ap_id}) do
  61     actor = User.get_cached_by_ap_id(ap_id)
  62
  63     query =
  64       from(
  65         l in Pleroma.List,
  66         where: fragment("? && ?", l.following, ^[actor.follower_address])
  67       )
  68
  69     Repo.all(query)
  70   end
  71
  72   def rename(%Pleroma.List{} = list, title) do
  73     list
  74     |> title_changeset(%{title: title})
  75     |> Repo.update()
  76   end
  77
  78   def create(title, %User{} = creator) do
  79     list = %Pleroma.List{user_id: creator.id, title: title}
  80     Repo.insert(list)
  81   end
  82
  83   def follow(%Pleroma.List{following: following} = list, %User{} = followed) do
  84     update_follows(list, %{following: Enum.uniq([followed.follower_address | following])})
  85   end
  86
  87   def unfollow(%Pleroma.List{following: following} = list, %User{} = unfollowed) do
  88     update_follows(list, %{following: List.delete(following, unfollowed.follower_address)})
  89   end
  90
  91   def delete(%Pleroma.List{} = list) do
  92     Repo.delete(list)
  93   end
  94
  95   def update_follows(%Pleroma.List{} = list, attrs) do
  96     list
  97     |> follow_changeset(attrs)
  98     |> Repo.update()
  99   end
 100 end